[gentoo-commits] gentoo-x86 commit in sys-apps/portage: ChangeLog portage-2.2_rc34.ebuild

[Zac Medico (zmedico)]

zmedico     09/08/03 22:55:36

  Modified:             ChangeLog
  Added:                portage-2.2_rc34.ebuild
  Log:
  03 Aug 2009; Zac Medico <zmedico@g.o> +portage-2.2_rc34.ebuild:
  2.2_rc34 bump. This fixes bug #82488 (problem in evaluation of conditional
  PROVIDE), bug #137562 (backtracking for unsatisfied deps), bug #236786
  (repoman warning for test useflag in RDEPEND), bug #253467 (fix possible
  interference with portage environment variables), bug #258684 (move sandbox
  variables from ebuild.sh), bug #264434 (lazy evaluation of || deps),
  bug #268929 (strict-aliasing check for gcc 4.4), bug #270040 (fix repoman
  to handle overlay categories), bug #270658 (fix usev to comply with PMS),
  bug #270953 (fix !!atom blockers to work for package is same slot),
  bug #272063 (fix docbook xml to work with xmlto-0.0.22), bug #273020
  (document FEATURES=multilib-strict), bug #274279 (color.map support for
  color=color), bug #274742 (remove repoman quoting check for "dir" variable,
  bug #275047 (split _emerge python module), bug #275217 (backtracking for
  slot conflicts), bug #275796 (make || deps prefer packages in graph over
  installed packages), bug #275821 (make emerge reject !!atom blockers for
  old EAPIs), bug #275901 (make emerge reject USE deps for old EAPIs),
  bug #275945 (make emerge avoid updates unless --update is enabled),
  bug #275947 (enable build.log on selinux), bug #276264 (document cache
  issues with eclass-overrides), bug #276813 (performance improvements),
  bug #276866 (--binpkg-respect-use option), and bug #278729 (prevent
  interaction between || deps and unsatisfied USE deps).
  (Portage version: 2.2_rc34/cvs/Linux i686)

Revision  Changes    Path
1.620                sys-apps/portage/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/portage/ChangeLog?rev=1.620&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/portage/ChangeLog?rev=1.620&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/portage/ChangeLog?r1=1.619&r2=1.620

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/portage/ChangeLog,v
retrieving revision 1.619
retrieving revision 1.620
diff -u -r1.619 -r1.620
--- ChangeLog	2 Aug 2009 19:51:34 -0000	1.619
+++ ChangeLog	3 Aug 2009 22:55:35 -0000	1.620
@@ -1,6 +1,30 @@
 # ChangeLog for sys-apps/portage
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/portage/ChangeLog,v 1.619 2009/08/02 19:51:34 zmedico Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/portage/ChangeLog,v 1.620 2009/08/03 22:55:35 zmedico Exp $
+
+*portage-2.2_rc34 (03 Aug 2009)
+
+  03 Aug 2009; Zac Medico <zmedico@g.o> +portage-2.2_rc34.ebuild:
+  2.2_rc34 bump. This fixes bug #82488 (problem in evaluation of conditional
+  PROVIDE), bug #137562 (backtracking for unsatisfied deps), bug #236786
+  (repoman warning for test useflag in RDEPEND), bug #253467 (fix possible
+  interference with portage environment variables), bug #258684 (move sandbox
+  variables from ebuild.sh), bug #264434 (lazy evaluation of || deps),
+  bug #268929 (strict-aliasing check for gcc 4.4), bug #270040 (fix repoman
+  to handle overlay categories), bug #270658 (fix usev to comply with PMS),
+  bug #270953 (fix !!atom blockers to work for package is same slot),
+  bug #272063 (fix docbook xml to work with xmlto-0.0.22), bug #273020
+  (document FEATURES=multilib-strict), bug #274279 (color.map support for
+  color=color), bug #274742 (remove repoman quoting check for "dir" variable,
+  bug #275047 (split _emerge python module), bug #275217 (backtracking for
+  slot conflicts), bug #275796 (make || deps prefer packages in graph over
+  installed packages), bug #275821 (make emerge reject !!atom blockers for
+  old EAPIs), bug #275901 (make emerge reject USE deps for old EAPIs),
+  bug #275945 (make emerge avoid updates unless --update is enabled),
+  bug #275947 (enable build.log on selinux), bug #276264 (document cache
+  issues with eclass-overrides), bug #276813 (performance improvements),
+  bug #276866 (--binpkg-respect-use option), and bug #278729 (prevent
+  interaction between || deps and unsatisfied USE deps).
 
   02 Aug 2009; Zac Medico <zmedico@g.o> portage-2.1.6.13.ebuild,
   portage-2.2_rc33.ebuild:



1.1                  sys-apps/portage/portage-2.2_rc34.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/portage/portage-2.2_rc34.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/sys-apps/portage/portage-2.2_rc34.ebuild?rev=1.1&content-type=text/plain

Index: portage-2.2_rc34.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/portage/portage-2.2_rc34.ebuild,v 1.1 2009/08/03 22:55:36 zmedico Exp $

inherit eutils multilib python

DESCRIPTION="Portage is the package management and distribution system for Gentoo"
HOMEPAGE="http://www.gentoo.org/proj/en/portage/index.xml"
LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~sparc-fbsd ~x86 ~x86-fbsd"
PROVIDE="virtual/portage"
SLOT="0"
IUSE="build doc epydoc selinux linguas_pl"

python_dep=">=dev-lang/python-2.5 <dev-lang/python-3.0"

DEPEND="${python_dep}
	!build? ( >=sys-apps/sed-4.0.5 )
	doc? ( app-text/xmlto ~app-text/docbook-xml-dtd-4.4 )
	epydoc? ( >=dev-python/epydoc-2.0 )"
RDEPEND="${python_dep}
	!build? ( >=sys-apps/sed-4.0.5
		>=app-shells/bash-3.2_p17
		|| ( >=app-admin/eselect-news-20071201 >=app-admin/eselect-1.1 ) )
	elibc_FreeBSD? ( sys-freebsd/freebsd-bin )
	elibc_glibc? ( >=sys-apps/sandbox-1.6 )
	elibc_uclibc? ( >=sys-apps/sandbox-1.6 )
	>=app-misc/pax-utils-0.1.17
	selinux? ( >=dev-python/python-selinux-2.16 )"
PDEPEND="
	!build? (
		>=net-misc/rsync-2.6.4
		userland_GNU? ( >=sys-apps/coreutils-6.4 )
	)"
# coreutils-6.4 rdep is for date format in emerge-webrsync #164532
# rsync-2.6.4 rdep is for the --filter option #167668

SRC_ARCHIVES="http://dev.gentoo.org/~zmedico/portage/archives"

prefix_src_archives() {
	local x y
	for x in ${@}; do
		for y in ${SRC_ARCHIVES}; do
			echo ${y}/${x}
		done
	done
}

PV_PL="2.1.2"
PATCHVER_PL=""
TARBALL_PV=$PV
SRC_URI="mirror://gentoo/${PN}-${TARBALL_PV}.tar.bz2
	$(prefix_src_archives ${PN}-${TARBALL_PV}.tar.bz2)
	linguas_pl? ( mirror://gentoo/${PN}-man-pl-${PV_PL}.tar.bz2
		$(prefix_src_archives ${PN}-man-pl-${PV_PL}.tar.bz2) )"

PATCHVER=
if [ -n "${PATCHVER}" ]; then
	SRC_URI="${SRC_URI} mirror://gentoo/${PN}-${PATCHVER}.patch.bz2
	$(prefix_src_archives ${PN}-${PATCHVER}.patch.bz2)"
fi

S="${WORKDIR}"/${PN}-${TARBALL_PV}
S_PL="${WORKDIR}"/${PN}-${PV_PL}

src_unpack() {
	unpack ${A}
	cd "${S}"
	if [ -n "${PATCHVER}" ]; then
		cd "${S}"
		epatch "${WORKDIR}/${PN}-${PATCHVER}.patch"
	fi
	einfo "Setting portage.VERSION to ${PVR} ..."
	sed -i "s/^VERSION=.*/VERSION=\"${PVR}\"/" pym/portage/__init__.py || \
		die "Failed to patch portage.VERSION"
}

src_compile() {

	if use doc; then
		cd "${S}"/doc
		touch fragment/date
		# Workaround for bug #272063, remove in next portage release.
		sed 's:^XMLTO_FLAGS =:XMLTO_FLAGS = --skip-validation:' -i Makefile
		make xhtml xhtml-nochunks || die "failed to make docs"
	fi

	if use epydoc; then
		einfo "Generating api docs"
		mkdir "${WORKDIR}"/api
		local my_modules epydoc_opts=""
		# A name collision between the portage.dbapi class and the
		# module with the same name triggers an epydoc crash unless
		# portage.dbapi is excluded from introspection.
		ROOT=/ has_version '>=dev-python/epydoc-3_pre0' && \
			epydoc_opts='--exclude-introspect portage\.dbapi'
		my_modules="$(find "${S}/pym" -name "*.py" \
			| sed -e 's:/__init__.py$::' -e 's:\.py$::' -e "s:^${S}/pym/::" \
			 -e 's:/:.:g' | sort)" || die "error listing modules"
		PYTHONPATH="${S}/pym:${PYTHONPATH}" epydoc -o "${WORKDIR}"/api \
			-qqqqq --no-frames --show-imports $epydoc_opts \
			--name "${PN}" --url "${HOMEPAGE}" \
			${my_modules} || die "epydoc failed"
	fi
}

src_test() {
	./pym/portage/tests/runTests || \
		die "test(s) failed"
}

src_install() {
	local libdir=$(get_libdir)
	local portage_base="/usr/${libdir}/portage"
	local portage_share_config=/usr/share/portage/config

	cd "${S}"/cnf
	insinto /etc
	doins etc-update.conf dispatch-conf.conf

	dodir "${portage_share_config}"
	insinto "${portage_share_config}"
	doins "${S}/cnf/"{sets.conf,make.globals}
	if [ -f "make.conf.${ARCH}".diff ]; then
		patch make.conf "make.conf.${ARCH}".diff || \
			die "Failed to patch make.conf.example"
		newins make.conf make.conf.example
	else
		eerror ""
		eerror "Portage does not have an arch-specific configuration for this arch."
		eerror "Please notify the arch maintainer about this issue. Using generic."
		eerror ""
		newins make.conf make.conf.example
	fi

	dosym ..${portage_share_config}/make.globals /etc/make.globals

	insinto /etc/logrotate.d
	doins "${S}"/cnf/logrotate.d/elog-save-summary

	# BSD and OSX need a sed wrapper so that find/xargs work properly
	if use userland_GNU; then
		rm "${S}"/bin/ebuild-helpers/sed || die "Failed to remove sed wrapper"
	fi

	for x in $(find "$S"/bin -type d) ; do
		x=${x#$S/}
		dodir $portage_base/$x || die "dodir failed"
		exeinto $portage_base/$x || die "exeinto failed"
		cd "$S"/$x || die "cd failed"
		doexe $(find . -mindepth 1 -maxdepth 1 -type f ! -type l) || \
			die "doexe failed"
		symlinks=$(find . -mindepth 1 -maxdepth 1 -type l)
		if [ -n "$symlinks" ] ; then
			cp -P $symlinks "$D$portage_base/$x" || die "cp failed"
		fi
	done

	for x in $(find "$S"/pym -type d) ; do
		x=${x#$S/}
		dodir $portage_base/$x || die "dodir failed"
		insinto $portage_base/$x || die "insinto failed"
		cd "$S"/$x || die "cd failed"
		doins *.py || die "doins failed"
		symlinks=$(find . -mindepth 1 -maxdepth 1 -type l)
		if [ -n "$symlinks" ] ; then
			cp -P $symlinks "$D$portage_base/$x" || die "cp failed"
		fi
	done

	# Symlinks to directories cause up/downgrade issues and the use of these
	# modules outside of portage is probably negligible.
	for x in "${D}${portage_base}/pym/"{cache,elog_modules} ; do
		[ ! -L "${x}" ] && continue
		die "symlink to directory will cause upgrade/downgrade issues: '${x}'"
	done

	exeinto ${portage_base}/pym/portage/tests
	doexe  "${S}"/pym/portage/tests/runTests

	doman "${S}"/man/*.[0-9]
	if use linguas_pl; then
		doman -i18n=pl "${S_PL}"/man/pl/*.[0-9]
		doman -i18n=pl_PL.UTF-8 "${S_PL}"/man/pl_PL.UTF-8/*.[0-9]
	fi

	dodoc "${S}"/{ChangeLog,NEWS,RELEASE-NOTES}
	use doc && dohtml -r "${S}"/doc/*
	use epydoc && dohtml -r "${WORKDIR}"/api

	dodir /usr/bin
	for x in ebuild egencache emerge portageq repoman xpak; do
		dosym ../${libdir}/portage/bin/${x} /usr/bin/${x}
	done

	dodir /usr/sbin
	local my_syms="archive-conf
		dispatch-conf
		emaint
		emerge-webrsync
		env-update
		etc-update
		fixpackages
		quickpkg
		regenworld"
	local x
	for x in ${my_syms}; do
		dosym ../${libdir}/portage/bin/${x} /usr/sbin/${x}
	done
	dosym env-update /usr/sbin/update-env
	dosym etc-update /usr/sbin/update-etc

	dodir /etc/portage
	keepdir /etc/portage
}

pkg_preinst() {
	if ! use build && ! has_version dev-python/pycrypto && \
		has_version '>=dev-lang/python-2.5' ; then
		if ! built_with_use '>=dev-lang/python-2.5' ssl ; then
			ewarn "If you are an ebuild developer and you plan to commit ebuilds"
			ewarn "with this system then please install dev-python/pycrypto or"
			ewarn "enable the ssl USE flag for >=dev-lang/python-2.5 in order"
			ewarn "to enable RMD160 hash support."
			ewarn "See bug #198398 for more information."
		fi
	fi
	if [ -f "${ROOT}/etc/make.globals" ]; then
		rm "${ROOT}/etc/make.globals"
	fi

	has_version "<${CATEGORY}/${PN}-2.2_alpha"
	MINOR_UPGRADE=$?

	has_version "<=${CATEGORY}/${PN}-2.2_pre5"
	WORLD_MIGRATION_UPGRADE=$?

	# If portage-2.1.6 is installed and the preserved_libs_registry exists,
	# assume that the NEEDED.ELF.2 files have already been generated.
	has_version "<=${CATEGORY}/${PN}-2.2_pre7" && \
		! ( [ -e "$ROOT"var/lib/portage/preserved_libs_registry ] && \
		has_version ">=${CATEGORY}/${PN}-2.1.6_rc" )
	NEEDED_REBUILD_UPGRADE=$?

	has_version "<${CATEGORY}/${PN}-2.2_alpha"
	ADD_SYSTEM_TO_WORLD=$?

	if [ $ADD_SYSTEM_TO_WORLD != 0 -a "$ROOT" != / ] && \
		! has_version "${CATEGORY}/${PN}" ; then
		# building stage 1
		ADD_SYSTEM_TO_WORLD=0
	fi

	[[ -n $PORTDIR_OVERLAY ]] && has_version "<${CATEGORY}/${PN}-2.1.6.12"
	REPO_LAYOUT_CONF_WARN=$?
}

pkg_postinst() {
	# Compile all source files recursively. Any orphans
	# will be identified and removed in postrm.
	python_mod_optimize /usr/$(get_libdir)/portage/pym

	if [ $ADD_SYSTEM_TO_WORLD = 0 ] && \
		[ ! -e "$ROOT"var/lib/portage/world_sets ] ; then
		einfo "adding @system to world_sets for backward compatibility"
		echo @system > "$ROOT"var/lib/portage/world_sets
	fi

	if [ $WORLD_MIGRATION_UPGRADE = 0 ] ; then
		einfo "moving set references from the worldfile into world_sets"
		cd "${ROOT}/var/lib/portage/"
		grep "^@" world >> world_sets
		sed -i -e '/^@/d' world
	fi

	if [ $NEEDED_REBUILD_UPGRADE = 0 ] ; then
		einfo "rebuilding NEEDED.ELF.2 files"
		for cpv in "${ROOT}/var/db/pkg"/*/*; do
			if [ -f "${cpv}/NEEDED" ]; then
				rm -f "${cpv}/NEEDED.ELF.2"
				while read line; do
					filename=${line% *}
					needed=${line#* }
					needed=${needed//+/++}
					needed=${needed//#/##}
					needed=${needed//%/%%}
					newline=$(scanelf -BF "%a;%F;%S;%r;${needed}" $filename)
					newline=${newline//  -  }
					echo "${newline:3}" >> "${cpv}/NEEDED.ELF.2"
				done < "${cpv}/NEEDED"
			fi
		done
	fi

	if [ $REPO_LAYOUT_CONF_WARN = 0 ] ; then
		ewarn
		echo "If you want overlay eclasses to override eclasses from" \
			"other repos then see the portage(5) man page" \
			"for information about the new layout.conf and repos.conf" \
			"configuration files." \
			| fmt -w 75 | while read -r ; do ewarn "$REPLY" ; done
		ewarn
	fi

	einfo
	einfo "For help with using portage please consult the Gentoo Handbook"
	einfo "at http://www.gentoo.org/doc/en/handbook/handbook-x86.xml?part=3"
	einfo

	if [ $MINOR_UPGRADE = 0 ] ; then
		elog "If you're upgrading from a pre-2.2 version of portage you might"
		elog "want to remerge world (emerge -e world) to take full advantage"
		elog "of some of the new features in 2.2."
		elog "This is not required however for portage to function properly."
		elog
	fi

	if [ -z "${PV/*_rc*}" ]; then
		elog "If you always want to use the latest development version of portage"
		elog "please read http://www.gentoo.org/proj/en/portage/doc/testing.xml"
		elog
	fi
}

pkg_postrm() {
	python_mod_cleanup /usr/$(get_libdir)/portage/pym
}