[gentoo-commits] repo/gentoo:master commit in: dev-python/libtmux/

[Patrick McLean]

commit:     c7797a57647da37cf7bf237ba579dbf7e251324d
Author:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
AuthorDate: Tue Apr 28 02:21:21 2020 +0000
Commit:     Patrick McLean <chutzpah <AT> gentoo <DOT> org>
CommitDate: Tue Apr 28 02:21:21 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c7797a57

dev-python/libtmux-0.8.2-r2: Revbump, dep on tmux 3 (bug #709834)

Closes: https://bugs.gentoo.org/709834
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Patrick McLean <chutzpah <AT> gentoo.org>

 dev-python/libtmux/libtmux-0.8.2-r2.ebuild | 37 ++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)

diff --git a/dev-python/libtmux/libtmux-0.8.2-r2.ebuild b/dev-python/libtmux/libtmux-0.8.2-r2.ebuild
new file mode 100644
index 00000000000..489daf45be8
--- /dev/null
+++ b/dev-python/libtmux/libtmux-0.8.2-r2.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} pypy3 )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+inherit distutils-r1
+
+DESCRIPTION="python api for tmux"
+HOMEPAGE="https://libtmux.git-pull.com/"
+SRC_URI="https://github.com/tmux-python/${PN}/archive/v${PV}.tar.gz -> ${PN}-v${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND=">=app-misc/tmux-3.0a"
+
+PATCHES=(
+	"${FILESDIR}/libtmux-0.8.2-tests.patch"
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx doc \
+	dev-python/alagitpull \
+	dev-python/docutils
+
+python_prepare_all() {
+	# avoid a dependency on sphinx_issues
+	local issues="https://github.com/tmux-python/libtmux/issues/"
+	sed -i "s:'sphinx_issues',::" doc/conf.py || die
+	sed -r -i "s|:issue:\`([[:digit:]]+)\`|\`issue \1 ${issues}\1\`|" CHANGES || die
+	rm requirements/doc.txt || die
+
+	distutils-r1_python_prepare_all
+}