[gentoo-commits] gentoo-x86 commit in net-www/nspluginwrapper: ChangeLog nspluginwrapper-1.2.2.ebuild nspluginwrapper-1.1.10.ebuild nspluginwrapper-1.1.4.ebuild

[Patrick McLean (chutzpah)]

chutzpah    09/02/02 21:31:05

  Modified:             ChangeLog
  Added:                nspluginwrapper-1.2.2.ebuild
  Removed:              nspluginwrapper-1.1.10.ebuild
                        nspluginwrapper-1.1.4.ebuild
  Log:
  Version bump (bug #256257). Clean out beta versions.
  (Portage version: 2.1.6.7/cvs/Linux x86_64)

Revision  Changes    Path
1.24                 net-www/nspluginwrapper/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/nspluginwrapper/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/nspluginwrapper/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/nspluginwrapper/ChangeLog?r1=1.23&r2=1.24

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-www/nspluginwrapper/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog	16 Dec 2008 14:45:20 -0000	1.23
+++ ChangeLog	2 Feb 2009 21:31:05 -0000	1.24
@@ -1,6 +1,13 @@
 # ChangeLog for net-www/nspluginwrapper
-# Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-www/nspluginwrapper/ChangeLog,v 1.23 2008/12/16 14:45:20 chutzpah Exp $
+# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-www/nspluginwrapper/ChangeLog,v 1.24 2009/02/02 21:31:05 chutzpah Exp $
+
+*nspluginwrapper-1.2.2 (02 Feb 2009)
+
+  02 Feb 2009; Patrick McLean <chutzpah@g.o>
+  -nspluginwrapper-1.1.4.ebuild, -nspluginwrapper-1.1.10.ebuild,
+  +nspluginwrapper-1.2.2.ebuild:
+  Version bump (bug #256257). Clean out beta versions.
 
 *nspluginwrapper-1.1.10 (16 Dec 2008)
 



1.1                  net-www/nspluginwrapper/nspluginwrapper-1.2.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/nspluginwrapper/nspluginwrapper-1.2.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-www/nspluginwrapper/nspluginwrapper-1.2.2.ebuild?rev=1.1&content-type=text/plain

Index: nspluginwrapper-1.2.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-www/nspluginwrapper/nspluginwrapper-1.2.2.ebuild,v 1.1 2009/02/02 21:31:05 chutzpah Exp $

inherit eutils nsplugins multilib

DESCRIPTION="Netscape Plugin Wrapper - Load 32bit plugins on 64bit browser"
HOMEPAGE="http://www.gibix.net/projects/nspluginwrapper/"
SRC_URI="http://www.gibix.net/projects/${PN}/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

RDEPEND=">=x11-libs/gtk+-2
	net-misc/curl
	app-emulation/emul-linux-x86-xlibs
	app-emulation/emul-linux-x86-gtklibs
	|| ( >=sys-apps/util-linux-2.13 sys-apps/setarch )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# bug #238403
	epatch "${FILESDIR}/${PN}-1.1.0-quiet-64bit-plugin-warnings.patch"
}

src_compile() {
	econf --with-biarch \
		--with-lib32=$(ABI=x86 get_libdir) \
		--with-lib64=$(get_libdir) \
		--pkglibdir=/usr/$(get_libdir)/${PN}

	emake || die "emake failed"

}

src_install() {
	emake -j1 DESTDIR="${D}" install || die "emake install failed"

	inst_plugin "/usr/$(get_libdir)/${PN}/x86_64/linux/npwrapper.so"
	dosym "/usr/$(get_libdir)/${PN}/x86_64/linux/npconfig" "/usr/bin/${PN}"

	dodoc NEWS README TODO ChangeLog
}

pkg_postinst() {
	einfo "Auto installing 32bit plugins..."
	${PN} -a -i
	elog "Any 32bit plugins you currently have installed have now been"
	elog "configured to work in a 64bit browser. Any plugins you install in"
	elog "the future will first need to be setup with:"
	elog "  \"nspluginwrapper -i <path-to-32bit-plugin>\""
	elog "before they will function in a 64bit browser"
	elog
}

# this is terribly ugly, but without a way to query portage as to whether
# we are upgrading/reinstalling a package versus unmerging, I can't think of
# a better way

pkg_prerm() {
	einfo "Removing wrapper plugins..."
	${PN} --auto --remove
}

pkg_postrm() {
	if [[ -x /usr/bin/${PN} ]]; then
		einfo "Auto installing 32bit plugins..."
		${PN} --auto --install
	fi
}