[gentoo-commits] repo/gentoo:master commit in: dev-python/reflink/

[Arthur Zamarin]

commit:     61c5989c2dbf7f8cda0e4062b4af539085103758
Author:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
AuthorDate: Sun May 29 18:37:06 2022 +0000
Commit:     Arthur Zamarin <arthurzam <AT> gentoo <DOT> org>
CommitDate: Sun May 29 18:37:06 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=61c5989c

dev-python/reflink: EAPI=8, Use PEP517

Signed-off-by: Arthur Zamarin <arthurzam <AT> gentoo.org>

 dev-python/reflink/reflink-0.2.1-r2.ebuild | 48 ++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)

diff --git a/dev-python/reflink/reflink-0.2.1-r2.ebuild b/dev-python/reflink/reflink-0.2.1-r2.ebuild
new file mode 100644
index 000000000000..d07e6fb4a670
--- /dev/null
+++ b/dev-python/reflink/reflink-0.2.1-r2.ebuild
@@ -0,0 +1,48 @@
+# Copyright 2019-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9} )
+DISTUTILS_IN_SOURCE_BUILD=1
+
+inherit distutils-r1
+
+DESCRIPTION="Python wrapper around the reflink system calls"
+HOMEPAGE="https://gitlab.com/rubdos/pyreflink"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+
+RDEPEND="virtual/python-cffi[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}"
+BDEPEND="${RDEPEND}
+	test? ( sys-fs/btrfs-progs )
+"
+
+distutils_enable_sphinx docs
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -e 's|'\''pytest-runner'\'',\?||' -i setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local notestmsg="Tests need FEATURES='-usersandbox -userpriv -sandbox'"
+	if [[ ${EUID} != 0 ]]; then
+		ewarn "${notestmsg}"
+	elif
+		has sandbox ${FEATURES}; then
+			ewarn "${notestmsg}"
+	else
+		pushd "${BUILD_DIR}"/lib >/dev/null || die
+		# module import will fail with any other directory structure
+		cp -rv "${S}"/tests ./ || die
+		pytest -vv || die "Tests fail with ${EPYTHON}"
+		popd >/dev/null || die
+	fi
+}