[gentoo-commits] gentoo-x86 commit in app-text/cb2bib: ChangeLog cb2bib-1.3.7.ebuild

[Dominik Kapusta (ayoy)]

ayoy        10/02/22 15:47:36

  Modified:             ChangeLog
  Added:                cb2bib-1.3.7.ebuild
  Log:
  Version bump (bug #306319)
  (Portage version: 2.2_rc62/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  app-text/cb2bib/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/cb2bib/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/cb2bib/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/cb2bib/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/cb2bib/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	6 Jan 2010 20:02:58 -0000	1.1
+++ ChangeLog	22 Feb 2010 15:47:35 -0000	1.2
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/cb2bib
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/cb2bib/ChangeLog,v 1.1 2010/01/06 20:02:58 ayoy Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/cb2bib/ChangeLog,v 1.2 2010/02/22 15:47:35 ayoy Exp $
+
+*cb2bib-1.3.7 (22 Feb 2010)
+
+  22 Feb 2010; Dominik Kapusta <ayoy@g.o> +cb2bib-1.3.7.ebuild:
+  Version bump (bug #306319)
 
 *cb2bib-1.3.6 (06 Jan 2010)
 



1.1                  app-text/cb2bib/cb2bib-1.3.7.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/cb2bib/cb2bib-1.3.7.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-text/cb2bib/cb2bib-1.3.7.ebuild?rev=1.1&content-type=text/plain

Index: cb2bib-1.3.7.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/cb2bib/cb2bib-1.3.7.ebuild,v 1.1 2010/02/22 15:47:35 ayoy Exp $

EAPI="2"

inherit qt4-r2

DESCRIPTION="Tool for extracting unformatted bibliographic references"
HOMEPAGE="http://www.molspaces.com/cb2bib/"
SRC_URI="http://www.molspaces.com/dl/progs/${P}.tar.gz"

SLOT="0"
LICENSE="GPL-3"
KEYWORDS="~amd64 ~x86"
IUSE="debug +lzo +poll"

DEPEND="x11-libs/qt-webkit:4
	lzo? ( dev-libs/lzo )"
RDEPEND="${DEPEND}"

src_prepare() {
	echo "CONFIG += ordered" >> "${PN}.pro" || die "patching project file failed"
	sed -i 's:\.\./COPYRIGHT \.\.\/LICENSE::' src/src.pro || die "sed src.pro failed"
}

src_configure() {
	# Custom configure script has only few options, so call ./configure manually...
	# We need to unset QTDIR here, else we may end up with qt3 if it is installed.
	# TODO: remove QTDIR when qt3 goes away
	QTDIR="" ./configure \
		$(use_enable lzo) \
		$(use_enable poll cbpoll) \
		--disable-qmake-call \
		--qmakepath /usr/bin/qmake \
		--prefix /usr \
		--bindir /usr/bin \
		--datadir /usr/share \
		--desktopdatadir /usr/share/applications \
		--icondir /usr/share/pixmaps \
		|| die "cb2bib-provided configure failed"

	eqmake4 $(cat qmake-additional-args)
}

pkg_postinst() {
	elog "For best functionality, emerge the following packages:"
	elog "    app-text/poppler-utils  - for data import from PDF files"
	elog "    app-text/dvipdfm        - for data import from DVI files"
	elog "    app-text/bibutils       - for data import from ISI, endnote format"
	elog "    media-fonts/jsmath      - for displaying mathematical notation"
	elog "    media-libs/exiftool     - for proper UTF-8 metadata writing in PDF"
	elog "                              text strings"
	elog "    virtual/latex-base      - to check for BibTeX file correctness and to get"
	elog "                              nice printing through the shell script bib2pdf"
}