[gentoo-commits] repo/gentoo:master commit in: net-mail/notmuch/

[Amadeusz Piotr Żołnowski]

commit:     40e420de0e057ccf087ae3e5e7079c91d326e95d
Author:     Amadeusz Żołnowski <aidecoe <AT> gentoo <DOT> org>
AuthorDate: Sun Aug 27 22:31:56 2017 +0000
Commit:     Amadeusz Piotr Żołnowski <aidecoe <AT> gentoo <DOT> org>
CommitDate: Sun Aug 27 22:31:56 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=40e420de

net-mail/notmuch: Bump version

Package-Manager: Portage-2.3.7, Repoman-2.3.3

 net-mail/notmuch/Manifest            |   1 +
 net-mail/notmuch/notmuch-0.25.ebuild | 206 +++++++++++++++++++++++++++++++++++
 2 files changed, 207 insertions(+)

diff --git a/net-mail/notmuch/Manifest b/net-mail/notmuch/Manifest
index 9e2791f4b31..97358714fc1 100644
--- a/net-mail/notmuch/Manifest
+++ b/net-mail/notmuch/Manifest
@@ -2,3 +2,4 @@ DIST database-v1.tar.xz 204876 SHA256 4299e051b10e1fa7b33ea2862790a09ebfe9685968
 DIST notmuch-0.23.7.tar.gz 692230 SHA256 f11bb10d71945f6c3f16d23117afc70810aa485878e66bb4bf43cc3f08038913 SHA512 e71da3bd6ce1b344aae79b277b695a4668d4fe1b8838618d6970a0b27df9867bac66a3240473ef31fc30ed8af2b0a558203ed5ffb34da873c991b1ecc6c08522 WHIRLPOOL 0b14cd6fb2b584b27b7893bb9c45724725069a6bc980cfe52f80ec3f6ec95c3a8f631975875f44b46b2799d5a0c31a62ff845b2400b7389cd8aa6f55361a0851
 DIST notmuch-0.24.1.tar.gz 709190 SHA256 fa117de2c6096dd896a333b9c770572a939e04a02abe6745b6b07f5363063ca3 SHA512 e2014380de68de3e1a3fd3058a441c6771a92bfffe07c0bd2b374802dd8b2539eddbbb91074738f58f48452a936f2f9427fadca825a165c61a27fe0c3e1fe7fc WHIRLPOOL 75904127fb33ce011aaa22a1c86ac58375c1f8881a1cf384254d5adb7c13316c28436d622c760d8dec150b7442ded475b6f80c5991c5654ca418cd875e9a743b
 DIST notmuch-0.24.2.tar.gz 709272 SHA256 aa76a96684d5c5918d940182b6fe40f7d6745f144476fdda57388479d586cc51 SHA512 fcdc4ad5a65c57dd3077d93aeb384378f8dee105362fa8c2755daf14bbeb5376f8d1580fd79c8bd8e8d2d88cd44846ca9972b2f942133a447eb99d08ef9056dc WHIRLPOOL 679094ca2bd57a3b2f0f4ae5f2022c8bd1922e55fb095780b67de13c75758b4daa5892843e187405f294ed406ce47922bd6b854759984c5518bad8dc058236a6
+DIST notmuch-0.25.tar.gz 882093 SHA256 65d28d1f783d02629039f7d15d9a2bada147a7d3809f86fe8d13861b0f6ae60b SHA512 5f4961818c8c0350e3fbbedd86f407a55fecf211971003a770d99ea2db89bb6b98c2294e114d6abff4d40985f506b7f4b52736a7ee5c78390eb4f2363a65c6f5 WHIRLPOOL 94ec2cb30c92b8c88da9b66f2a8afa7c01977671cdc018113a1716414a8555a9bec7d77b933df6dd4c3c339e3a2dfd46319f86725f1b84b608e7066c60b91f1c

diff --git a/net-mail/notmuch/notmuch-0.25.ebuild b/net-mail/notmuch/notmuch-0.25.ebuild
new file mode 100644
index 00000000000..a40a43dd00f
--- /dev/null
+++ b/net-mail/notmuch/notmuch-0.25.ebuild
@@ -0,0 +1,206 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit bash-completion-r1 elisp-common eutils flag-o-matic pax-utils \
+	distutils-r1 toolchain-funcs
+
+DESCRIPTION="Thread-based e-mail indexer, supporting quick search and tagging"
+HOMEPAGE="http://notmuchmail.org/"
+SRC_URI="${HOMEPAGE%/}/releases/${P}.tar.gz
+	test? ( ${HOMEPAGE%/}/releases/test-databases/database-v1.tar.xz )"
+
+LICENSE="GPL-3"
+# Sub-slot corresponds to major wersion of libnotmuch.so.X.Y.  Bump of Y is
+# meant to be binary backward compatible.
+SLOT="0/5"
+KEYWORDS="~alpha ~amd64 ~x86"
+REQUIRED_USE="
+	nmbug? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	test? ( crypt emacs python valgrind )
+	"
+IUSE="crypt doc emacs mutt nmbug python test valgrind"
+
+CDEPEND="
+	!!<app-shells/bash-completion-1.9
+	>=dev-libs/glib-2.22:2
+	>=dev-libs/gmime-2.6.20-r2:2.6
+	>=dev-libs/xapian-1.2.7-r2:=
+	dev-python/sphinx[${PYTHON_USEDEP}]
+	>=sys-libs/zlib-1.2.5.2
+	sys-libs/talloc
+	crypt? ( >=dev-libs/gmime-2.6.20-r2:2.6[smime] )
+	emacs? ( >=virtual/emacs-23 )
+	python? ( ${PYTHON_DEPS} )
+	"
+DEPEND="${CDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( app-misc/dtach || ( >=app-editors/emacs-23[libxml2]
+		>=app-editors/emacs-vcs-23[libxml2] ) sys-devel/gdb
+		crypt? ( app-crypt/gnupg dev-libs/openssl ) )
+	valgrind? ( dev-util/valgrind )
+	"
+RDEPEND="${CDEPEND}
+	crypt? ( app-crypt/gnupg )
+	nmbug? ( dev-vcs/git )
+	mutt? ( dev-perl/File-Which dev-perl/Mail-Box dev-perl/MailTools
+		dev-perl/String-ShellQuote dev-perl/Term-ReadLine-Gnu
+		virtual/perl-Digest-SHA virtual/perl-File-Path virtual/perl-Getopt-Long
+		virtual/perl-Pod-Parser )
+	"
+
+DOCS=( AUTHORS NEWS README )
+SITEFILE="50${PN}-gentoo.el"
+MY_LD_LIBRARY_PATH="${WORKDIR}/${P}/lib"
+
+bindings() {
+	local ret=0
+
+	if use $1; then
+		pushd bindings/$1 || die
+		shift
+		"$@"
+		ret=$?
+		popd || die
+	fi
+
+	return $ret
+}
+
+pkg_pretend() {
+	if has_version '<net-mail/notmuch-0.18'; then
+		ewarn
+		ewarn "There are few not backward compatible changes between"
+		ewarn "<notmuch-0.18 and >=notmuch-0.18.  See NEWS file"
+		ewarn "(0.18 section) for details before first use!"
+		ewarn
+	fi
+}
+
+pkg_setup() {
+	if use emacs; then
+		elisp-need-emacs 23 || die "Emacs version too low"
+	fi
+}
+
+src_unpack() {
+	unpack "${P}".tar.gz
+	if use test; then
+		mkdir -p "${S}"/test/test-databases || die
+		cp "${DISTDIR}"/database-v1.tar.xz "${S}"/test/test-databases/ || die
+	fi
+}
+
+src_prepare() {
+	default
+
+	bindings python distutils-r1_src_prepare
+	bindings python mv README README-python || die
+	mv contrib/notmuch-mutt/README contrib/notmuch-mutt/README-mutt || die
+
+	# assure that new Makefile.config will be generated
+	rm -f Makefile.config || die
+
+	if use test; then
+		append-cflags -g
+		append-cxxflags -g
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		--bashcompletiondir="$(get_bashcompdir)"
+		--emacslispdir="${EPREFIX}/${SITELISP}/${PN}"
+		--emacsetcdir="${EPREFIX}/${SITEETC}/${PN}"
+		--without-desktop
+		--without-ruby
+		--zshcompletiondir="${EPREFIX}/usr/share/zsh/site-functions"
+		$(use_with emacs)
+		$(use_with doc api-docs)
+	)
+	tc-export CC CXX
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	V=1 default
+	bindings python distutils-r1_src_compile
+
+	if use mutt; then
+		pushd contrib/notmuch-mutt || die
+		emake notmuch-mutt.1
+		popd || die
+	fi
+
+	if use doc; then
+		pydocs() {
+			pushd docs || die
+			emake html
+			rm -r html/_sources || die
+			rm html/{objects.inv,.buildinfo} || die
+			mkdir -p ../html && mv html ../html/python || die
+			popd || die
+		}
+		LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" bindings python pydocs
+	fi
+}
+
+src_test() {
+	pax-mark -m notmuch
+	LD_LIBRARY_PATH="${MY_LD_LIBRARY_PATH}" V=1 default
+	pax-mark -ze notmuch
+}
+
+src_install() {
+	default
+
+	if use emacs; then
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die
+	fi
+
+	if use nmbug; then
+		dobin devel/nmbug/nmbug
+		dobin devel/nmbug/notmuch-report
+	fi
+
+	if use mutt; then
+		pushd contrib/notmuch-mutt || die
+		dobin notmuch-mutt
+		doman notmuch-mutt.1
+		insinto /etc/mutt
+		doins notmuch-mutt.rc
+		dodoc README-mutt
+		popd || die
+	fi
+
+	DOCS="" bindings python distutils-r1_src_install
+	use doc && bindings python dodoc -r html
+}
+
+pkg_preinst() {
+	if use mutt && ! [[ -e ${ROOT}/etc/mutt/notmuch-mutt.rc ]]; then
+		elog "To enable notmuch support in mutt, add the following line into"
+		elog "your mutt config file, please:"
+		elog ""
+		elog "  source /etc/mutt/notmuch-mutt.rc"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+
+	if has_version '<dev-libs/xapian-1.4'; then
+		elog "Regular expression searches supported for from: and subject:"
+		elog "require >=dev-libs/xapian-1.4."
+	fi
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}