[gentoo-commits] gentoo-x86 commit in dev-java/antenna: ChangeLog antenna-1.0.2.ebuild

[Petteri Raty (betelgeuse)]

betelgeuse    09/04/05 22:16:07

  Modified:             ChangeLog
  Added:                antenna-1.0.2.ebuild
  Log:
  Version bump. Fixes bug #264532.
  (Portage version: 2.2_rc27/cvs/Linux i686)

Revision  Changes    Path
1.7                  dev-java/antenna/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/antenna/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/antenna/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/antenna/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/antenna/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	12 Jul 2007 22:26:44 -0000	1.6
+++ ChangeLog	5 Apr 2009 22:16:07 -0000	1.7
@@ -1,6 +1,11 @@
 # ChangeLog for dev-java/antenna
-# Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/antenna/ChangeLog,v 1.6 2007/07/12 22:26:44 betelgeuse Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/antenna/ChangeLog,v 1.7 2009/04/05 22:16:07 betelgeuse Exp $
+
+*antenna-1.0.2 (05 Apr 2009)
+
+  05 Apr 2009; Petteri Räty <betelgeuse@g.o> +antenna-1.0.2.ebuild:
+  Version bump. Fixes bug #264532.
 
   12 Jul 2007; Petteri Räty <betelgeuse@g.o>
   -antenna-0.9.13-r1.ebuild:



1.1                  dev-java/antenna/antenna-1.0.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/antenna/antenna-1.0.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-java/antenna/antenna-1.0.2.ebuild?rev=1.1&content-type=text/plain

Index: antenna-1.0.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/antenna/antenna-1.0.2.ebuild,v 1.1 2009/04/05 22:16:07 betelgeuse Exp $

EAPI=2

JAVA_PKG_IUSE="doc examples source"

inherit java-pkg-2 java-ant-2 eutils

MY_P=${DISTDIR}/${PN}-src-${PV}.zip

DESCRIPTION="Ant task for J2ME"
HOMEPAGE="http://antenna.sourceforge.net/"
SRC_URI="mirror://sourceforge/antenna/${PN}-src-${PV}.zip"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~x86"
IUSE=""

COMMON_DEP="dev-java/ant-core:0
	dev-java/antlr:0
	dev-java/servletapi:2.4"
DEPEND=">=virtual/jdk-1.4
	app-arch/unzip
	${COMMON_DEP}"
RDEPEND=">=virtual/jre-1.4
	${COMMON_DEP}"

S="${WORKDIR}"

JAVA_PKG_BSFIX="off"

src_unpack() {
	default
	unzip -n lib/preprocessor-src-1.1.zip
}

java_prepare() {
	rm -rf lib
	java-ant_bsfix_one build.xml
	java-ant_rewrite-classpath build.xml
}

src_compile() {
	local cp="ant-core,antlr,servletapi-2.4"
	EANT_GENTOO_CLASSPATH="${cp}" \
		EANT_BUILD_TARGET="init compile package" \
		EANT_DOC_TARGET="" java-pkg-2_src_compile
	if use doc; then
		javadoc -encoding latin1 -d api $(find src -name "*.java") \
			-classpath $(java-pkg_getjars "${cp}") \
			|| die "javadoc failed"
	fi
}

src_install() {
	java-pkg_newjar dist/${PN}-bin-${PV}.jar
	java-pkg_register-ant-task

	if use doc; then
		java-pkg_dohtml doc/*
		java-pkg_dojavadoc api
	fi
	use source && java-pkg_dosrc src/*
	use examples && java-pkg_doexamples samples
}