[gentoo-commits] gentoo-x86 commit in x11-drivers/synaptics: ChangeLog synaptics-0.14.6-r2.ebuild

[Bryan Stine (battousai)]

battousai    08/04/01 23:57:32

  Modified:             ChangeLog
  Added:                synaptics-0.14.6-r2.ebuild
  Log:
  Ebuild r-bump with features to fix bugs #134309, #206614, #215323.
  (Portage version: 2.1.4.4)

Revision  Changes    Path
1.33                 x11-drivers/synaptics/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-drivers/synaptics/ChangeLog?rev=1.33&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-drivers/synaptics/ChangeLog?rev=1.33&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-drivers/synaptics/ChangeLog?r1=1.32&r2=1.33

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-drivers/synaptics/ChangeLog,v
retrieving revision 1.32
retrieving revision 1.33
diff -u -r1.32 -r1.33
--- ChangeLog	24 Feb 2008 02:45:10 -0000	1.32
+++ ChangeLog	1 Apr 2008 23:57:31 -0000	1.33
@@ -1,6 +1,22 @@
 # ChangeLog for x11-drivers/synaptics
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-drivers/synaptics/ChangeLog,v 1.32 2008/02/24 02:45:10 dberkholz Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-drivers/synaptics/ChangeLog,v 1.33 2008/04/01 23:57:31 battousai Exp $
+
+*synaptics-0.14.6-r2 (01 Apr 2008)
+
+  01 Apr 2008; Bryan Stine <battousai@g.o>
+  +files/synaptics-fix-xinerama.patch,
+  +files/synaptics-install-so-exec.patch, +synaptics-0.14.6-r2.ebuild:
+  Ebuild revision bump with a few new features. First, added a patch to
+  driver code to allow the touchpad to interact correctly with multiple
+  screens using Xinerama, fixing bug #206614. Second, added a patch to the
+  Makefile to install the Xorg module as executable to allow the Xorg loader
+  to bring it in automatically, fixing bug #215323. Finally, added
+  linux-info logic to the ebuild to check the kernel config for
+  CONFIG_INPUT_EVDEV (either as a module or built-in) as the driver requires
+  that interface for full support; fixes bug #134309. Revision-bumped the
+  ebuild to ensure the Xinerama and executable patches get pulled onto
+  users' systems.
 
   24 Feb 2008; Donnie Berkholz <dberkholz@g.o>; ChangeLog:
   Update my email.



1.1                  x11-drivers/synaptics/synaptics-0.14.6-r2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-drivers/synaptics/synaptics-0.14.6-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-drivers/synaptics/synaptics-0.14.6-r2.ebuild?rev=1.1&content-type=text/plain

Index: synaptics-0.14.6-r2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-drivers/synaptics/synaptics-0.14.6-r2.ebuild,v 1.1 2008/04/01 23:57:31 battousai Exp $

inherit toolchain-funcs eutils linux-info

IUSE=""

DESCRIPTION="Driver for Synaptics touchpads"
HOMEPAGE="http://w1.894.telia.com/~u89404340/touchpad/"
SRC_URI="http://w1.894.telia.com/~u89404340/touchpad/files/${P}.tar.bz2"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"

RDEPEND="x11-libs/libXext"
DEPEND="${RDEPEND}
	x11-base/xorg-server
	>=sys-apps/sed-4"

evdev-input_check() {
	# Check kernel config for required event interface support (either
	# built-in or as a module. Bug #134309.

	ebegin "Checking kernel config for event device support"
	linux_chkconfig_present INPUT_EVDEV
	eend $?

	if [[ $? -ne 0 ]] ; then
		ewarn "Synaptics driver requires event interface support."
		ewarn "Please enable the event interface in your kernel config."
		ewarn "The option can be found at:"
		ewarn
		ewarn "  Device Drivers"
		ewarn "    Input device support"
		ewarn "      -*- Generic input layer"
		ewarn "        <*> Event interface"
		ewarn
		ewarn "Then rebuild the kernel or install the module."
		epause 5
	fi
}

pkg_setup() {
	linux-info_pkg_setup
	evdev-input_check
}

src_unpack() {
	unpack ${A} ; cd "${S}"

	# Switch up the CC and CFLAGS stuff.
	sed -i \
		-e "s:CC = gcc:CC = $(tc-getCC):g" \
		-e "s:CDEBUGFLAGS = -O2:CDEBUGFLAGS = ${CFLAGS}:g" \
		"${S}"/Makefile

	# Fix grabbing of event devices so it will not stop working together with
	# packages which grab their devices at their own like sys-apps/inputd does.
	epatch "${FILESDIR}"/synaptics-fixeventgrab.diff

	epatch "${FILESDIR}"/synaptics_input_api.diff

	# Patch the Makefile to install the library as executable. Bug #215323.
	epatch "${FILESDIR}"/synaptics-install-so-exec.patch

	# Fix to handle multiple screens through Xinerama properly. Bug #206614.
	epatch "${FILESDIR}"/synaptics-fix-xinerama.patch
}

src_compile() {
	emake || die
}

src_install() {
	make \
		DESTDIR="${D}" \
		PREFIX=/usr \
		MANDIR="${D}"/usr/share/man \
		install || die

	dodoc script/usbmouse script/usbhid alps.patch trouble-shooting.txt
	dodoc COMPATIBILITY FILES INSTALL* NEWS TODO README*

	# Stupid new daemon, didn't work for me because of shm issues
	newinitd "${FILESDIR}"/rc.init syndaemon
	newconfd "${FILESDIR}"/rc.conf syndaemon
}



-- 
gentoo-commits@l.g.o mailing list