[gentoo-commits] repo/gentoo:master commit in: dev-python/flask-appconfig/

[Ian Delaney]

commit:     9d3f2a04b078e76c7aad1b298cfc891f30fcda79
Author:     Louis Sautier <sautier.louis <AT> gmail <DOT> com>
AuthorDate: Mon Apr 25 23:00:03 2016 +0000
Commit:     Ian Delaney <idella4 <AT> gentoo <DOT> org>
CommitDate: Fri Apr 29 07:09:44 2016 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9d3f2a04

dev-python/flask-appconfig: new package, dependency of flask-bootstrap, vn. 0.11.1

Package-Manager: portage-2.2.28
Closes: https://github.com/gentoo/gentoo/pull/1353

Signed-off-by: Ian Delaney <idella4 <AT> gentoo.org>

 dev-python/flask-appconfig/Manifest                |  1 +
 .../flask-appconfig/flask-appconfig-0.11.1.ebuild  | 52 ++++++++++++++++++++++
 dev-python/flask-appconfig/metadata.xml            | 17 +++++++
 3 files changed, 70 insertions(+)

diff --git a/dev-python/flask-appconfig/Manifest b/dev-python/flask-appconfig/Manifest
new file mode 100644
index 0000000..df31c4f
--- /dev/null
+++ b/dev-python/flask-appconfig/Manifest
@@ -0,0 +1 @@
+DIST flask-appconfig-0.11.1.tar.gz 14545 SHA256 9869a752692e56f35ed3b017ea0e5b1d4b918a23bac8bc98a9e41ab54f5a9902 SHA512 9ebc42be5ef247b1f14b85f7b65600a1595ecdc70e792c0cd495347254b07675a3b7a306df8d2f2663626ceafa4ce7700f6f26cd0f1bcd974ba6bbab293847ee WHIRLPOOL f59662f9e7ace02e1e8dfc1a0a99b40c0cc5a353782d925d71e528fecc73ffbcea2891f99c3a1d20900f5b4f4064be9981f04ec20519aa74e2f872e8167b7da3

diff --git a/dev-python/flask-appconfig/flask-appconfig-0.11.1.ebuild b/dev-python/flask-appconfig/flask-appconfig-0.11.1.ebuild
new file mode 100644
index 0000000..0c24d0f
--- /dev/null
+++ b/dev-python/flask-appconfig/flask-appconfig-0.11.1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Configures Flask applications in a canonical way"
+HOMEPAGE="https://github.com/mbr/flask-appconfig"
+# PyPI tarballs don't include tests
+# https://github.com/mbr/flask-appconfig/pull/4
+SRC_URI="https://github.com/mbr/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/flask[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		${RDEPEND}
+	)
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+"
+
+python_prepare_all() {
+	sed -i "s/, 'sphinx.ext.intersphinx'//" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}

diff --git a/dev-python/flask-appconfig/metadata.xml b/dev-python/flask-appconfig/metadata.xml
new file mode 100644
index 0000000..8639b4a
--- /dev/null
+++ b/dev-python/flask-appconfig/metadata.xml
@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sautier.louis@×××××.com</email>
+		<name>Louis Sautier</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>proxy-maint@g.o</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="pypi">flask-appconfig</remote-id>
+		<remote-id type="github">mbr/flask-appconfig</remote-id>
+		<bugs-to>https://github.com/mbr/flask-appconfig/issues</bugs-to>
+	</upstream>
+</pkgmetadata>