[gentoo-commits] repo/proj/libressl:master commit in: app-crypt/qca/

[Quentin Retornaz]

commit:     7a82073c1f8e9c2f8b4a6659cf21718406e0ec2c
Author:     Saki Xi <space_raccoon <AT> riseup <DOT> net>
AuthorDate: Wed Nov 30 13:03:10 2022 +0000
Commit:     Quentin Retornaz <gentoo <AT> retornaz <DOT> com>
CommitDate: Thu Dec  1 18:17:27 2022 +0000
URL:        https://gitweb.gentoo.org/repo/proj/libressl.git/commit/?id=7a82073c

Bump qca, use same patch

Signed-off-by: Saki Xi <space_raccoon <AT> riseup.net>
Signed-off-by: Quentin Retornaz <gentoo <AT> retornaz.com>

 app-crypt/qca/Manifest         |  1 +
 app-crypt/qca/qca-2.3.5.ebuild | 90 ++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 91 insertions(+)

diff --git a/app-crypt/qca/Manifest b/app-crypt/qca/Manifest
index aad1181..4dcbbe8 100644
--- a/app-crypt/qca/Manifest
+++ b/app-crypt/qca/Manifest
@@ -1 +1,2 @@
 DIST qca-2.3.4.tar.xz 737072 BLAKE2B 64e698135f02bf115269203d44a53d40449be1620487340551c1e45f66f042132beb2cfa2363d1249f92de3ffd670f1807219cb3ce3d6e7c05afd8c22242b703 SHA512 af27338b5c018d39c8c745b63691dec3914e29ff79347ab338f4391ee1dc9832d158b222bc9ef6c7681cf4b2893a38829a4daadf1d53622d6947de2efeb880a8
+DIST qca-2.3.5.tar.xz 741036 BLAKE2B 3948dc9b58a8ef03eec246cc14c7582d30e2513ea4b8f457a44d4a0c8f91fdb10af041f7cc342a0c8d9540a43cb47b4ca5b35641dfc3716c065fc3a1d6ff227a SHA512 656e44d4f30c3c0e1a8c04f2703484e3cff2d962b12c6ff9891b9f28127cd61ed30dcd248c059bf9066ac645bf53a9b7c14bdb413a7766c8b3f3d37426478d96

diff --git a/app-crypt/qca/qca-2.3.5.ebuild b/app-crypt/qca/qca-2.3.5.ebuild
new file mode 100644
index 0000000..2991efa
--- /dev/null
+++ b/app-crypt/qca/qca-2.3.5.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake kde.org qmake-utils
+
+DESCRIPTION="Qt Cryptographic Architecture (QCA)"
+HOMEPAGE="https://userbase.kde.org/QCA"
+SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="2"
+KEYWORDS="amd64 ~arm arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~sparc-solaris"
+IUSE="botan debug doc examples gcrypt gpg logger nss pkcs11 sasl softstore +ssl test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-qt/qtcore-5.14:5
+	botan? ( dev-libs/botan:= )
+	gcrypt? ( dev-libs/libgcrypt:= )
+	gpg? ( app-crypt/gnupg )
+	nss? ( dev-libs/nss )
+	pkcs11? (
+		>=dev-libs/openssl-1.1
+		dev-libs/pkcs11-helper
+	)
+	sasl? ( dev-libs/cyrus-sasl:2 )
+	ssl? ( >=dev-libs/openssl-1.1:= )
+"
+DEPEND="${RDEPEND}
+	test? (
+		dev-qt/qtnetwork:5
+		dev-qt/qttest:5
+	)
+"
+BDEPEND="
+	doc? (
+		app-doc/doxygen[dot]
+		virtual/latex-base
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-disable-pgp-test.patch"
+	"${FILESDIR}/${PN}-2.3.4-libressl.patch"
+)
+
+qca_plugin_use() {
+	echo -DWITH_${2:-$1}_PLUGIN=$(usex "$1")
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DQCA_FEATURE_INSTALL_DIR="${EPREFIX}$(qt5_get_mkspecsdir)/features"
+		-DQCA_PLUGINS_INSTALL_DIR="${EPREFIX}$(qt5_get_plugindir)"
+		$(qca_plugin_use botan)
+		$(qca_plugin_use gcrypt)
+		$(qca_plugin_use gpg gnupg)
+		$(qca_plugin_use logger)
+		$(qca_plugin_use nss)
+		$(qca_plugin_use pkcs11)
+		$(qca_plugin_use sasl cyrus-sasl)
+		$(qca_plugin_use softstore)
+		$(qca_plugin_use ssl ossl)
+		-DBUILD_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	local -x QCA_PLUGIN_PATH="${BUILD_DIR}/lib/qca"
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	if use doc; then
+		pushd "${BUILD_DIR}" >/dev/null || die
+		doxygen Doxyfile || die
+		dodoc -r apidocs/html
+		popd >/dev/null || die
+	fi
+
+	if use examples; then
+		dodoc -r "${S}"/examples
+	fi
+}