[gentoo-commits] gentoo-x86 commit in gnome-extra/libgda: libgda-4.99.4.ebuild ChangeLog metadata.xml

[Nirbheek Chauhan (nirbheek)]

nirbheek    11/09/30 19:27:46

  Modified:             ChangeLog metadata.xml
  Added:                libgda-4.99.4.ebuild
  Log:
  Bump to 4.99.4 from the gnome overlay, ebuild updates by tetromino
  
  (Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

Revision  Changes    Path
1.177                gnome-extra/libgda/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/ChangeLog?rev=1.177&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/ChangeLog?rev=1.177&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/ChangeLog?r1=1.176&r2=1.177

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/libgda/ChangeLog,v
retrieving revision 1.176
retrieving revision 1.177
diff -u -r1.176 -r1.177
--- ChangeLog	13 Sep 2011 11:46:42 -0000	1.176
+++ ChangeLog	30 Sep 2011 19:27:46 -0000	1.177
@@ -1,6 +1,16 @@
 # ChangeLog for gnome-extra/libgda
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/ChangeLog,v 1.176 2011/09/13 11:46:42 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/ChangeLog,v 1.177 2011/09/30 19:27:46 nirbheek Exp $
+
+*libgda-4.99.4 (30 Sep 2011)
+
+  30 Sep 2011; Nirbheek Chauhan <nirbheek@g.o>
+  +files/libgda-4.99.1-control-center-icon-collision.patch,
+  +files/libgda-4.99.1-gda-browser-doc-collision.patch,
+  +files/libgda-4.99.1-gda-browser-help-collision.patch, +libgda-4.99.4.ebuild,
+  +files/libgda-4.99.4-disable-broken-tests.patch,
+  +files/libgda-4.99.4-statement-rewriting-fix.patch, metadata.xml:
+  Bump to 4.99.4 from the gnome overlay, ebuild updates by tetromino
 
   13 Sep 2011; Pacho Ramos <pacho@g.o> -libgda-3.0.4.ebuild:
   Remove old.



1.7                  gnome-extra/libgda/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/metadata.xml?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/metadata.xml?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/metadata.xml?r1=1.6&r2=1.7

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/gnome-extra/libgda/metadata.xml,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- metadata.xml	13 Sep 2011 11:46:42 -0000	1.6
+++ metadata.xml	30 Sep 2011 19:27:46 -0000	1.7
@@ -8,6 +8,8 @@
 	<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg> for
 		introspection</flag>
 	<flag name="json">Enable support for JSON format</flag>
+	<flag name="mdb">Enable support for Microsoft Access Database using 
+		<pkg>app-office/mdbtools</pkg></flag>
 	<flag name="sourceview">Enable support for <pkg>x11-libs/gtksourceview</pkg></flag>
 </use>
 </pkgmetadata>



1.1                  gnome-extra/libgda/libgda-4.99.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/libgda-4.99.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/gnome-extra/libgda/libgda-4.99.4.ebuild?rev=1.1&content-type=text/plain

Index: libgda-4.99.4.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/libgda/libgda-4.99.4.ebuild,v 1.1 2011/09/30 19:27:46 nirbheek Exp $

EAPI="3"
GNOME2_LA_PUNT="yes"
GCONF_DEBUG="yes"
GNOME_TARBALL_SUFFIX="xz" # remove when python eclass supports EAPI 4
PYTHON_DEPEND="2"

inherit autotools db-use eutils flag-o-matic gnome2 java-pkg-opt-2 python

DESCRIPTION="Gnome Database Access Library"
HOMEPAGE="http://www.gnome-db.org/"
LICENSE="GPL-2 LGPL-2"

IUSE="berkdb bindist canvas doc firebird gnome-keyring gtk graphviz http +introspection json ldap mdb mysql oci8 postgres sourceview ssl"
SLOT="5"
KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

# FIXME: sqlite is automagic, but maybe it is a hard-dep
# FIXME: autoconf is a hell of inconsistencies
RDEPEND="
	app-text/iso-codes
	>=dev-libs/glib-2.16:2
	>=dev-libs/libxml2-2
	dev-libs/libxslt
	dev-libs/libunique:3
	sys-libs/readline
	sys-libs/ncurses
	berkdb?   ( sys-libs/db )
	!bindist? ( firebird? ( dev-db/firebird ) )
	gtk? (
		>=x11-libs/gtk+-3.0.0:3
		canvas? ( x11-libs/goocanvas:2.0 )
		sourceview? ( x11-libs/gtksourceview:3.0 )
		graphviz? ( media-gfx/graphviz )
	)
	gnome-keyring? ( || ( gnome-base/libgnome-keyring <gnome-base/gnome-keyring-2.29.4 ) )
	http? ( >=net-libs/libsoup-2.24:2.4 )
	introspection? ( >=dev-libs/gobject-introspection-0.6.5 )
	json?     ( dev-libs/json-glib )
	ldap?     ( net-nds/openldap )
	mdb?      ( >app-office/mdbtools-0.5 )
	mysql?    ( virtual/mysql )
	postgres? ( dev-db/postgresql-base )
	ssl?      ( dev-libs/openssl )
	>=dev-db/sqlite-3.6.22:3"

DEPEND="${RDEPEND}
	>=dev-util/pkgconfig-0.18
	>=dev-util/intltool-0.35.5
	>=app-text/gnome-doc-utils-0.9
	doc? ( >=dev-util/gtk-doc-1 )"

# XXX: some tests fail when run from portage (but pass when building by hand)
RESTRICT="test"

pkg_setup() {
	DOCS="AUTHORS ChangeLog NEWS README"

	if use canvas || use graphviz || use sourceview; then
		if ! use gtk; then
			ewarn "You must enable USE=gtk to make use of canvas, graphivz or sourceview USE flag."
			ewarn "Disabling for now."
			G2CONF="${G2CONF} --without-goocanvas --without-graphivz --without-gtksourceview"
		else
			G2CONF="${G2CONF}
				$(use_with canvas goocanvas)
				$(use_with graphviz)
				$(use_with sourceview gtksourceview)"
		fi
	fi

	G2CONF="${G2CONF}
		--with-unique
		--disable-scrollkeeper
		--disable-static
		--enable-system-sqlite
		$(use_with berkdb bdb /usr)
		$(use_with gnome-keyring)
		$(use_with gtk ui)
		$(use_with http libsoup)
		$(use_enable introspection)
		$(use_with java java $JAVA_HOME)
		$(use_enable json)
		$(use_with ldap)
		$(use_with mdb mdb /usr)
		$(use_with mysql mysql /usr)
		$(use_with postgres postgres /usr)
		$(use_enable ssl crypto)"

	if use bindist; then
		# firebird license is not GPL compatible
		G2CONF="${G2CONF} --without-firebird"
	else
		G2CONF="${G2CONF} $(use_with firebird firebird /usr)"
	fi

	use berkdb && append-cppflags "-I$(db_includedir)"
	use oci8 || G2CONF="${G2CONF} --without-oracle"

	# Not in portage
	G2CONF="${G2CONF}
		--disable-default-binary"
}

src_prepare() {
	# Fix build order for generated content, upstream #630958
	#epatch "${FILESDIR}/${PN}-9999-fix-build-order.patch"

	# Fix compilation failure of keyword_hash.c, upstream #630959
	#epatch "${FILESDIR}/${PN}-4.2.0-missing-include-in-keyword_hash-generator.patch"

	# Upstream patch to fix a serious statement rewriting bug, in next release
	epatch "${FILESDIR}/${PN}-4.99.4-statement-rewriting-fix.patch"

	# Disable broken tests so we can check the others
	epatch "${FILESDIR}/${PN}-4.99.4-disable-broken-tests.patch"

	# Prevent file collisions with libgda:4
	epatch "${FILESDIR}/${PN}-4.99.1-gda-browser-help-collision.patch"
	epatch "${FILESDIR}/${PN}-4.99.1-gda-browser-doc-collision.patch"
	epatch "${FILESDIR}/${PN}-4.99.1-control-center-icon-collision.patch"
	# Move files with mv (since epatch can't handle rename diffs) and
	# update pre-generated gtk-doc files
	local f
	for f in tools/browser/doc/gda-browser* ; do
		mv ${f} ${f/gda-browser/gda-browser-5.0} || die "mv ${f} failed"
	done
	for f in tools/browser/doc/html/gda-browser.devhelp* ; do
		sed -e 's:name="gda-browser":name="gda-browser-5.0":' \
			-i ${f} || die "sed ${f} failed"
		mv ${f} ${f/gda-browser/gda-browser-5.0} || die "mv ${f} failed"
	done
	for f in control-center/data/*_gda-control-center.png ; do
		mv ${f} ${f/_gda-control-center.png/_gda-control-center-5.0.png} ||
			die "mv ${f} failed"
	done

	python_convert_shebangs -r 2 libgda-report/RML/trml2{html,pdf}

	eautoreconf
	gnome2_src_prepare
}

src_test() {
	emake check XDG_DATA_HOME="${T}/.local" || die "tests failed"
}

pkg_postinst() {
	gnome2_pkg_postinst
	local d
	for d in /usr/share/libgda-5.0/gda_trml2{html,pdf} ; do
		python_mod_optimize ${d}
	done
}

pkg_postrm() {
	gnome2_pkg_postrm
	local d
	for d in /usr/share/libgda-5.0/gda_trml2{html,pdf} ; do
		python_mod_cleanup ${d}
	done
}