[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-commander/

[Andreas Sturmlechner]

commit:     67bcdc5ab52b89392a0492de707d421de50973dd
Author:     Uwe Scholz <uwescholz <AT> src <DOT> gnome <DOT> org>
AuthorDate: Thu Aug 15 20:28:53 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Fri Aug 16 08:24:19 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=67bcdc5a

gnome-extra/gnome-commander: version bump to 1.10.1

Signed-off-by: Uwe Scholz <u.scholz83 <AT> gmx.de>
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 gnome-extra/gnome-commander/Manifest               |  1 +
 .../gnome-commander/gnome-commander-1.10.1.ebuild  | 68 ++++++++++++++++++++++
 2 files changed, 69 insertions(+)

diff --git a/gnome-extra/gnome-commander/Manifest b/gnome-extra/gnome-commander/Manifest
index e021ac6fddc..2ce5ec32c6b 100644
--- a/gnome-extra/gnome-commander/Manifest
+++ b/gnome-extra/gnome-commander/Manifest
@@ -1 +1,2 @@
+DIST gnome-commander-1.10.1.tar.xz 7424500 BLAKE2B 6abddf8dae4bc0a1d740ffee49ccc7d816d783bdb5c2b90c9d0681c1db5fa3f42700e65a780881400c1af038d7dfe7f458a98cf2f8f1c1b0fc6f93a3d58dc069 SHA512 b5bc548444149e00f29e6e3b7f785c99a08d27a0a2642cf78c203411a8d2937341a76685b09172047162afe3e0fc92ff13c82bdbd8105281d360c1df44b4702d
 DIST gnome-commander-1.10.0.tar.xz 7421328 BLAKE2B 4cfb6a5d445217de10007d4371cd5cce95319dd68a6e7f071def2258cd965cfbeab671c6016e624ef474501608214f309c56360216cc53c83a1660b38dbe77d9 SHA512 76e2cca3af7e11ae7f327fa25bb175ad28d36d8b71c4908ce8b91533ed53a444a30d861a24cf94ee34dd7954d1f9dd0a14d26c2214854424b80f8e7c107db60d

diff --git a/gnome-extra/gnome-commander/gnome-commander-1.10.1.ebuild b/gnome-extra/gnome-commander/gnome-commander-1.10.1.ebuild
new file mode 100644
index 00000000000..06cd772cfed
--- /dev/null
+++ b/gnome-extra/gnome-commander/gnome-commander-1.10.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 toolchain-funcs
+
+DESCRIPTION="A graphical, full featured, twin-panel file manager"
+HOMEPAGE="https://gcmd.github.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="chm exif gsf pdf taglib samba test +unique"
+
+RDEPEND="
+	app-text/yelp-tools
+	>=dev-libs/glib-2.44.0:2
+	unique? ( >=dev-libs/libunique-0.9.3:1 )
+	gnome-base/gnome-keyring
+	>=gnome-base/gnome-vfs-2.0.0
+	>=gnome-base/libgnome-2.0.0
+	>=gnome-base/libgnomeui-2.4.0
+	>=x11-libs/gtk+-2.18.0:2
+	chm? ( dev-libs/chmlib )
+	exif? ( >=media-gfx/exiv2-0.14 )
+	gsf? ( >=gnome-extra/libgsf-1.12.0 )
+	samba? ( >=gnome-base/gnome-vfs-2.0.0[samba] )
+	pdf? ( >=app-text/poppler-0.18 )
+	taglib? ( >=media-libs/taglib-1.4 )
+"
+
+PATCHES=( "${FILESDIR}/gnome-commander-1.10.0-exiv2-0.27.1-missing-header.patch" )
+
+DEPEND="
+	${RDEPEND}
+	dev-util/gtk-doc-am
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( >=dev-cpp/gtest-1.7.0 )
+"
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		$(use_with chm libchm) \
+		$(use_with exif exiv2) \
+		$(use_with gsf libgsf) \
+		$(use_with pdf poppler) \
+		$(use_with samba) \
+		$(use_with taglib) \
+		$(use_with unique)
+}
+
+pkg_pretend() {
+	if tc-is-gcc && [[ $(gcc-major-version) -lt 8 ]]; then
+		eerror "Compilation with gcc older than version 8 is not supported"
+		die "GCC too old, please use gcc-8 or above"
+	fi
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	has_version dev-util/meld || elog "You need dev-util/meld to synchronize files and directories."
+	has_version gnome-extra/yelp || elog "You need gnome-extra/yelp to view the docs."
+}