[gentoo-commits] gentoo-x86 commit in dev-lang/gdl: ChangeLog gdl-0.9_rc1.ebuild gdl-0.9_rc2.ebuild

[Markus Dittrich (markusle)]

markusle    09/08/26 02:46:17

  Modified:             ChangeLog gdl-0.9_rc1.ebuild
  Added:                gdl-0.9_rc2.ebuild
  Log:
  Version bump and fixed hdf5 issue (#275388) as well as collision with antlr (#267671).
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.12                 dev-lang/gdl/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/ChangeLog?r1=1.11&r2=1.12

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/gdl/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog	2 Sep 2008 09:32:03 -0000	1.11
+++ ChangeLog	26 Aug 2009 02:46:16 -0000	1.12
@@ -1,6 +1,14 @@
 # ChangeLog for dev-lang/gdl
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/ChangeLog,v 1.11 2008/09/02 09:32:03 bicatali Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/ChangeLog,v 1.12 2009/08/26 02:46:16 markusle Exp $
+
+*gdl-0.9_rc2 (25 Aug 2009)
+
+  25 Aug 2009; Markus Dittrich <markusle@g.o> +gdl-0.9_rc2.ebuild,
+  +files/gdl-0.9_rc2-gcc4.4.patch, +files/gdl-0.9_rc2-antlr.patch:
+  Version bump and fixed hdf5-1.8 issue (see bug #275388).
+  Also, the ebuild now compiles against the system antlr fixing
+  the file collision with dev-java/antlr (see bug #267671).
 
   02 Sep 2008; Sébastien Fabbro <bicatali@g.o>
   -files/gdl-0.8.11-gcc4-gentoo.patch, -files/gdl-0.9_pre5-proj4.patch,



1.5                  dev-lang/gdl/gdl-0.9_rc1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/gdl-0.9_rc1.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/gdl-0.9_rc1.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/gdl-0.9_rc1.ebuild?r1=1.4&r2=1.5

Index: gdl-0.9_rc1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/gdl/gdl-0.9_rc1.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- gdl-0.9_rc1.ebuild	6 Jun 2008 15:56:03 -0000	1.4
+++ gdl-0.9_rc1.ebuild	26 Aug 2009 02:46:16 -0000	1.5
@@ -1,6 +1,6 @@
-# Copyright 1999-2008 Gentoo Foundation
+# Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/gdl-0.9_rc1.ebuild,v 1.4 2008/06/06 15:56:03 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/gdl-0.9_rc1.ebuild,v 1.5 2009/08/26 02:46:16 markusle Exp $
 
 inherit eutils flag-o-matic autotools
 



1.1                  dev-lang/gdl/gdl-0.9_rc2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/gdl-0.9_rc2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-lang/gdl/gdl-0.9_rc2.ebuild?rev=1.1&content-type=text/plain

Index: gdl-0.9_rc2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/gdl/gdl-0.9_rc2.ebuild,v 1.1 2009/08/26 02:46:16 markusle Exp $

EAPI="2"

inherit eutils flag-o-matic autotools

MYP=${P/_/}
DESCRIPTION="An Interactive Data Language compatible incremental compiler"
LICENSE="GPL-2"
HOMEPAGE="http://gnudatalanguage.sourceforge.net/"
SRC_URI="mirror://sourceforge/gnudatalanguage/${MYP}.tar.gz"

SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="python fftw hdf hdf5 netcdf imagemagick proj"

RDEPEND=">=sys-libs/readline-4.3
	sci-libs/gsl
	=dev-java/antlr-2.7*[cxx]
	>=sci-libs/plplot-5.3
	imagemagick? ( media-gfx/imagemagick )
	hdf? ( sci-libs/hdf )
	hdf5? ( sci-libs/hdf5 )
	netcdf? ( sci-libs/netcdf )
	python? ( dev-python/numarray dev-python/matplotlib )
	fftw? ( >=sci-libs/fftw-3 )
	proj? ( sci-libs/proj )"

DEPEND="${RDEPEND}
	sys-devel/libtool"

S="${WORKDIR}/${MYP}"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-0.9_rc1-proj4.patch
	epatch "${FILESDIR}"/${PN}-0.9_rc1-magick.patch
	epatch "${FILESDIR}"/${P}-gcc4.4.patch
	epatch "${FILESDIR}"/${P}-antlr.patch

	# we need to blow away the directory with antlr
	# otherwise the build system picks up bogus
	# header files
	rm -fr "${S}"/src/antlr || die "failed to remove antlr directory"

	eautoreconf
}

src_configure() {
	# need to check for old plplot
	local myconf
	if has_version '<sci-libs/plplot-5.9.0'; then
		myconf="${myconf} --enable-oldplplot"
	fi

	# sorry, but even configure barfs with --as-needed
	# when linking against imagemagick - have yet to
	# figure out what the problem is
	use imagemagick && append-ldflags -Wl,--no-as-needed

	# make sure we're hdf5-1.6 backward compatible
	use hdf5 && append-flags -DH5_USE_16_API

	use proj && append-cppflags -DPJ_LIB__
	econf \
	  $(use_with python) \
	  $(use_with fftw) \
	  $(use_with hdf) \
	  $(use_with hdf5) \
	  $(use_with netcdf) \
	  $(use_with imagemagick Magick) \
	  $(use_with proj libproj4) \
	  ${myconf} \
	  || die "econf failed"

}

src_test() {
	cd "${S}"/testsuite
	PATH="${S}"/src gdl <<-EOF
		test_suite
	EOF
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	insinto /usr/share/${PN}
	doins -r src/pro src/py || die "install pro and py files failed"
	dodoc README PYTHON.txt AUTHORS ChangeLog NEWS TODO HACKING \
		|| die "Failed to install docs"

	# add GDL provided routines to IDL_PATH
	echo "GDL_STARTUP=/usr/share/${PN}/pro" > 99gdl
	echo "GDL_PATH=/usr/share/${PN}" >> 99gdl
	doenvd 99gdl || die "doenvd failed"
}