[gentoo-commits] gentoo-x86 commit in app-editors/gedit: ChangeLog gedit-2.22.3.ebuild

[Mart Raudsepp (leio)]

leio        08/06/02 17:57:50

  Modified:             ChangeLog
  Added:                gedit-2.22.3.ebuild
  Log:
  Version bump for misc bug fixes and translation updates
  (Portage version: 2.1.5.3)

Revision  Changes    Path
1.242                app-editors/gedit/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/ChangeLog?rev=1.242&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/ChangeLog?rev=1.242&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/ChangeLog?r1=1.241&r2=1.242

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v
retrieving revision 1.241
retrieving revision 1.242
diff -u -r1.241 -r1.242
--- ChangeLog	29 May 2008 15:35:21 -0000	1.241
+++ ChangeLog	2 Jun 2008 17:57:50 -0000	1.242
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/gedit
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.241 2008/05/29 15:35:21 hawking Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.242 2008/06/02 17:57:50 leio Exp $
+
+*gedit-2.22.3 (02 Jun 2008)
+
+  02 Jun 2008; Mart Raudsepp <leio@g.o> +gedit-2.22.3.ebuild:
+  Version bump for misc bug fixes and translation updates
 
   29 May 2008; Ali Polatel <hawking@g.o> gedit-2.22.0.ebuild,
   gedit-2.22.1.ebuild:



1.1                  app-editors/gedit/gedit-2.22.3.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/gedit-2.22.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/app-editors/gedit/gedit-2.22.3.ebuild?rev=1.1&content-type=text/plain

Index: gedit-2.22.3.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/gedit-2.22.3.ebuild,v 1.1 2008/06/02 17:57:50 leio Exp $

inherit gnome2 python eutils autotools

DESCRIPTION="A text editor for the GNOME desktop"
HOMEPAGE="http://www.gnome.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="doc python spell xattr"

RDEPEND=">=gnome-base/gconf-2
	xattr? ( sys-apps/attr )
	>=dev-libs/glib-2.14
	>=x11-libs/gtk+-2.12
	>=x11-libs/gtksourceview-2.2
	>=gnome-base/libgnomeui-2.16
	>=gnome-base/libglade-2.5.1
	>=gnome-base/gnome-vfs-2.16
	spell? (
		>=app-text/enchant-1.2
		app-text/iso-codes
	)
	python? (
		>=dev-python/pygobject-2.12
		>=dev-python/pygtk-2.12
		>=dev-python/pygtksourceview-2.2
	)"

DEPEND="${RDEPEND}
	sys-devel/gettext
	>=dev-util/pkgconfig-0.9
	>=app-text/scrollkeeper-0.3.11
	>=dev-util/intltool-0.35
	>=app-text/gnome-doc-utils-0.3.2
	gnome-base/gnome-common"
# gnome-common needed to eautoreconf

DOCS="AUTHORS BUGS ChangeLog MAINTAINERS NEWS README"

if [[ "${ARCH}" == "PPC" ]] ; then
	# HACK HACK HACK: someone fix this garbage
	MAKEOPTS="${MAKEOPTS} -j1"
fi

pkg_setup() {
	G2CONF="${G2CONF}
		--disable-scrollkeeper
		$(use_enable python)
		$(use_enable spell)
		$(use_enable xattr attr)"
}

src_unpack() {
	gnome2_src_unpack

	# Remove symbols that are not meant to be part of the docs, and
	# break compilation if USE="doc -python" (bug #158638).
	if use !python && use doc; then
		epatch "${FILESDIR}"/${PN}-2.16.2-no_python_module_docs.patch
	fi

	# chown on fbsd doesn't have --reference.  Bug #183691
	epatch "${FILESDIR}"/${PN}-2.18.1-fbsd.patch

	# fixes failing python test due to libtool 2.2, bug #216110
	epatch "${FILESDIR}/${PN}-2.22.1-fix-libtool-2.2.patch"

	# disable pyc compiling
	mv "${S}"/py-compile "${S}"/py-compile.orig
	ln -s $(type -P true) "${S}"/py-compile

	eautoreconf
}

pkg_postinst() {
	use python && python_mod_optimize /usr/$(get_libdir)/gedit-2/plugins
}

pkg_postrm() {
	use python && python_mod_cleanup /usr/$(get_libdir)/gedit-2/plugins
}



-- 
gentoo-commits@l.g.o mailing list