[gentoo-commits] gentoo-x86 commit in games-strategy/freecol: ChangeLog freecol-0.7.2.ebuild

[Tristan Heaven (nyhm)]

nyhm        07/09/19 22:41:41

  Modified:             ChangeLog
  Added:                freecol-0.7.2.ebuild
  Log:
  Version bump
  (Portage version: 2.1.3.9)

Revision  Changes    Path
1.24                 games-strategy/freecol/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/freecol/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/freecol/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/freecol/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-strategy/freecol/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog	6 Sep 2007 06:18:00 -0000	1.23
+++ ChangeLog	19 Sep 2007 22:41:41 -0000	1.24
@@ -1,6 +1,12 @@
 # ChangeLog for games-strategy/freecol
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-strategy/freecol/ChangeLog,v 1.23 2007/09/06 06:18:00 opfer Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-strategy/freecol/ChangeLog,v 1.24 2007/09/19 22:41:41 nyhm Exp $
+
+*freecol-0.7.2 (19 Sep 2007)
+
+  19 Sep 2007; Tristan Heaven <nyhm@g.o>
+  +files/freecol-0.7.2-home.patch, +freecol-0.7.2.ebuild:
+  Version bump
 
   06 Sep 2007; Christian Faulhammer <opfer@g.o> freecol-0.7.1.ebuild:
   stable x86, bug 190643



1.1                  games-strategy/freecol/freecol-0.7.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/freecol/freecol-0.7.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/games-strategy/freecol/freecol-0.7.2.ebuild?rev=1.1&content-type=text/plain

Index: freecol-0.7.2.ebuild
===================================================================
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-strategy/freecol/freecol-0.7.2.ebuild,v 1.1 2007/09/19 22:41:41 nyhm Exp $

WANT_ANT_TASKS="ant-nodeps"

inherit eutils java-pkg-2 java-ant-2 games

DESCRIPTION="An open source clone of the game Colonization"
HOMEPAGE="http://www.freecol.org/"
SRC_URI="mirror://sourceforge/${PN}/${P}-src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"

RDEPEND="dev-java/higlayout"
DEPEND="${RDEPEND}
	test? (
		dev-java/ant-junit
		dev-java/ant-trax
	)
	>=virtual/jdk-1.6"
RDEPEND="${RDEPEND}
	>=virtual/jre-1.6"

S=${WORKDIR}/${PN}

pkg_setup() {
	games_pkg_setup
	java-pkg-2_pkg_setup
}

src_unpack() {
	unpack ${A}
	cd "${S}"
	rm -v FreeCol.jar jars/* */*/*.jar || die

	epatch "${FILESDIR}"/${P}-home.patch

	sed -i "/Class-Path/s:jars/.*$:$(java-pkg_getjars higlayout):" \
		src/MANIFEST.MF \
		|| die "sed failed"

	cd jars
	java-pkg_jar-from higlayout
}

# Default would be from games
src_compile() {
	eant
}

src_test() {
	java-pkg_jar-from --into test/lib junit
	ANT_TASKS="ant-junit ant-trax ant-nodeps" eant testall
}

src_install () {
	insinto "${GAMES_DATADIR}"/${PN}
	doins -r data || die "doins failed"

	java-pkg_jarinto "${GAMES_DATADIR}"/${PN}
	java-pkg_dojar FreeCol.jar

	java-pkg_dolauncher ${PN} \
		-into "${GAMES_PREFIX}" \
		--pwd "${GAMES_DATADIR}"/${PN} \
		--java_args -Xmx512M

	dodoc README
	doicon ${PN}.xpm
	make_desktop_entry ${PN} FreeCol ${PN}.xpm
	prepgamesdirs
}



-- 
gentoo-commits@g.o mailing list