[gentoo-commits] repo/gentoo:master commit in: sys-apps/gnome-disk-utility/

[Mart Raudsepp]

commit:     96be73e149aa24c0f90c3a9b38825d0821c044d1
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 11 09:22:06 2021 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Jul 11 09:23:03 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=96be73e1

sys-apps/gnome-disk-utility: bump to 40.2

Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 sys-apps/gnome-disk-utility/Manifest               |  1 +
 .../gnome-disk-utility-40.2.ebuild                 | 63 ++++++++++++++++++++++
 2 files changed, 64 insertions(+)

diff --git a/sys-apps/gnome-disk-utility/Manifest b/sys-apps/gnome-disk-utility/Manifest
index 45b319d6ec1..44c6a165d6a 100644
--- a/sys-apps/gnome-disk-utility/Manifest
+++ b/sys-apps/gnome-disk-utility/Manifest
@@ -1 +1,2 @@
 DIST gnome-disk-utility-40.1.tar.xz 1387480 BLAKE2B ef3650cadd2f5e264abbf805fa0af1c7e9e30e067c946d91dd879600e2db5b9af83cc8f7990954cd8d859a7456d4054ddb9bcad0ed716a08b848f78dddda98d8 SHA512 be7a298f6ca9afad5dfd420a5ff5386a1e096f7d956339d5528702b2bd2b657dad4b9017b0ae519d13480fe0806fa64fd1c94e2c1136ee00a6b17c7f21a0acf1
+DIST gnome-disk-utility-40.2.tar.xz 1387320 BLAKE2B fa5df2f3c18a6635e41fdbab7382b036771028b86bff6adf94241aa2919d2a489f1829299e6efb46ab25daccba01919d372269250a3456319f4057a0dcec76cd SHA512 a674968270fa00874f69e1d3db7afea9cab7d5a0cbedbc1aae02282941d5e92f4816b27f35b6775e758148fa27750460adbe4c6f591a68caab0c6c9d709fa50c

diff --git a/sys-apps/gnome-disk-utility/gnome-disk-utility-40.2.ebuild b/sys-apps/gnome-disk-utility/gnome-disk-utility-40.2.ebuild
new file mode 100644
index 00000000000..3192512980a
--- /dev/null
+++ b/sys-apps/gnome-disk-utility/gnome-disk-utility-40.2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Disk Utility for GNOME using udisks"
+HOMEPAGE="https://wiki.gnome.org/Apps/Disks"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="fat elogind gnome systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+DEPEND="
+	>=media-libs/libdvdread-4.2.0:0=
+	>=dev-libs/glib-2.31:2
+	>=x11-libs/gtk+-3.16.0:3
+	>=media-libs/libcanberra-0.1[gtk3]
+	>=gui-libs/libhandy-1.1.90:1=
+	>=app-arch/xz-utils-5.0.5
+	>=x11-libs/libnotify-0.7:=
+	>=app-crypt/libsecret-0.7
+	>=dev-libs/libpwquality-1.0.0
+	>=sys-fs/udisks-2.7.6:2
+	elogind? ( >=sys-auth/elogind-209 )
+	systemd? ( >=sys-apps/systemd-209:0= )
+"
+RDEPEND="${DEPEND}
+	x11-themes/adwaita-icon-theme
+	fat? ( sys-fs/dosfstools )
+	gnome? ( >=gnome-base/gnome-settings-daemon-3.8 )
+"
+# libxml2 for xml-stripblanks in gresource
+BDEPEND="
+	dev-libs/libxml2:2
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dlogind=$(usex systemd libsystemd $(usex elogind libelogind none))
+		$(meson_use gnome gsd_plugin)
+		-Dman=true
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}