[gentoo-commits] gentoo-x86 commit in dev-embedded/sgpp-lite-arm-linux-bin: metadata.xml sgpp-lite-arm-linux-bin-2010.09.50.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      10/12/02 15:15:56

  Added:                metadata.xml
                        sgpp-lite-arm-linux-bin-2010.09.50.ebuild ChangeLog
  Log:
  Initial package by me.
  
  (Portage version: 2.2.0_alpha5/cvs/Linux x86_64)

Revision  Changes    Path
1.1                  dev-embedded/sgpp-lite-arm-linux-bin/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/sgpp-lite-arm-linux-bin/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/sgpp-lite-arm-linux-bin/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<herd>dev-embedded</herd>
</pkgmetadata>



1.1                  dev-embedded/sgpp-lite-arm-linux-bin/sgpp-lite-arm-linux-bin-2010.09.50.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/sgpp-lite-arm-linux-bin/sgpp-lite-arm-linux-bin-2010.09.50.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/sgpp-lite-arm-linux-bin/sgpp-lite-arm-linux-bin-2010.09.50.ebuild?rev=1.1&content-type=text/plain

Index: sgpp-lite-arm-linux-bin-2010.09.50.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-embedded/sgpp-lite-arm-linux-bin/sgpp-lite-arm-linux-bin-2010.09.50.ebuild,v 1.1 2010/12/02 15:15:56 vapier Exp $

CPU="arm"
TARGET="arm-none-linux-gnueabi"
HOST="i686-pc-linux-gnu"
MY_P="${CPU}-${PV%.*}-${PV##*.}-${TARGET}-${HOST}"

DESCRIPTION="regular, validated releases of the GNU Toolchain for ${CPU} processors by CodeSourcery"
HOMEPAGE="http://www.codesourcery.com/sgpp/lite/${CPU}"
SRC_URI="http://www.codesourcery.com/public/gnu_toolchain/${TARGET}/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="${PV}"
KEYWORDS="~amd64 ~x86"
IUSE="doc"
RESTRICT="strip" # package is already stripped, and contains target bins
QA_EXECSTACK="opt/${P}/*"

RDEPEND="sys-libs/glibc"
DEPEND=""

S=${WORKDIR}/${CPU}-${PV%.*}

src_install() {
	local d="/opt/${P}"
	dodir ${d}
	cp -pPR * "${D}"/${d}/ || die

	pushd "${D}"/${d}/share/doc/${CPU}-${TARGET} >/dev/null
	if use doc ; then
		dohtml -r html/* || die
		dodoc pdf/* || die
	fi
	rm -rf html pdf
	rm LICENSE.txt man/man7/{fsf-funding,gpl,gfdl}.7 || die
	mv man info ../..
	popd >/dev/null
	find "${D}" -depth -type d -empty -delete

	cat <<-EOF > "${T}"/15${P}
	PATH=${d}/bin
	MANPATH=${d}/share/man
	INFOPATH=${d}/share/info
	EOF
	doenvd "${T}"/15${P} || die
}



1.1                  dev-embedded/sgpp-lite-arm-linux-bin/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/sgpp-lite-arm-linux-bin/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-embedded/sgpp-lite-arm-linux-bin/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-embedded/sgpp-lite-arm-linux-bin
# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-embedded/sgpp-lite-arm-linux-bin/ChangeLog,v 1.1 2010/12/02 15:15:56 vapier Exp $

*sgpp-lite-arm-linux-bin-2010.09.50 (02 Dec 2010)

  02 Dec 2010; Mike Frysinger <vapier@g.o>
  +sgpp-lite-arm-linux-bin-2010.09.50.ebuild, +metadata.xml:
  Initial package by me.