[gentoo-commits] repo/gentoo:master commit in: x11-misc/redshift/

[Sebastian Pipping]

commit:     7e4aa823d94eb3c0e05a6e4becad19a6e973277a
Author:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 20 16:51:19 2021 +0000
Commit:     Sebastian Pipping <sping <AT> gentoo <DOT> org>
CommitDate: Tue Apr 20 16:57:10 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7e4aa823

x11-misc/redshift: Stop using /usr/share/appdata

Closes: https://bugs.gentoo.org/784281
Signed-off-by: Sebastian Pipping <sping <AT> gentoo.org>
Package-Manager: Portage-3.0.18, Repoman-3.0.3

 x11-misc/redshift/redshift-1.12-r5.ebuild | 93 +++++++++++++++++++++++++++++++
 1 file changed, 93 insertions(+)

diff --git a/x11-misc/redshift/redshift-1.12-r5.ebuild b/x11-misc/redshift/redshift-1.12-r5.ebuild
new file mode 100644
index 00000000000..0030954649e
--- /dev/null
+++ b/x11-misc/redshift/redshift-1.12-r5.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit flag-o-matic systemd autotools gnome2-utils python-r1
+
+DESCRIPTION="A screen color temperature adjusting software"
+HOMEPAGE="http://jonls.dk/redshift/"
+SRC_URI="https://github.com/jonls/redshift/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="appindicator geoclue gtk nls"
+
+COMMON_DEPEND=">=x11-libs/libX11-1.4
+	x11-libs/libXxf86vm
+	x11-libs/libxcb
+	x11-libs/libdrm
+	appindicator? ( dev-libs/libappindicator:3[introspection] )
+	geoclue? ( app-misc/geoclue:2.0 dev-libs/glib:2 )
+	gtk? ( ${PYTHON_DEPS} )"
+RDEPEND="${COMMON_DEPEND}
+	gtk? ( dev-python/pygobject[${PYTHON_USEDEP}]
+		x11-libs/gtk+:3[introspection]
+		dev-python/pyxdg[${PYTHON_USEDEP}] )"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/intltool-0.50
+	nls? ( sys-devel/gettext )
+"
+REQUIRED_USE="gtk? ( ${PYTHON_REQUIRED_USE} )"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	use gtk && python_setup
+
+	# Fix compile for Clang (bug #732438)
+	append-cflags -fPIE
+
+	econf \
+		$(use_enable nls) \
+		--enable-drm \
+		--enable-randr \
+		--enable-vidmode \
+		--disable-wingdi \
+		\
+		--disable-corelocation \
+		$(use_enable geoclue geoclue2) \
+		\
+		$(use_enable gtk gui) \
+		--with-systemduserunitdir="$(systemd_get_userunitdir)" \
+		--enable-apparmor \
+		--disable-quartz \
+		--disable-ubuntu
+}
+
+_impl_specific_src_install() {
+	emake DESTDIR="${D}" pythondir="$(python_get_sitedir)" \
+			-C src/redshift-gtk install
+}
+
+src_install() {
+	emake DESTDIR="${D}" UPDATE_ICON_CACHE=/bin/true install
+
+	if use gtk; then
+		python_foreach_impl _impl_specific_src_install
+		python_replicate_script "${D}"/usr/bin/redshift-gtk
+		dosym redshift-gtk /usr/bin/gtk-redshift
+
+		python_foreach_impl python_optimize
+	fi
+
+	# https://bugs.gentoo.org/784281
+	mv "${D}"/usr/share/{appdata,metainfo}/ || die
+}
+
+pkg_preinst() {
+	use gtk && gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	use gtk && gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	use gtk && gnome2_icon_cache_update
+}