[gentoo-commits] gentoo-x86 commit in media-libs/lvtk: metadata.xml lvtk-1.2.0.ebuild Manifest ChangeLog

[Ben de Groot (yngwin)]

yngwin      15/07/25 08:17:03

  Added:                metadata.xml lvtk-1.2.0.ebuild Manifest ChangeLog
  Log:
  Initial import. Ebuild updated from proaudio overlay.
  
  (Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key 0x4FDF9CFD2FAC514E!)

Revision  Changes    Path
1.1                  media-libs/lvtk/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/lvtk/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/lvtk/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
  <herd>proaudio</herd>
  <use>
    <flag name='gtk2'>Enable <pkg>x11-libs/gtk+:2</pkg> based GUI support</flag>
    <flag name='tools'>Compile and install ttl2c tool</flag>
  </use>
</pkgmetadata>



1.1                  media-libs/lvtk/lvtk-1.2.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/lvtk/lvtk-1.2.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/lvtk/lvtk-1.2.0.ebuild?rev=1.1&content-type=text/plain

Index: lvtk-1.2.0.ebuild
===================================================================
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/lvtk/lvtk-1.2.0.ebuild,v 1.1 2015/07/25 08:17:03 yngwin Exp $

EAPI=5
PYTHON_COMPAT=( python2_7 )
PYTHON_REQ_USE="threads(+)"
inherit python-single-r1 waf-utils

DESCRIPTION="A set of C++ wrappers around the LV2 C API"
HOMEPAGE="http://lvtoolkit.org/"
SRC_URI="https://github.com/lvtk/lvtk/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc examples +gtk2 +tools"

RDEPEND="media-libs/lv2
	>=dev-libs/boost-1.40.0
	gtk2? ( dev-cpp/gtkmm:2.4 )"
DEPEND="${RDEPEND}
	${PYTHON_DEPS}
	doc? ( app-doc/doxygen
		media-gfx/graphviz )
	virtual/pkgconfig"

DOCS=( AUTHORS ChangeLog README )

src_configure() {
	local mywafconfargs=(
		"--docdir=${EPREFIX}/usr/share/doc/${PF}"
		"--lv2dir=${EPREFIX}/usr/$(get_libdir)/lv2"
	)
	use debug    && mywafconfargs+=( "--debug" )
	use doc      && mywafconfargs+=( "--docs" )
	use examples || mywafconfargs+=( "--disable-examples" )
	use tools    || mywafconfargs+=( "--disable-tools" )
	use gtk2     || mywafconfargs+=( "--disable-ui" )
	waf-utils_src_configure ${mywafconfargs[@]}
}

src_install() {
	waf-utils_src_install

	# It does not respect docdir properly, reported upstream
	if use doc; then
		mv "${ED}/usr/share/doc/${PF}/lvtk-1.0/html" "${ED}/usr/share/doc/${PF}/html"
		rmdir "${ED}/usr/share/doc/${PF}/lvtk-1.0"
	fi
}



1.1                  media-libs/lvtk/Manifest

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/lvtk/Manifest?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/lvtk/Manifest?rev=1.1&content-type=text/plain

Index: Manifest
===================================================================
DIST lvtk-1.2.0.tar.gz 201146 SHA256 4dda4c26a16fc3f216ff77f5bb308f05667640e54fc80f0ae4984e869990cb0e SHA512 f193ec28103cb2f6353ff0f96f8790041baf1ae99472c5d04017c23b42d0179b1f5e1de6722e17080410311d0e7e1de4ca0ae9ab76fb3bf8a02d9dc1451d8db7 WHIRLPOOL c7a70d033a2a02b02f890cc68789b376e7e4e53231290dbaa5bb85abf0d3b53cb64afe352bab6d71ddcd77a5f4d002073564ebc398d6f35d7cc75bc1b49728e2
EBUILD lvtk-1.2.0.ebuild 1374 SHA256 4c0fc19e540c01231a48ffd0d0fdc9950ea02391ad58bc3e6f3ec6a750576e29 SHA512 63844cba9f81320b0f9cb4dda62ae4a88cd0625309c557d4df4800b5f82674b65005aaafacef13cb88d5600d3517d5905ef07bd97a8c41f483cbf1d77ce8e038 WHIRLPOOL ebd4a30693463a2b66fbddf19df668e5b1eb3dddfa27279d2758008b3005e3f281a624dda8940cf0e1f04e883499539fc715ff46d57d883459333e1137b6d23f
MISC metadata.xml 322 SHA256 b389e5d038c1ef88a44c2b7ed38aad4bdb8a1862a2d9a80c887854ae32229f0c SHA512 e83344f47953e37519a1da7cb0f72ce277c0dec24306b78da979a39963f17c7ab09f45e503e8b31a81080af1d70145166e327c17127e8a68ec4de7174d928f4b WHIRLPOOL 7b512ff4840e105db044b997dd3f985928952d8ba57f6f75e3d6ecd2896606004a2ca15604d2f863962a753a11a819f908d6b2dc8478373be8b82dbb0e5fdee8



1.1                  media-libs/lvtk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/lvtk/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/lvtk/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for media-libs/lvtk
# Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/lvtk/ChangeLog,v 1.1 2015/07/25 08:17:03 yngwin Exp $

*lvtk-1.2.0 (25 Jul 2015)

  25 Jul 2015; Ben de Groot <yngwin@g.o> +lvtk-1.2.0.ebuild,
  +metadata.xml:
  Initial import. Ebuild updated from proaudio overlay.