[gentoo-commits] gentoo-x86 commit in media-gfx/fontforge: metadata.xml ChangeLog fontforge-20090408-r1.ebuild

[Peter Alfredsen (loki_val)]

loki_val    09/04/21 21:35:02

  Modified:             metadata.xml ChangeLog
  Added:                fontforge-20090408-r1.ebuild
  Log:
  Provide pango and cairo use-flags and deps, bug 266868.
  (Portage version: 2.2_rc28/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  media-gfx/fontforge/metadata.xml

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/fontforge/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/fontforge/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/fontforge/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/fontforge/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	21 Jan 2009 16:24:36 -0000	1.2
+++ metadata.xml	21 Apr 2009 21:35:02 -0000	1.3
@@ -19,6 +19,8 @@
 	capable of more exotic images than normal fonts but require much more effort
 	to support.</flag>
 
+	<flag name="pango">Enable pango font rendering</flag>
+
 	<flag name='pasteafter'>Controls whether fontforge has a paste after command
 	(Useful for making words?). This is kind of fun, but it isn't useful for
 	normal fonts.</flag>



1.107                media-gfx/fontforge/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/fontforge/ChangeLog?rev=1.107&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/fontforge/ChangeLog?rev=1.107&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/fontforge/ChangeLog?r1=1.106&r2=1.107

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/fontforge/ChangeLog,v
retrieving revision 1.106
retrieving revision 1.107
diff -u -r1.106 -r1.107
--- ChangeLog	9 Apr 2009 04:48:28 -0000	1.106
+++ ChangeLog	21 Apr 2009 21:35:02 -0000	1.107
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/fontforge
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/fontforge/ChangeLog,v 1.106 2009/04/09 04:48:28 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/fontforge/ChangeLog,v 1.107 2009/04/21 21:35:02 loki_val Exp $
+
+*fontforge-20090408-r1 (21 Apr 2009)
+
+  21 Apr 2009; Peter Alfredsen <loki_val@g.o>
+  +fontforge-20090408-r1.ebuild:
+  Provide pango and cairo use-flags and deps, bug 266868.
 
 *fontforge-20090408 (09 Apr 2009)
 



1.1                  media-gfx/fontforge/fontforge-20090408-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/fontforge/fontforge-20090408-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-gfx/fontforge/fontforge-20090408-r1.ebuild?rev=1.1&content-type=text/plain

Index: fontforge-20090408-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/fontforge/fontforge-20090408-r1.ebuild,v 1.1 2009/04/21 21:35:02 loki_val Exp $

# Some notes for maintainers this package:
# 1. README-unix: freetype headers are required to make use of truetype debugger
# in fontforge.
# 2. --enable-{double,longdouble} these just make ff use more storage space. In
# normal fonts neither is useful. Leave off.
# 3. FontForge autodetects libraries but does not link with them. They are
# dynamically loaded at run time if fontforge found them at build time.
# --with-regular-link disables this behaviour. No reason to make it optional for
# users. http://fontforge.sourceforge.net/faq.html#libraries. To see what
# libraries fontforge thinks with use $ fontforge --library-status

EAPI=2

inherit eutils fdo-mime

CIDMAPV="20090121"
DESCRIPTION="postscript font editor and converter"
HOMEPAGE="http://fontforge.sourceforge.net/"
SRC_URI="mirror://sourceforge/fontforge/${PN}_full-${PV}.tar.bz2
	doc? ( mirror://sourceforge/fontforge/fontforge_htdocs-${PV}.tar.bz2 )
	cjk? ( mirror://gentoo/cidmaps-${CIDMAPV}.tgz )"	# http://fontforge.sf.net/cidmaps.tgz

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="cjk cairo doc gif debug jpeg nls pasteafter png +python tiff tilepath truetype truetype-debugger pango type3 svg unicode +X"

RDEPEND="gif? ( >=media-libs/giflib-4.1.0-r1 )
	jpeg? ( >=media-libs/jpeg-6b-r2 )
	png? ( >=media-libs/libpng-1.2.4 )
	python? ( dev-lang/python )
	tiff? ( >=media-libs/tiff-3.5.7-r1 )
	truetype? ( >=media-libs/freetype-2.1.4 )
	truetype-debugger? ( >=media-libs/freetype-2.3.8[fontforge,-bindist] )
	svg? ( >=dev-libs/libxml2-2.6.7 )
	unicode? ( >=media-libs/libuninameslist-030713 )
	cairo? ( >=x11-libs/cairo-1.6.4[X] )
	pango? ( >=x11-libs/pango-1.20.3[X] )
	x11-libs/libXi
	x11-proto/inputproto
	!media-gfx/pfaedit"
DEPEND="${RDEPEND}
	nls? ( sys-devel/gettext )"

src_unpack() {
	unpack ${PN}_full-${PV}.tar.bz2
	use cjk && unpack cidmaps-${CIDMAPV}.tgz
	if use doc; then
		mkdir html
		cd html
		unpack fontforge_htdocs-${PV}.tar.bz2
	fi
	cd "${S}"
	epatch "${FILESDIR}/fontforge-desktop.patch"
}

src_prepare() {
	if use doc; then
		cd "${WORKDIR}/html/"
		chmod -x *.html
	fi
}

src_configure() {
	# no real way of disabling gettext/nls ...
	use nls || export ac_cv_header_libintl_h=no
	econf \
		$(use_with truetype-debugger freetype-src "/usr/include/freetype2/internal4fontforge/") \
		$(use_enable type3) \
		$(use_with python) \
		$(use_with python pyextension) \
		$(use_enable pasteafter) \
		$(use_with X x) \
		$(use_enable cjk gb12345) \
		$(use_enable tilepath) \
		$(use_enable debug debug-raw-points) \
		$(use_with pango) \
		$(use_with cairo)
}

src_install() {
	emake install DESTDIR="${D}" || die
	dodoc AUTHORS README*

	if use cjk; then #129518
		insinto /usr/share/fontforge
		doins "${WORKDIR}"/*.cidmap
	fi

	doicon Packaging/fontforge.png
	insinto /usr/share/applications
	doins Packaging/fontforge.desktop
	insinto /usr/share/mime/application
	doins Packaging/fontforge.xml

	if use doc; then
		insinto /usr/share/doc/${PN}
		cd "${WORKDIR}/html/"
		doins -r *
	fi
}

pkg_postrm() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}

pkg_postinst() {
	fdo-mime_desktop_database_update
	fdo-mime_mime_database_update
}