[gentoo-commits] gentoo-x86 commit in app-emulation/xtrs: metadata.xml ChangeLog xtrs-4.9d-r1.ebuild

[Ulrich Mueller (ulm)]

ulm         12/09/28 20:34:00

  Modified:             metadata.xml ChangeLog
  Added:                xtrs-4.9d-r1.ebuild
  Log:
  Specify LICENSE more precisely. Install non-free LDOS/LS-DOS disk images for Model 4P only with USE=ldos.
  
  (Portage version: 2.1.11.23/cvs/Linux x86_64)

Revision  Changes    Path
1.6                  app-emulation/xtrs/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xtrs/metadata.xml?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xtrs/metadata.xml?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xtrs/metadata.xml?r1=1.5&r2=1.6

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/xtrs/metadata.xml,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- metadata.xml	23 Sep 2011 21:39:53 -0000	1.5
+++ metadata.xml	28 Sep 2012 20:34:00 -0000	1.6
@@ -20,4 +20,7 @@
   Physical cassettes can be read and written too. The user interface is a
   bit spartan, but it gets the job done.
 </longdescription>
+<use>
+  <flag name='ldos'>Install disk images for Model 4P</flag>
+</use>
 </pkgmetadata>



1.40                 app-emulation/xtrs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xtrs/ChangeLog?rev=1.40&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xtrs/ChangeLog?rev=1.40&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xtrs/ChangeLog?r1=1.39&r2=1.40

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/xtrs/ChangeLog,v
retrieving revision 1.39
retrieving revision 1.40
diff -u -r1.39 -r1.40
--- ChangeLog	23 Dec 2010 10:50:25 -0000	1.39
+++ ChangeLog	28 Sep 2012 20:34:00 -0000	1.40
@@ -1,6 +1,13 @@
 # ChangeLog for app-emulation/xtrs
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/xtrs/ChangeLog,v 1.39 2010/12/23 10:50:25 ulm Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/xtrs/ChangeLog,v 1.40 2012/09/28 20:34:00 ulm Exp $
+
+*xtrs-4.9d-r1 (28 Sep 2012)
+
+  28 Sep 2012; Ulrich Müller <ulm@g.o> +xtrs-4.9d-r1.ebuild,
+  metadata.xml:
+  Specify LICENSE more precisely. Install non-free LDOS/LS-DOS disk images for
+  Model 4P only with USE=ldos.
 
   23 Dec 2010; Ulrich Mueller <ulm@g.o> xtrs-4.9d.ebuild:
   Fix bug 337941 properly.



1.1                  app-emulation/xtrs/xtrs-4.9d-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xtrs/xtrs-4.9d-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/xtrs/xtrs-4.9d-r1.ebuild?rev=1.1&content-type=text/plain

Index: xtrs-4.9d-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/xtrs/xtrs-4.9d-r1.ebuild,v 1.1 2012/09/28 20:34:00 ulm Exp $

EAPI=4

inherit flag-o-matic toolchain-funcs

DESCRIPTION="Radio Shack TRS-80 emulator"
HOMEPAGE="http://www.tim-mann.org/xtrs.html"
SRC_URI="http://www.tim-mann.org/trs80/${P}.tar.gz
	ldos? ( http://www.tim-mann.org/trs80/ld4-631.zip )"

LICENSE="xtrs ldos? ( freedist )"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="ldos"

DEPEND="sys-libs/ncurses
	sys-libs/readline
	>=x11-libs/libX11-1.0.0"
RDEPEND="${DEPEND}"

src_prepare() {
	sed -i -e 's/$(CC) -o/$(CC) $(LDFLAGS) -o/' Makefile || die
}

src_compile() {
	use ppc && append-flags -Dbig_endian
	emake CC="$(tc-getCC)" DEBUG="${CFLAGS}" LDFLAGS="${LDFLAGS}" \
		DISKDIR="-DDISKDIR='\"/usr/share/xtrs\"'" \
		DEFAULT_ROM="-DDEFAULT_ROM='\"/usr/share/xtrs/romimage\"' \
			-DDEFAULT_ROM3='\"/usr/share/xtrs/romimage.m3\"' \
			-DDEFAULT_ROM4P='\"/usr/share/xtrs/romimage.m4p\"'"
}

src_install() {
	dodir /usr/bin /usr/share/xtrs/disks /usr/share/man/man1
	emake PREFIX="${D}"/usr install

	insopts -m0444
	insinto /usr/share/xtrs/disks
	doins cpmutil.dsk utility.dsk

	if use ldos; then
		doins "${WORKDIR}"/ld4-631.dsk
		dosym disks/ld4-631.dsk /usr/share/xtrs/disk4p-0
		dosym disks/utility.dsk /usr/share/xtrs/disk4p-1
	fi

	dodoc ChangeLog README xtrsrom4p.README cpmutil.html dskspec.html
}

pkg_postinst() {
	ewarn "For copyright reasons, xtrs does not include actual ROM images."
	ewarn "Because of this, unless you supply your own ROM, xtrs will"
	ewarn "not function in any mode except 'Model 4p' mode (a minimal"
	ewarn "free ROM is included for this), which can be run like this:"
	ewarn "    xtrs -model 4p"
	elog ""
	elog "If you already own a copy of the ROM software (e.g., if you have"
	elog "a TRS-80 with this ROM), then you can make yourself a copy of this"
	elog "for use with xtrs using utilities available on the web.  You can"
	elog "also often find various ROMs elsewhere.  To load your own ROM,"
	elog "specify the '-romfile' option."
}