[gentoo-commits] repo/gentoo:master commit in: media-gfx/imagemagick/

[Lars Wendler]

commit:     86aa55df9beca13b91c1f543d0f4426d414da211
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Mon Jul 17 13:13:49 2017 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Mon Jul 17 13:21:08 2017 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=86aa55df

media-gfx/imagemagick: Bump to versions 6.9.9.0 and 7.0.6.1

Package-Manager: Portage-2.3.6, Repoman-2.3.2

 media-gfx/imagemagick/Manifest                   |   2 +
 media-gfx/imagemagick/imagemagick-6.9.9.0.ebuild | 184 +++++++++++++++++++++++
 media-gfx/imagemagick/imagemagick-7.0.6.1.ebuild | 184 +++++++++++++++++++++++
 3 files changed, 370 insertions(+)

diff --git a/media-gfx/imagemagick/Manifest b/media-gfx/imagemagick/Manifest
index 59e41e827fd..461ae481d56 100644
--- a/media-gfx/imagemagick/Manifest
+++ b/media-gfx/imagemagick/Manifest
@@ -1,4 +1,6 @@
 DIST ImageMagick-6.9.7-4.tar.xz 8797776 SHA256 68842c55ed9c958b84aae17974961cefff4212bf7146f09fd15c09dbdc2d9629 SHA512 9ee9cf01c486575183a67e418bdbdcf4ac2b7ea2f9ff033db6a74f8271af0567da00f020dd8c18e042221d20444bed21d5d5256944ddeaf9916b62bf1844acf6 WHIRLPOOL 7c75006dafd28bb0fe02e130b4fcbae5fe54c6fbfdb29ba6b49796a14354e7aeb56b80c498eb57a4a8c7b383af025406dfeba66735ba89fd35d61125b51e7d41
 DIST ImageMagick-6.9.8-3.tar.xz 8819084 SHA256 5dd5804f803d01f0c0c6fc0f3da68cc8e4c638b5ff56770f8481bbe202411316 SHA512 78d467a3d6f38d9b2f30d9d5154a45396a082e7c31119e37a3646080fbc3a87447e9fd73ffbdcc8cf45e9370bdab963d7e5b674d5933ac6d52e017371d7c1460 WHIRLPOOL 80ad8fe7afd7a564739426d1e8eee8d85900c420a07a1edc7ef047958537c0fbd5674e9f3385cc7448e903b4ebd08c24e21bdf3e0615d42614a740df7abba914
 DIST ImageMagick-6.9.8-6.tar.xz 8772452 SHA256 dc587a30457d1b42fa980fe7d94bfad906407ad811335e60f5eb673b3a17afeb SHA512 9bd05db02f0565063d6513620567e54b66521dc49b9dd26a83e68d1aab3ca599b9b34ba0661df2e3a88042b88806db156f6a1e9598c34d76307c0fb4ad0c4271 WHIRLPOOL de126414da7b8bfc99102ad7ff3e3d181bc584561344b29c927f66531ecf797ef5e95100279af7a20372a13be67829565d47c612676089419d413ddfa84fa632
+DIST ImageMagick-6.9.9-0.tar.xz 8780640 SHA256 0a8a091dc4f57ec486e03285a1c30dc3f062d58133f848b6274dfc6ae5dbb60b SHA512 ddd2042e5d9fd2ee9ba91f65c7be3f0cf1a8ce340be9cefaaca2517073d2319b43b7190c5302c92e845f8e250d87681e375aec7238ca93401b42dd248776e338 WHIRLPOOL 603965b07098c3963ab5c089ee4a3fa4b1d36eb8fa52d1e5c22d2dd9bdd6b5ffa165713274fb524991faffe447ce7df14df40c8848f1436e7b86c25d901eda45
 DIST ImageMagick-7.0.5-7.tar.xz 8261496 SHA256 f72d089074d6c968bab38d1c18b22bd92c876e7ae23f7261db0b7c3552186586 SHA512 b634d4bba00fb3a344af350c29d8ecb397901c05cafece1de136a1d8f95e65a1324b4f035b5ed021d505980e8b373ddd4995805b73ed48a257039aa829e58855 WHIRLPOOL 1ac5e950fdf57e2000fae3c1817725e2ea86f41e6e51661a4cb93a47b83cba9864874d3d3662831fbd66308e2816744d9a7532ebeea1c615e3bad9a879a5f0a9
+DIST ImageMagick-7.0.6-1.tar.xz 8546292 SHA256 7a273e0428a817a240fa0b37d209e41285676189cb9969abdb8b1d7d01d36fc4 SHA512 09c6cf0fa3f7f04dc806ad49e5324e8f051e79032f6d9ef83235c130764c931942ee90d643476c92f36fd49a53d3fd195553b658f2f937b82b4950e57724bcfb WHIRLPOOL 107a11ff2a8671a570ab45768645e3f3af900d35b850cd8b858906515061adfe97d1cb4b7ce570d123de46e0585403b97364ec9f99c0aa16ac5d78568f0892af

diff --git a/media-gfx/imagemagick/imagemagick-6.9.9.0.ebuild b/media-gfx/imagemagick/imagemagick-6.9.9.0.ebuild
new file mode 100644
index 00000000000..29bb1d35600
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-6.9.9.0.ebuild
@@ -0,0 +1,184 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic libtool multilib toolchain-funcs versionator
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-gfx/ufraw )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-proto/xextproto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	local mesa_cards ati_cards nvidia_cards render_cards
+	default
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	shopt -s nullglob
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	nvidia_cards=$(echo -n /dev/nvidia** | sed 's/ /:/g')
+	if test -n "${nvidia_cards}"; then
+		addpredict "${nvidia_cards}"
+	fi
+	render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
+	if test -n "${render_cards}"; then
+		addpredict "${render_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	CONFIG_SHELL=$(type -P bash) \
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable hdri) \
+		$(use_enable opencl) \
+		--with-threads \
+		--with-modules \
+		--with-quantum-depth=${depth} \
+		$(use_with cxx magick-plus-plus) \
+		$(use_with perl) \
+		--with-perl-options='INSTALLDIRS=vendor' \
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts \
+		$(use_with bzip2 bzlib) \
+		$(use_with X x) \
+		$(use_with zlib) \
+		--without-autotrace \
+		$(use_with postscript dps) \
+		$(use_with djvu) \
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu \
+		$(use_with fftw) \
+		$(use_with fpx) \
+		$(use_with fontconfig) \
+		$(use_with truetype freetype) \
+		$(use_with postscript gslib) \
+		$(use_with graphviz gvc) \
+		$(use_with jbig) \
+		$(use_with jpeg) \
+		$(use_with jpeg2k openjp2) \
+		$(use_with lcms) \
+		$(use_with lqr) \
+		$(use_with lzma) \
+		$(use_with openexr) \
+		$(use_with pango) \
+		$(use_with png) \
+		$(use_with svg rsvg) \
+		$(use_with tiff) \
+		$(use_with webp) \
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts) \
+		$(use_with wmf) \
+		$(use_with xml) \
+		--${openmp}-openmp \
+		--with-gcc-arch=no-automagic
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
+	emake check
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/renderD128"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}

diff --git a/media-gfx/imagemagick/imagemagick-7.0.6.1.ebuild b/media-gfx/imagemagick/imagemagick-7.0.6.1.ebuild
new file mode 100644
index 00000000000..683354b7f95
--- /dev/null
+++ b/media-gfx/imagemagick/imagemagick-7.0.6.1.ebuild
@@ -0,0 +1,184 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils flag-o-matic libtool multilib toolchain-funcs versionator
+
+MY_P=ImageMagick-$(replace_version_separator 3 '-')
+
+DESCRIPTION="A collection of tools and libraries for many image formats"
+HOMEPAGE="http://www.imagemagick.org/"
+SRC_URI="mirror://${PN}/${MY_P}.tar.xz"
+
+LICENSE="imagemagick"
+SLOT="0/${PV}"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="bzip2 corefonts cxx djvu fftw fontconfig fpx graphviz hdri jbig jpeg jpeg2k lcms lqr lzma opencl openexr openmp pango perl png postscript q32 q8 raw static-libs svg test tiff truetype webp wmf X xml zlib"
+
+RESTRICT="perl? ( userpriv )"
+
+RDEPEND="
+	dev-libs/libltdl:0
+	bzip2? ( app-arch/bzip2 )
+	corefonts? ( media-fonts/corefonts )
+	djvu? ( app-text/djvu )
+	fftw? ( sci-libs/fftw:3.0 )
+	fontconfig? ( media-libs/fontconfig )
+	fpx? ( >=media-libs/libfpx-1.3.0-r1 )
+	graphviz? ( media-gfx/graphviz )
+	jbig? ( >=media-libs/jbigkit-2:= )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( >=media-libs/openjpeg-2.1.0:2 )
+	lcms? ( media-libs/lcms:2= )
+	lqr? ( media-libs/liblqr )
+	opencl? ( virtual/opencl )
+	openexr? ( media-libs/openexr:0= )
+	pango? ( x11-libs/pango )
+	perl? ( >=dev-lang/perl-5.8.8:0= )
+	png? ( media-libs/libpng:0= )
+	postscript? ( app-text/ghostscript-gpl )
+	raw? ( media-gfx/ufraw )
+	svg? ( gnome-base/librsvg )
+	tiff? ( media-libs/tiff:0= )
+	truetype? (
+		media-fonts/urw-fonts
+		>=media-libs/freetype-2
+		)
+	webp? ( media-libs/libwebp:0= )
+	wmf? ( media-libs/libwmf )
+	X? (
+		x11-libs/libICE
+		x11-libs/libSM
+		x11-libs/libXext
+		x11-libs/libXt
+		)
+	xml? ( dev-libs/libxml2:= )
+	lzma? ( app-arch/xz-utils )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}
+	!media-gfx/graphicsmagick[imagemagick]
+	virtual/pkgconfig
+	X? ( x11-proto/xextproto )"
+
+REQUIRED_USE="corefonts? ( truetype )
+	test? ( corefonts )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	local ati_cards mesa_cards nvidia_cards render_cards
+	default
+
+	elibtoolize # for Darwin modules
+
+	# For testsuite, see https://bugs.gentoo.org/show_bug.cgi?id=500580#c3
+	shopt -s nullglob
+	ati_cards=$(echo -n /dev/ati/card* | sed 's/ /:/g')
+	if test -n "${ati_cards}"; then
+		addpredict "${ati_cards}"
+	fi
+	mesa_cards=$(echo -n /dev/dri/card* | sed 's/ /:/g')
+	if test -n "${mesa_cards}"; then
+		addpredict "${mesa_cards}"
+	fi
+	nvidia_cards=$(echo -n /dev/nvidia* | sed 's/ /:/g')
+	if test -n "${nvidia_cards}"; then
+		addpredict "${nvidia_cards}"
+	fi
+	render_cards=$(echo -n /dev/dri/renderD128* | sed 's/ /:/g')
+	if test -n "${render_cards}"; then
+		addpredict "${render_cards}"
+	fi
+	shopt -u nullglob
+	addpredict /dev/nvidiactl
+}
+
+src_configure() {
+	local depth=16
+	use q8 && depth=8
+	use q32 && depth=32
+
+	local openmp=disable
+	use openmp && { tc-has-openmp && openmp=enable; }
+
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lnsl -lsocket
+
+	CONFIG_SHELL=$(type -P bash) \
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable hdri) \
+		$(use_enable opencl) \
+		--with-threads \
+		--with-modules \
+		--with-quantum-depth=${depth} \
+		$(use_with cxx magick-plus-plus) \
+		$(use_with perl) \
+		--with-perl-options='INSTALLDIRS=vendor' \
+		--with-gs-font-dir="${EPREFIX}"/usr/share/fonts/urw-fonts \
+		$(use_with bzip2 bzlib) \
+		$(use_with X x) \
+		$(use_with zlib) \
+		--without-autotrace \
+		$(use_with postscript dps) \
+		$(use_with djvu) \
+		--with-dejavu-font-dir="${EPREFIX}"/usr/share/fonts/dejavu \
+		$(use_with fftw) \
+		$(use_with fpx) \
+		$(use_with fontconfig) \
+		$(use_with truetype freetype) \
+		$(use_with postscript gslib) \
+		$(use_with graphviz gvc) \
+		$(use_with jbig) \
+		$(use_with jpeg) \
+		$(use_with jpeg2k openjp2) \
+		$(use_with lcms) \
+		$(use_with lqr) \
+		$(use_with lzma) \
+		$(use_with openexr) \
+		$(use_with pango) \
+		$(use_with png) \
+		$(use_with svg rsvg) \
+		$(use_with tiff) \
+		$(use_with webp) \
+		$(use_with corefonts windows-font-dir "${EPREFIX}"/usr/share/fonts/corefonts) \
+		$(use_with wmf) \
+		$(use_with xml) \
+		--${openmp}-openmp \
+		--with-gcc-arch=no-automagic
+}
+
+src_test() {
+	LD_LIBRARY_PATH="${S}/coders/.libs:${S}/filters/.libs:${S}/Magick++/lib/.libs:${S}/magick/.libs:${S}/wand/.libs" \
+	emake check
+}
+
+src_install() {
+	# Ensure documentation installation files and paths with each release!
+	emake \
+		DESTDIR="${D}" \
+		DOCUMENTATION_PATH="${EPREFIX}"/usr/share/doc/${PF}/html \
+		install
+
+	rm -f "${ED}"/usr/share/doc/${PF}/html/{ChangeLog,LICENSE,NEWS.txt}
+	dodoc {AUTHORS,README}.txt ChangeLog
+
+	if use perl; then
+		find "${ED}" -type f -name perllocal.pod -exec rm -f {} +
+		find "${ED}" -depth -mindepth 1 -type d -empty -exec rm -rf {} +
+	fi
+
+	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
+
+	if use opencl; then
+		cat <<-EOF > "${T}"/99${PN}
+		SANDBOX_PREDICT="/dev/nvidiactl:/dev/nvidia-uvm:/dev/ati/card:/dev/dri/card:/dev/dri/renderD128"
+		EOF
+
+		insinto /etc/sandbox.d
+		doins "${T}"/99${PN} #472766
+	fi
+
+	insinto /usr/share/${PN}
+	doins config/*icm
+}