[gentoo-commits] gentoo-x86 commit in mail-mta/ssmtp: ChangeLog ssmtp-2.64-r1.ebuild ssmtp-2.64.ebuild

[Jeroen Roovers (jer)]

jer         11/01/27 18:33:18

  Modified:             ChangeLog
  Added:                ssmtp-2.64-r1.ebuild
  Removed:              ssmtp-2.64.ebuild
  Log:
  Install the ChangeLog now there is one.
  
  (Portage version: 2.2.0_alpha19/cvs/Linux i686)

Revision  Changes    Path
1.109                mail-mta/ssmtp/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/ssmtp/ChangeLog?rev=1.109&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/ssmtp/ChangeLog?rev=1.109&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/ssmtp/ChangeLog?r1=1.108&r2=1.109

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-mta/ssmtp/ChangeLog,v
retrieving revision 1.108
retrieving revision 1.109
diff -u -r1.108 -r1.109
--- ChangeLog	20 Jan 2011 04:30:25 -0000	1.108
+++ ChangeLog	27 Jan 2011 18:33:18 -0000	1.109
@@ -1,6 +1,12 @@
 # ChangeLog for mail-mta/ssmtp
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-mta/ssmtp/ChangeLog,v 1.108 2011/01/20 04:30:25 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-mta/ssmtp/ChangeLog,v 1.109 2011/01/27 18:33:18 jer Exp $
+
+*ssmtp-2.64-r1 (27 Jan 2011)
+
+  27 Jan 2011; Jeroen Roovers <jer@g.o> -ssmtp-2.64.ebuild,
+  +ssmtp-2.64-r1.ebuild:
+  Install the ChangeLog now there is one.
 
   20 Jan 2011; Diego E. Pettenò <flameeyes@g.o> ssmtp-2.64.ebuild:
   Silence a harmless warning from repoman by renaming a variable.



1.1                  mail-mta/ssmtp/ssmtp-2.64-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/ssmtp/ssmtp-2.64-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-mta/ssmtp/ssmtp-2.64-r1.ebuild?rev=1.1&content-type=text/plain

Index: ssmtp-2.64-r1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-mta/ssmtp/ssmtp-2.64-r1.ebuild,v 1.1 2011/01/27 18:33:18 jer Exp $

EAPI="3"

PATCHSET=2

WANT_AUTOMAKE=none

inherit eutils autotools

DESCRIPTION="Extremely simple MTA to get mail off the system to a Mailhub"
HOMEPAGE="ftp://ftp.debian.org/debian/pool/main/s/ssmtp/"
SRC_URI="mirror://debian/pool/main/s/ssmtp/${P/-/_}.orig.tar.bz2
	http://dev.gentoo.org/~flameeyes/ssmtp/${P}-patches-${PATCHSET}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="ipv6 ssl gnutls"

DEPEND="ssl? (
		!gnutls? ( dev-libs/openssl )
		gnutls? ( net-libs/gnutls )
	)"
RDEPEND="${DEPEND}
	net-mail/mailbase
	!net-mail/mailwrapper
	!virtual/mta"
PROVIDE="virtual/mta"

pkg_setup() {
	enewgroup ssmtp
}

src_prepare() {
	EPATCH_SUFFIX="patch" EPATCH_SOURCE="${WORKDIR}/patches" \
		epatch

	eautoconf
}

src_configure() {
	econf \
		--sysconfdir="${EPREFIX}"/etc/ssmtp \
		$(use_enable ssl) $(use_with gnutls) \
		$(use_enable ipv6 inet6) \
		--enable-md5auth
}

src_compile() {
	emake etcdir="${EPREFIX}"/etc || die
}

src_install() {
	dosbin ssmtp || die

	doman ssmtp.8 ssmtp.conf.5 || die
	dodoc ChangeLog CHANGELOG_OLD INSTALL README TLS || die
	newdoc ssmtp.lsm DESC || die

	insinto /etc/ssmtp
	doins ssmtp.conf revaliases || die

	local conffile="${ED}etc/ssmtp/ssmtp.conf"

	# Sorry about the weird indentation, I couldn't figure out a cleverer way
	# to do this without having horribly >80 char lines.
	sed -i -e "s:^hostname=:\n# Gentoo bug #47562\\
# Commenting the following line will force ssmtp to figure\\
# out the hostname itself.\n\\
# hostname=:" \
		"${conffile}" || die "sed failed"

	# Comment rewriteDomain (bug #243364)
	sed -i -e "s:^rewriteDomain=:#rewriteDomain=:" "${conffile}"

	# Set restrictive perms on ssmtp.conf as per #187841, #239197
	# Protect the ssmtp configfile from being readable by regular users as it
	# may contain login/password data to auth against a the mailhub used.
	fowners root:ssmtp /etc/ssmtp/ssmtp.conf
	fperms 640 /etc/ssmtp/ssmtp.conf

	fowners root:ssmtp /usr/sbin/ssmtp
	fperms 2711 /usr/sbin/ssmtp

	dosym ../sbin/ssmtp /usr/lib/sendmail || die
	dosym ../sbin/ssmtp /usr/bin/sendmail || die
	dosym ssmtp /usr/sbin/sendmail || die
	dosym ../sbin/ssmtp /usr/bin/mailq || die
	dosym ../sbin/ssmtp /usr/bin/newaliases || die
}