[gentoo-commits] gentoo-x86 commit in games-util/pyfa: ChangeLog pyfa-1.1.6.ebuild pyfa-1.1.4-r1.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    12/05/02 05:12:05

  Modified:             ChangeLog
  Added:                pyfa-1.1.6.ebuild
  Removed:              pyfa-1.1.4-r1.ebuild
  Log:
  Version bump with updates for Escalation to Inferno. Drop old.
  
  (Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

Revision  Changes    Path
1.10                 games-util/pyfa/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/ChangeLog?rev=1.10&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/ChangeLog?rev=1.10&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/ChangeLog?r1=1.9&r2=1.10

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-util/pyfa/ChangeLog,v
retrieving revision 1.9
retrieving revision 1.10
diff -u -r1.9 -r1.10
--- ChangeLog	3 Apr 2012 15:40:48 -0000	1.9
+++ ChangeLog	2 May 2012 05:12:05 -0000	1.10
@@ -1,6 +1,12 @@
 # ChangeLog for games-util/pyfa
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-util/pyfa/ChangeLog,v 1.9 2012/04/03 15:40:48 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-util/pyfa/ChangeLog,v 1.10 2012/05/02 05:12:05 tetromino Exp $
+
+*pyfa-1.1.6 (02 May 2012)
+
+  02 May 2012; Alexandre Rostovtsev <tetromino@g.o>
+  -pyfa-1.1.4-r1.ebuild, +pyfa-1.1.6.ebuild:
+  Version bump with updates for Escalation to Inferno. Drop old.
 
 *pyfa-1.1.5 (03 Apr 2012)
 



1.1                  games-util/pyfa/pyfa-1.1.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/pyfa-1.1.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/pyfa-1.1.6.ebuild?rev=1.1&content-type=text/plain

Index: pyfa-1.1.6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-util/pyfa/pyfa-1.1.6.ebuild,v 1.1 2012/05/02 05:12:05 tetromino Exp $

EAPI="4"
PYTHON_DEPEND="2:2.6"
PYTHON_USE_WITH="sqlite threads"

inherit eutils gnome2-utils python

if [[ ${PV/_rc*/} == ${PV} ]] ; then
	MY_PV=${PV}-escalation-src
	FOLDER=stable/${PV}
else
	MY_PV=${PV/_rc/-stable-RC}-src
	FOLDER=stable/${PV/*_rc/RC}
fi

DESCRIPTION="Python Fitting Assistant - a ship fitting application for EVE Online"
HOMEPAGE="http://www.evefit.org/Pyfa"
SRC_URI="http://dl.evefit.org/${FOLDER}/${PN}-${MY_PV}.tar.bz2"

LICENSE="GPL-3 LGPL-2.1 CCPL-Attribution-2.5 free-noncomm"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+graph"

RDEPEND="dev-python/sqlalchemy
	dev-python/wxpython:2.8
	graph? ( dev-python/matplotlib[wxwidgets] dev-python/numpy )"
DEPEND=""

S=${WORKDIR}/${PN}

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	# make staticPath settable from configforced again
	epatch "${FILESDIR}/${PN}-1.1-staticPath.patch"

	# use correct slot of wxpython, http://trac.evefit.org/ticket/475
	epatch "${FILESDIR}/${PN}-1.1.4-wxversion.patch"

	python_convert_shebangs -r -x 2 .
	sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
		-e "s:%%EPREFIX%%:${EPREFIX}:" \
		"${FILESDIR}/configforced.py" > configforced.py
}

src_install() {
	local packagedir=$(python_get_sitedir)/${PN}
	insinto "${packagedir}"
	doins -r eos gui icons service config*.py info.py gpl.txt
	exeinto "${packagedir}"
	doexe ${PN}.py
	dosym "${packagedir}/${PN}.py" /usr/bin/${PN}
	insinto /usr/share/${PN}
	doins -r staticdata
	dodoc readme.txt
	insinto /usr/share/icons/hicolor/32x32/apps
	doins icons/pyfa.png
	insinto /usr/share/icons/hicolor/64x64/apps
	newins icons/pyfa64.png pyfa.png
	domenu "${FILESDIR}/${PN}.desktop"
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	gnome2_icon_cache_update
	python_mod_optimize ${PN}
}

pkg_postrm() {
	gnome2_icon_cache_update
	python_mod_cleanup ${PN}
}