[gentoo-commits] repo/gentoo:master commit in: sys-kernel/gentoo-kernel-bin/

[Sam James]

commit:     bc3275620c807cb0a21c317ffa19379f051c4cc3
Author:     Sam James <sam <AT> gentoo <DOT> org>
AuthorDate: Thu Apr  1 01:12:15 2021 +0000
Commit:     Sam James <sam <AT> gentoo <DOT> org>
CommitDate: Thu Apr  1 01:17:44 2021 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=bc327562

sys-kernel/gentoo-kernel-bin: bump to 5.4.109 for arm64

Signed-off-by: Sam James <sam <AT> gentoo.org>

 sys-kernel/gentoo-kernel-bin/Manifest              |   1 +
 .../gentoo-kernel-bin-5.4.109-r1.ebuild            | 114 +++++++++++++++++++++
 2 files changed, 115 insertions(+)

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 7cf1fa0b213..28cff24c2ec 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -63,6 +63,7 @@ DIST gentoo-kernel-5.4.108-1.amd64.xpak 61175107 BLAKE2B 75b91a1bb41642cf4bd6dc1
 DIST gentoo-kernel-5.4.108-1.arm64.xpak 56476237 BLAKE2B b0834e97fd92abaa2acf2887e9e2f7ead98a5134b2d789a716037cc80398bf260fbb4ea913fe958b29ea172b52104afa5b5786985337f5a4b84280be1eb1b7d8 SHA512 4ee727e0b0773ed461ca4756937e8b0c55e57ef81f33e87d498f64feed0666ecf24934c9a2cf371ad7100ea21dcff285ef3dec600da065030511db5b8ef4802d
 DIST gentoo-kernel-5.4.108-1.x86.xpak 53014350 BLAKE2B 6924f9905ffa7626b90eed819f8f9e8a7c71e67315f9ad0a25ff31219bee44fb58b382b13324f13dd9f56f43ff4b2a56c91f1689a585dda2dfcd7fdbd4ac3f27 SHA512 c72041904e43bd11c42cd613f957c1a838f4bc4abe492712901a3c690d58064e96ff6094594e9e9fc1299f2265c63628b1078f97c90fdfec17c3fe3c63f546cc
 DIST gentoo-kernel-5.4.109-1.amd64.xpak 61197533 BLAKE2B d192b84c8e00a992256d44bce33975e29f7ae330a62a5902df14ca08ac5222c3bdbcb1ac27df36db615deecd7af7e264842c2aa358e4cc54e830f3507f5ad034 SHA512 33f192621fa3aa692e7b77897e57e50c7af81cb3ba6a40fd090bdafb5ed7b83dc83438028fc6999723e7f82a22635462746a92ced5439f136c56e0559c85b945
+DIST gentoo-kernel-5.4.109-1.arm64.xpak 56430663 BLAKE2B 6079b762ab5cdeb0c745a1a030e4a3af36883588c88dcb8c8cd811aa47d7cbaebc573b152f01fed451dbbfda1ec89ed400270e6fda4e3e1df1aec497b3f7815a SHA512 2d29230577255473618d698363af8c7ef8dd9dd3dcaeaec8fc8802e453838d2c1685e001a6ceb784f6c6ab77fb2b991366e213fec9c45b5763a3a5f57674cef7
 DIST gentoo-kernel-5.4.109-1.x86.xpak 53002823 BLAKE2B eb9548ce9e285fa665e2adc01f33198b9f2b2ae1ea21ddbaf10c9a92664ac6bb12da1c7c6c1923e2efe4746879d3ee27b75f560a69d958465fcea03ebb4f3a7d SHA512 f3848ac5f9ba9e04af65e1b1888e7a2b9836dfeb8ca3f5a692146f524f8e8d87d7b6766183879c879004d8505f013553d13885ffcf97724ba6f1df49c724af3f
 DIST linux-5.10.tar.xz 116606704 BLAKE2B b923d7b66309224f42f35f8a5fa219421b0a9362d2adacdadd8d96251f61f7230878ea297a269a7f3b3c56830f0b177e068691e1d7f88501a05653b0a13274d1 SHA512 95bc137d0cf9148da6a9d1f1a878698dc27b40f68e22c597544010a6c591ce1b256f083489d3ff45ff77753289b535135590194d88ef9f007d0ddab3d74de70e
 DIST linux-5.11.tar.xz 117619104 BLAKE2B 81300c27bd5476387a83123aaeb4163c73eb61e9245806c23660cb5e6a4fa88ffc9def027031335fa0270fc4080506cd415990014364e3a98b9d2e8c58a29524 SHA512 a567ec133018bb5ec00c60281479b466c26e02137a93a9c690e83997947df02b6fd94e76e8df748f6d70ceb58a19bacc3b1467de10b7a1fad2763db32b3f1330

diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.109-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.109-r1.ebuild
new file mode 100644
index 00000000000..b63276300c5
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.4.109-r1.ebuild
@@ -0,0 +1,114 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 3 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}