[gentoo-commits] gentoo-x86 commit in app-misc/workrave: ChangeLog workrave-1.9.0.ebuild

[Gilles Dartiguelongue (eva)]

eva         08/11/22 14:50:49

  Modified:             ChangeLog
  Added:                workrave-1.9.0.ebuild
  Log:
  Bump to 1.9.0. Gstreamer support is not enabled because it freezes workrave on my box. Closes bug #236270.
  (Portage version: 2.2_rc15/cvs/Linux 2.6.24-gentoo-r8-mactel x86_64)

Revision  Changes    Path
1.56                 app-misc/workrave/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/workrave/ChangeLog?rev=1.56&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/workrave/ChangeLog?rev=1.56&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/workrave/ChangeLog?r1=1.55&r2=1.56

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-misc/workrave/ChangeLog,v
retrieving revision 1.55
retrieving revision 1.56
diff -u -r1.55 -r1.56
--- ChangeLog	4 Nov 2008 00:13:28 -0000	1.55
+++ ChangeLog	22 Nov 2008 14:50:49 -0000	1.56
@@ -1,6 +1,16 @@
 # ChangeLog for app-misc/workrave
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-misc/workrave/ChangeLog,v 1.55 2008/11/04 00:13:28 jmbsvicetto Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-misc/workrave/ChangeLog,v 1.56 2008/11/22 14:50:49 eva Exp $
+
+*workrave-1.9.0 (22 Nov 2008)
+
+  22 Nov 2008; Gilles Dartiguelongue <eva@g.o>
+  +files/workrave-1.9.0-compilation-fixes.patch,
+  +files/workrave-1.9.0-dbus-glib.xml, +files/workrave-1.9.0-gcc43.patch,
+  +files/workrave-1.9.0-gui.xml, +files/workrave-1.9.0-parallel-make.patch,
+  +files/workrave-1.9.0-service.in, +workrave-1.9.0.ebuild:
+  Bump to 1.9.0. Gstreamer support is not enabled because it freezes
+  workrave on my box. Closes bug #236270.
 
   04 Nov 2008; Jorge Manuel B. S. Vicetto <jmbsvicetto@g.o>
   metadata.xml:



1.1                  app-misc/workrave/workrave-1.9.0.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/workrave/workrave-1.9.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-misc/workrave/workrave-1.9.0.ebuild?rev=1.1&content-type=text/plain

Index: workrave-1.9.0.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-misc/workrave/workrave-1.9.0.ebuild,v 1.1 2008/11/22 14:50:49 eva Exp $

inherit autotools eutils gnome2

DESCRIPTION="Helpful utility to attack Repetitive Strain Injury (RSI)"
HOMEPAGE="http://workrave.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="arts dbus distribution gnome kde nls xml"

RDEPEND=">=dev-libs/glib-2
	>=gnome-base/gconf-2
	>=x11-libs/gtk+-2.6
	>=dev-cpp/gtkmm-2.4
	>=dev-cpp/glibmm-2.4
	>=dev-libs/libsigc++-2
	gnome? (
		>=gnome-base/libgnomeui-2
		>=dev-cpp/libgnomeuimm-2.6
		>=gnome-base/gnome-panel-2.0.10
		>=gnome-base/libbonobo-2
		>=gnome-base/orbit-2.8.3 )
	distribution? ( >=net-libs/gnet-2 )
	dbus? (
		>=sys-apps/dbus-1.0
		dev-libs/dbus-glib )
	xml? ( dev-libs/gdome2 )
	kde? (
		=x11-libs/qt-3*
		=kde-base/kdelibs-3* )
	arts? ( kde-base/arts )

	x11-libs/libX11
	x11-libs/libXtst
	x11-libs/libXt
	x11-libs/libXmu"

DEPEND="${RDEPEND}
	x11-proto/xproto
	x11-proto/inputproto
	x11-proto/recordproto

	nls? ( sys-devel/gettext )
	>=dev-util/pkgconfig-0.9"
# Currently freezes workrave
#	gstreamer? (
#		>=media-libs/gstreamer-0.10 )

DOCS="AUTHORS NEWS README TODO"

pkg_setup() {
	G2CONF="--enable-gconf
		--disable-gstreamer
		$(use_enable dbus)
		$(use_enable distribution)
		$(use_enable gnome)
		$(use_enable gnome gnomemm)
		$(use_enable kde)
		$(use_enable nls)
		$(use_enable xml)
		$(use_with arts)"
}

src_unpack() {
	gnome2_src_unpack

	# Fix intltool tests
	echo "frontend/gtkmm/src/gnome_applet/Workrave-Applet.server.in" >> po/POTFILES.skip
	echo "intl/plural.c" >> po/POTFILES.skip

	# Copy file missing from tarball
	cp "${FILESDIR}/${P}-gui.xml" "${S}/frontend/gtkmm/src/workrave-gui.xml"
	cp "${FILESDIR}/${P}-dbus-glib.xml" "${S}/common/bin/DBus-glib.xml"
	cp "${FILESDIR}/${P}-service.in" "${S}/frontend/gtkmm/src/org.workrave.Workrave.service.in"

	# Fix compilation with gcc-4
	epatch "${FILESDIR}/${P}-gcc43.patch"

	# Fix compilation with USE="-distribution"
	epatch "${FILESDIR}/${P}-compilation-fixes.patch"

	# Fix parallel make issues ?
	epatch "${FILESDIR}/${P}-parallel-make.patch"

	eautoreconf
}

src_compile() {
	if use kde; then
		addwrite "/usr/qt/3/etc/settings"
		export KDEDIR=$(kde-config --prefix)
		einfo "KDEDIR set to ${KDEDIR}"
	fi

	gnome2_src_compile
}