[gentoo-commits] repo/gentoo:master commit in: dev-python/virtualenv/

[Justin Lecher]

commit:     f3d0bba11d88b2cf566d5e75a017ed60150dd3c5
Author:     Justin Lecher <jlec <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 11 10:46:05 2015 +0000
Commit:     Justin Lecher <jlec <AT> gentoo <DOT> org>
CommitDate: Sun Oct 11 11:24:29 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f3d0bba1

dev-python/virtualenv: Add python3.5 support

Package-Manager: portage-2.2.23
Signed-off-by: Justin Lecher <jlec <AT> gentoo.org>

 dev-python/virtualenv/virtualenv-13.1.2-r1.ebuild | 53 +++++++++++++++++++++++
 1 file changed, 53 insertions(+)

diff --git a/dev-python/virtualenv/virtualenv-13.1.2-r1.ebuild b/dev-python/virtualenv/virtualenv-13.1.2-r1.ebuild
new file mode 100644
index 0000000..77713a1
--- /dev/null
+++ b/dev-python/virtualenv/virtualenv-13.1.2-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} pypy pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="Virtual Python Environment builder"
+HOMEPAGE="
+	http://www.virtualenv.org/
+	https://pypi.python.org/pypi/virtualenv
+	https://github.com/pypa/virtualenv/
+"
+SRC_URI="https://github.com/pypa/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+SLOT="0"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/pip-7.1.2[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)"
+
+DOCS=( docs/index.rst docs/changes.rst )
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.8.2-no-versioned-script.patch
+	"${FILESDIR}"/${PN}-12.1.1-skip-broken-test.patch
+)
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test -vvx || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( "${S}"/docs/_build/html/. )
+	distutils-r1_python_install_all
+}