[gentoo-commits] repo/gentoo:master commit in: net-misc/nextcloud-client/

[Bernard Cafarelli]

commit:     a85efc218990a86bf0907fca4201c7f185fe35a5
Author:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 19 10:01:16 2020 +0000
Commit:     Bernard Cafarelli <voyageur <AT> gentoo <DOT> org>
CommitDate: Wed Aug 19 10:02:08 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a85efc21

net-misc/nextcloud-client: 3.0.0 bump

Package-Manager: Portage-3.0.3, Repoman-3.0.0
Signed-off-by: Bernard Cafarelli <voyageur <AT> gentoo.org>

 net-misc/nextcloud-client/Manifest                 |  1 +
 .../nextcloud-client/nextcloud-client-3.0.0.ebuild | 87 ++++++++++++++++++++++
 2 files changed, 88 insertions(+)

diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index b23121293a5..b5aa4bc8c26 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -1,3 +1,4 @@
 DIST nextcloud-client-2.5.2.tar.gz 18995992 BLAKE2B 6ad23962d327c1feeec34f59092021f7f82f4baeaf973fac0572db55cb03bc8ba2ed0c5037bcbfa80ca057d3976aaf6e402e129f2ec963b3a9c432330ef6aaf3 SHA512 1000b420355d7a4104ca5b41e813d467dcb345b60c79c78ce532de9c58ea89cad10d5565a433409bd512f0f7771c18c7c27974b968c74f84ccfda1ed3510d3ae
 DIST nextcloud-client-2.6.4.tar.gz 19035129 BLAKE2B 8721737a4e2515996de1910219c2d36b545e068ed5c66b2df85166646c25488f401563e113674254d9d1b1a70c19435c7c0728718e1633e8036ac1e415925b97 SHA512 849bf9bfa6a50342f6b58e805dc72ef342cb5f3e2e27d8f45d6a48759b1956dec194fb376b9a6b760df724f01eec3a22aadaa439f03e5166b1b2afb5454e40f1
 DIST nextcloud-client-2.6.5.tar.gz 19134736 BLAKE2B 12defed7dc9a23622d49228c2e78586533f51d1cfd6209e263a0a8b94d307028b1afa76004768432a2bee68140602da003ef10133cd166fd3443a0a45ccccabc SHA512 fcb8ac368e064f9e9ffdc014faabb4f308045d2b047e1011e17bf2e54fa61f462f529eb48e5ec2aa638df8d9720bd7b88acef9b26aa3ba2b90e8977b3be45462
+DIST nextcloud-client-3.0.0.tar.gz 19060293 BLAKE2B 80c53e2db30c9a3a8bae8673a937448915010f9d736836a99660c498c0afe0f3e5d78faf80df4c2214f452c41c9d92357a341f00ecb8f4720f6c459a9d2ccb30 SHA512 5b03ad99feeb16dd7d22399df624da98bf6f2e758337aad5b4ff21f25e39e44d94fe0451101cbc8100e43adbd4a39f8d1bac64881d9e39ef3de58b018ccd35d6

diff --git a/net-misc/nextcloud-client/nextcloud-client-3.0.0.ebuild b/net-misc/nextcloud-client/nextcloud-client-3.0.0.ebuild
new file mode 100644
index 00000000000..88cfe0aa099
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-3.0.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin nautilus shibboleth test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	>=dev-libs/openssl-1.1.0:0=
+	dev-libs/qtkeychain[qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwebengine:5[widgets]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	shibboleth? ( dev-qt/qtwebkit:5 )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+RESTRICT="!test? ( test )"
+
+S=${WORKDIR}/desktop-${PV/_/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DNO_SHIBBOLETH=$(usex !shibboleth)
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+}