[gentoo-commits] gentoo-x86 commit in net-dialup/rp-pppoe: rp-pppoe-3.11.ebuild ChangeLog

[Lars Wendler (polynomial-c)]

polynomial-c    13/12/29 23:02:19

  Modified:             ChangeLog
  Added:                rp-pppoe-3.11.ebuild
  Log:
  Version bump
  
  (Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.104                net-dialup/rp-pppoe/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/rp-pppoe/ChangeLog?rev=1.104&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/rp-pppoe/ChangeLog?rev=1.104&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/rp-pppoe/ChangeLog?r1=1.103&r2=1.104

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-dialup/rp-pppoe/ChangeLog,v
retrieving revision 1.103
retrieving revision 1.104
diff -u -r1.103 -r1.104
--- ChangeLog	12 May 2013 04:00:43 -0000	1.103
+++ ChangeLog	29 Dec 2013 23:02:19 -0000	1.104
@@ -1,6 +1,12 @@
 # ChangeLog for net-dialup/rp-pppoe
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-dialup/rp-pppoe/ChangeLog,v 1.103 2013/05/12 04:00:43 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-dialup/rp-pppoe/ChangeLog,v 1.104 2013/12/29 23:02:19 polynomial-c Exp $
+
+*rp-pppoe-3.11 (29 Dec 2013)
+
+  29 Dec 2013; Lars Wendler <polynomial-c@g.o> +rp-pppoe-3.11.ebuild,
+  +files/rp-pppoe-3.11-gentoo.patch:
+  Version bump.
 
   12 May 2013; Patrick Lauer <patrick@g.o> rp-pppoe-3.8-r2.ebuild:
   Remove redundant WANT_AUTOMAKE



1.1                  net-dialup/rp-pppoe/rp-pppoe-3.11.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/rp-pppoe/rp-pppoe-3.11.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-dialup/rp-pppoe/rp-pppoe-3.11.ebuild?rev=1.1&content-type=text/plain

Index: rp-pppoe-3.11.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-dialup/rp-pppoe/rp-pppoe-3.11.ebuild,v 1.1 2013/12/29 23:02:19 polynomial-c Exp $

EAPI=5

inherit eutils flag-o-matic autotools

DESCRIPTION="A user-mode PPPoE client and server suite for Linux"
HOMEPAGE="http://www.roaringpenguin.com/pppoe/"
SRC_URI="http://www.roaringpenguin.com/files/download/${P}.tar.gz
	ftp://ftp.samba.org/pub/ppp/ppp-2.4.4.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sh ~sparc ~x86"
IUSE="X"

RDEPEND="net-dialup/ppp
	X? ( dev-lang/tk )"
# see bug #230491
DEPEND="|| ( <sys-kernel/linux-headers-2.6.24 >=sys-kernel/linux-headers-2.6.25 )
	${RDEPEND}"

src_prepare() {
	# Patch to enable integration of pppoe-start and pppoe-stop with
	# baselayout-1.11.x so that the pidfile can be found reliably per interface
	epatch "${FILESDIR}/${PN}-3.10-gentoo-netscripts.patch"

	epatch "${FILESDIR}/${PN}-3.10-username-charset.patch" # bug 82410
	epatch "${FILESDIR}/${PN}-3.10-plugin-options.patch"
	epatch "${FILESDIR}/${PN}-3.10-autotools.patch"
	epatch "${FILESDIR}/${PN}-3.10-session-offset.patch" # bug 204476
	has_version '<sys-kernel/linux-headers-2.6.35' && \
		epatch "${FILESDIR}/${PN}-3.10-linux-headers.patch" #334197
	epatch "${FILESDIR}/${PN}-3.10-posix-source-sigaction.patch"
	epatch "${FILESDIR}/${PN}-3.11-gentoo.patch"

	cd "${S}"/src || die
	eautoreconf
}

src_configure() {
	addpredict /dev/ppp

	cd "${S}/src" || die
	econf --enable-plugin=../../ppp-2.4.4
}

src_compile() {
	cd "${S}/src" || die
	emake

	if use X; then
		make -C "${S}/gui" || die "gui make failed"
	fi
}

src_install () {
	cd "${S}/src" || die
	emake DESTDIR="${D}" docdir=/usr/share/doc/${PF} install

	#Don't use compiled rp-pppoe plugin - see pkg_preinst below
	local pppoe_plugin="${D}/etc/ppp/plugins/rp-pppoe.so"
	if [ -f "${pppoe_plugin}" ] ; then
		rm "${pppoe_plugin}" || die
	fi

	if use X; then
		emake -C "${S}/gui" \
			DESTDIR="${D}" \
			datadir=/usr/share/doc/${PF}/ \
			install
		dosym /usr/share/doc/${PF}/tkpppoe /usr/share/tkpppoe
	fi
}

pkg_preinst() {
	# Use the rp-pppoe plugin that comes with net-dialup/pppd
	local PPPD_VER=$(best_version net-dialup/ppp)
	PPPD_VER=${PPPD_VER#*/*-} #reduce it to ${PV}-${PR}
	PPPD_VER=${PPPD_VER%%-*} #reduce it to ${PV}
	if [ -n "${PPPD_VER}" ] && [ -f "${ROOT}/usr/lib/pppd/${PPPD_VER}/rp-pppoe.so" ] ; then
		dosym /usr/lib/pppd/${PPPD_VER}/rp-pppoe.so /etc/ppp/plugins/rp-pppoe.so
	fi
}

pkg_postinst() {
	elog "Use pppoe-setup to configure your dialup connection."
}