[gentoo-commits] gentoo-x86 commit in dev-db/mysql-super-smack: mysql-super-smack-1.3-r3.ebuild ChangeLog mysql-super-smack-1.2.ebuild

[Brian Evans (grknight)]

grknight    14/06/25 23:08:37

  Modified:             ChangeLog
  Added:                mysql-super-smack-1.3-r3.ebuild
  Removed:              mysql-super-smack-1.2.ebuild
  Log:
  Revision bump to fix autotools and use EAPI5.
  Cleanup old
  
  (Portage version: 2.2.8-r1/cvs/Linux x86_64, signed Manifest commit with key 67C78E1D)

Revision  Changes    Path
1.20                 dev-db/mysql-super-smack/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mysql-super-smack/ChangeLog?rev=1.20&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mysql-super-smack/ChangeLog?rev=1.20&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mysql-super-smack/ChangeLog?r1=1.19&r2=1.20

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-db/mysql-super-smack/ChangeLog,v
retrieving revision 1.19
retrieving revision 1.20
diff -u -r1.19 -r1.20
--- ChangeLog	7 Nov 2013 03:25:47 -0000	1.19
+++ ChangeLog	25 Jun 2014 23:08:37 -0000	1.20
@@ -1,6 +1,13 @@
 # ChangeLog for dev-db/mysql-super-smack
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-super-smack/ChangeLog,v 1.19 2013/11/07 03:25:47 patrick Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-super-smack/ChangeLog,v 1.20 2014/06/25 23:08:37 grknight Exp $
+
+*mysql-super-smack-1.3-r3 (25 Jun 2014)
+
+  25 Jun 2014; Brian Evans <grknight@g.o>
+  +files/mysql-super-smack-1.3-automake-1.13.patch,
+  +mysql-super-smack-1.3-r3.ebuild, -mysql-super-smack-1.2.ebuild:
+  Revision bump to fix autotools and use EAPI5. Cleanup old
 
   07 Nov 2013; Patrick Lauer <patrick@g.o> mysql-super-smack-1.2.ebuild,
   mysql-super-smack-1.3-r2.ebuild:



1.1                  dev-db/mysql-super-smack/mysql-super-smack-1.3-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mysql-super-smack/mysql-super-smack-1.3-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-db/mysql-super-smack/mysql-super-smack-1.3-r3.ebuild?rev=1.1&content-type=text/plain

Index: mysql-super-smack-1.3-r3.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-db/mysql-super-smack/mysql-super-smack-1.3-r3.ebuild,v 1.1 2014/06/25 23:08:37 grknight Exp $

EAPI=5
WANT_AUTOMAKE="1.13"
AUTOTOOLS_AUTORECONF="YES"
#AUTOTOOLS_IN_SOURCE_BUILD="YES"

inherit eutils autotools-utils

MY_PN="super-smack"
MY_P="${MY_PN}-${PV}"
DESCRIPTION="Benchmarking, stress testing, and load generation tool for MySQL & PostGreSQL."
HOMEPAGE="http://vegan.net/tony/supersmack/"
SRC_URI="http://vegan.net/tony/supersmack/${MY_P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="+mysql postgres"
REQUIRED_USE="|| ( mysql postgres )"

DEPEND="mysql? ( virtual/mysql )
		postgres? ( dev-db/postgresql-server )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${MY_P}"

PATCHES=(
	"${FILESDIR}"/${PN}-1.2.destdir.patch
	"${FILESDIR}"/${PN}-1.3.amd64.patch
	"${FILESDIR}"/${PN}-1.3.gcc4.3.patch
	"${FILESDIR}"/${PN}-1.3-gen-data.patch
	"${FILESDIR}"/${PN}-1.3-automake-1.13.patch
)
DOCS=( CHANGES INSTALL MANUAL README TUTORIAL )

src_prepare() {
	# Clean up files so eautoreconf does not pick up any
	# deprecated autotools macros.
	rm acinclude.m4 aclocal.m4 acconfig.h config.status config.h || die
	mv configure.in configure.ac || die
	autotools-utils_src_prepare
}

src_configure() {
	local myeconfargs=(
		$(usex mysql --with-mysql "")
		$(usex postgres --with-pgsql "")
		--with-datadir=/var/tmp/${MY_PN}
		--with-smacks-dir=/usr/share/${MY_PN}
	)
	autotools-utils_src_configure
}

pkg_postinst() {
	elog "The gen-data binary is now installed as super-smack-gen-data"
}