[gentoo-commits] gentoo-x86 commit in media-video/aravis: aravis-0.1.15.ebuild ChangeLog aravis-0.1.13.ebuild

[Diego Petteno (flameeyes)]

flameeyes    12/08/28 00:05:32

  Modified:             ChangeLog
  Added:                aravis-0.1.15.ebuild
  Removed:              aravis-0.1.13.ebuild
  Log:
  Remove old; version bump.
  
  (Portage version: 2.2.0_alpha123/cvs/Linux x86_64)

Revision  Changes    Path
1.8                  media-video/aravis/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/aravis/ChangeLog?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/aravis/ChangeLog?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/aravis/ChangeLog?r1=1.7&r2=1.8

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/aravis/ChangeLog,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- ChangeLog	20 Jun 2012 16:36:14 -0000	1.7
+++ ChangeLog	28 Aug 2012 00:05:32 -0000	1.8
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/aravis
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/aravis/ChangeLog,v 1.7 2012/06/20 16:36:14 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/aravis/ChangeLog,v 1.8 2012/08/28 00:05:32 flameeyes Exp $
+
+*aravis-0.1.15 (28 Aug 2012)
+
+  28 Aug 2012; Diego E. Pettenò <flameeyes@g.o> +aravis-0.1.15.ebuild,
+  -aravis-0.1.13.ebuild:
+  Remove old; version bump.
 
 *aravis-0.1.14 (20 Jun 2012)
 
@@ -37,4 +43,3 @@
   07 Feb 2012; Diego E. Pettenò <flameeyes@g.o> +aravis-0.1.11.ebuild,
   +aravis-9999.ebuild, +metadata.xml:
   Initial import of Aravis project, maintained by me and Luca.
-



1.1                  media-video/aravis/aravis-0.1.15.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/aravis/aravis-0.1.15.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/aravis/aravis-0.1.15.ebuild?rev=1.1&content-type=text/plain

Index: aravis-0.1.15.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/aravis/aravis-0.1.15.ebuild,v 1.1 2012/08/28 00:05:32 flameeyes Exp $

EAPI=4

inherit versionator

KEYWORDS="~amd64"

if [[ ${PV} == "9999" ]]; then
	KEYWORDS=""
	EGIT_REPO_URI="git://git.gnome.org/aravis"
	EGIT_COMMIT="${aravis_LIVE_COMMIT:-master}"
	inherit git-2 autotools
fi

DESCRIPTION="Library for video acquisition using Genicam cameras."
HOMEPAGE="http://live.gnome.org/Aravis"

LICENSE="LGPL-2.1"
SLOT="0"

IUSE="X gstreamer"

GST_DEPEND="media-libs/gstreamer
	media-libs/gst-plugins-base"

RDEPEND=">=dev-libs/glib-2.22
	dev-libs/libxml2
	X? (
		>=x11-libs/gtk+-2.12:2
		${GST_DEPEND}
		media-libs/gst-plugins-base
		media-plugins/gst-plugins-xvideo
	)
	gstreamer? ( ${GST_DEPEND} )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	dev-libs/gobject-introspection"

if [[ -z ${EGIT_COMMIT} ]]; then
	SRC_URI="mirror://gnome/sources/${PN}/$(get_version_component_range 1-2)/${P}.tar.xz"
else
	DEPEND+=" dev-util/gtk-doc dev-util/intltool"
fi

src_prepare() {
	if [[ -n ${EGIT_COMMIT} ]]; then
		intltoolize || die
		gtkdocize || die
		eautoreconf
	fi
}

src_configure() {
	econf \
		--disable-silent-rules \
		--disable-static \
		$(use_enable X viewer) \
		$(use_enable gstreamer gst-plugin) \
		--enable-introspection
}

src_install() {
	emake install DESTDIR="${D}" aravisdocdir="/usr/share/doc/${PF}"
	find "${D}" -name '*.la' -delete
}