[gentoo-commits] gentoo-x86 commit in x11-terms/mlterm: mlterm-2.9.4-r4.ebuild ChangeLog

[Matsuu Takuto (matsuu)]

matsuu      09/07/01 14:06:19

  Modified:             ChangeLog
  Added:                mlterm-2.9.4-r4.ebuild
  Log:
  Added 256 color patch.
  (Portage version: 2.1.6.13/cvs/Linux x86_64)

Revision  Changes    Path
1.65                 x11-terms/mlterm/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/mlterm/ChangeLog?rev=1.65&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/mlterm/ChangeLog?rev=1.65&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/mlterm/ChangeLog?r1=1.64&r2=1.65

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-terms/mlterm/ChangeLog,v
retrieving revision 1.64
retrieving revision 1.65
diff -u -r1.64 -r1.65
--- ChangeLog	30 Sep 2008 16:24:04 -0000	1.64
+++ ChangeLog	1 Jul 2009 14:06:18 -0000	1.65
@@ -1,6 +1,11 @@
 # ChangeLog for x11-terms/mlterm
-# Copyright 2002-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/mlterm/ChangeLog,v 1.64 2008/09/30 16:24:04 matsuu Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/mlterm/ChangeLog,v 1.65 2009/07/01 14:06:18 matsuu Exp $
+
+*mlterm-2.9.4-r4 (01 Jul 2009)
+
+  01 Jul 2009; MATSUU Takuto <matsuu@g.o> +mlterm-2.9.4-r4.ebuild:
+  Added 256 color patch.
 
 *mlterm-2.9.4-r3 (30 Sep 2008)
 



1.1                  x11-terms/mlterm/mlterm-2.9.4-r4.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/mlterm/mlterm-2.9.4-r4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/x11-terms/mlterm/mlterm-2.9.4-r4.ebuild?rev=1.1&content-type=text/plain

Index: mlterm-2.9.4-r4.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-terms/mlterm/mlterm-2.9.4-r4.ebuild,v 1.1 2009/07/01 14:06:18 matsuu Exp $

inherit eutils toolchain-funcs

IUSE="truetype gtk imlib bidi nls uim scim m17n-lib"
#IUSE="${IUSE} iiimf"

DESCRIPTION="A multi-lingual terminal emulator"
HOMEPAGE="http://mlterm.sourceforge.net/"
SRC_URI="mirror://sourceforge/mlterm/${P}.tar.gz
	http://shinh.skr.jp/dat_dir/${P}_256.patch"

SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
LICENSE="BSD"

RDEPEND="virtual/utempter
	x11-libs/libX11
	x11-libs/libICE
	x11-libs/libSM
	gtk? ( >=x11-libs/gtk+-2 )
	!gtk? ( imlib? ( >=media-libs/imlib-1.9.14 ) )
	truetype? ( x11-libs/libXft )
	bidi? ( >=dev-libs/fribidi-0.10.4 )
	nls? ( virtual/libintl )
	uim? ( >=app-i18n/uim-1.0 )
	scim? ( >=app-i18n/scim-1.4 )
	m17n-lib? ( >=dev-libs/m17n-lib-1.2.0 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	nls? ( sys-devel/gettext )"

src_unpack() {
	unpack ${A}
	cd "${S}"
	epatch "${FILESDIR}"/${P}-uim15-fix.patch
	epatch "${DISTDIR}"/${P}_256.patch
	cd "${S}"/xwindow
	epatch "${FILESDIR}"/${PN}-2.9.1-gentoo.diff
	epatch "${FILESDIR}"/${PN}-2.9.3-asneeded.diff
}

src_compile() {
	local myconf

	if use gtk ; then
		myconf="${myconf} --with-imagelib=gdk-pixbuf"
	else
		if use imlib ; then
			myconf="${myconf} --with-imagelib=imlib"
		else
			myconf="${myconf} --with-imagelib=''"
		fi
		myconf="${myconf} --with-tools=mlclient,mlcc"
	fi

	# iiimf isn't stable enough
	#myconf="${myconf} $(use_enable iiimf)"

	econf --enable-utmp \
		$(use_enable truetype anti-alias) \
		$(use_enable bidi fribidi) \
		$(use_enable nls) \
		$(use_enable uim) \
		$(use_enable scim) \
		$(use_enable m17n-lib m17nlib) \
		${myconf} || die "econf failed"
	emake CC="$(tc-getCC)" || die "emake failed"
}

src_install () {
	emake DESTDIR="${D}" install || die

	dodoc ChangeLog README

	docinto ja
	dodoc doc/ja/*
	docinto en
	dodoc doc/en/*
}