[gentoo-commits] proj/kde:master commit in: kde-base/kdepim-meta/, kde-base/kdepim-runtime/, kde-base/akonadiconsole/, ...

[Michael Palimaka]

commit:     095ed39ea80a17dc48388405128b8cabb8ce0691
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Wed Feb  4 14:14:34 2015 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Wed Feb  4 14:14:34 2015 +0000
URL:        http://sources.gentoo.org/gitweb/?p=proj/kde.git;a=commit;h=095ed39e

[kde-base] Version bump kdepim 4.14.5

---
 .../akonadiconsole/akonadiconsole-4.14.5.ebuild    |  25 +++++
 kde-base/akregator/akregator-4.14.5.ebuild         |  22 ++++
 kde-base/blogilo/blogilo-4.14.5.ebuild             |  26 +++++
 .../calendarjanitor/calendarjanitor-4.14.5.ebuild  |  27 +++++
 kde-base/kabcclient/kabcclient-4.14.5.ebuild       |  26 +++++
 kde-base/kaddressbook/kaddressbook-4.14.5.ebuild   |  51 ++++++++++
 kde-base/kalarm/kalarm-4.14.5.ebuild               |  26 +++++
 .../kdepim-common-libs-4.14.5.ebuild               |  81 +++++++++++++++
 kde-base/kdepim-icons/kdepim-icons-4.14.5.ebuild   |  16 +++
 .../kdepim-kresources-4.14.5.ebuild                |  27 +++++
 kde-base/kdepim-meta/kdepim-meta-4.14.5.ebuild     |  38 +++++++
 .../kdepim-runtime/kdepim-runtime-4.14.5.ebuild    |  42 ++++++++
 kde-base/kjots/kjots-4.14.5.ebuild                 |  26 +++++
 kde-base/kleopatra/kleopatra-4.14.5.ebuild         |  40 ++++++++
 kde-base/kmail/kmail-4.14.5.ebuild                 | 113 +++++++++++++++++++++
 kde-base/knode/knode-4.14.5.ebuild                 |  48 +++++++++
 kde-base/knotes/knotes-4.14.5.ebuild               |  31 ++++++
 .../konsolekalendar/konsolekalendar-4.14.5.ebuild  |  31 ++++++
 kde-base/kontact/kontact-4.14.5.ebuild             |  51 ++++++++++
 kde-base/korganizer/korganizer-4.14.5.ebuild       |  76 ++++++++++++++
 kde-base/ktimetracker/ktimetracker-4.14.5.ebuild   |  38 +++++++
 kde-base/ktnef/ktnef-4.14.5.ebuild                 |  24 +++++
 22 files changed, 885 insertions(+)

diff --git a/kde-base/akonadiconsole/akonadiconsole-4.14.5.ebuild b/kde-base/akonadiconsole/akonadiconsole-4.14.5.ebuild
new file mode 100644
index 0000000..7e985e4
--- /dev/null
+++ b/kde-base/akonadiconsole/akonadiconsole-4.14.5.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="Akonadi developer console"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	>=app-office/akonadi-server-1.12.90
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs)
+"
+RDEPEND="${DEPEND}"
+
+KMEXTRACTONLY="
+	akonadi_next/
+	calendarsupport/
+	messageviewer/
+"

diff --git a/kde-base/akregator/akregator-4.14.5.ebuild b/kde-base/akregator/akregator-4.14.5.ebuild
new file mode 100644
index 0000000..fdc791c
--- /dev/null
+++ b/kde-base/akregator/akregator-4.14.5.ebuild
@@ -0,0 +1,22 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="KDE news feed aggregator"
+HOMEPAGE="http://www.kde.org/applications/internet/akregator"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs)
+"
+RDEPEND="${DEPEND}"
+
+KMLOADLIBS="kdepim-common-libs"

diff --git a/kde-base/blogilo/blogilo-4.14.5.ebuild b/kde-base/blogilo/blogilo-4.14.5.ebuild
new file mode 100644
index 0000000..b236565
--- /dev/null
+++ b/kde-base/blogilo/blogilo-4.14.5.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="KDE Blogging Client"
+HOMEPAGE="http://www.kde.org/applications/internet/blogilo"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep kdepim-common-libs)
+	$(add_kdebase_dep kdepimlibs)
+	>=net-libs/libkgapi-2.2.0
+"
+RDEPEND="${DEPEND}"
+
+KMEXTRACTONLY="
+	composereditor-ng/
+	pimcommon/
+"

diff --git a/kde-base/calendarjanitor/calendarjanitor-4.14.5.ebuild b/kde-base/calendarjanitor/calendarjanitor-4.14.5.ebuild
new file mode 100644
index 0000000..2c779a2
--- /dev/null
+++ b/kde-base/calendarjanitor/calendarjanitor-4.14.5.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+KMMODULE="console/${PN}"
+inherit kde4-meta
+
+DESCRIPTION="A tool to scan calendar data for buggy instances"
+HOMEPAGE="http://www.kde.org/"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep kdepim-common-libs)
+	$(add_kdebase_dep kdepimlibs)
+"
+RDEPEND="${DEPEND}"
+
+KMEXTRACTONLY="
+	calendarsupport/
+"
+
+KMLOADLIBS="kdepim-common-libs"

diff --git a/kde-base/kabcclient/kabcclient-4.14.5.ebuild b/kde-base/kabcclient/kabcclient-4.14.5.ebuild
new file mode 100644
index 0000000..f7b5657
--- /dev/null
+++ b/kde-base/kabcclient/kabcclient-4.14.5.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+KMMODULE="console/${PN}"
+inherit kde4-meta
+
+DESCRIPTION="A command line client for accessing the KDE addressbook"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep kdepimlibs)
+"
+RDEPEND="${DEPEND}"
+
+src_install() {
+	kde4-meta_src_install
+
+	# work around NULL DT_RPATH in kabc2mutt
+	dosym kabcclient ${PREFIX}/bin/kabc2mutt
+}

diff --git a/kde-base/kaddressbook/kaddressbook-4.14.5.ebuild b/kde-base/kaddressbook/kaddressbook-4.14.5.ebuild
new file mode 100644
index 0000000..388344c
--- /dev/null
+++ b/kde-base/kaddressbook/kaddressbook-4.14.5.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="The KDE Address Book"
+HOMEPAGE="http://www.kde.org/applications/office/kaddressbook/"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs)
+	dev-libs/grantlee:0
+	!kde-base/contactthemeeditor
+"
+RDEPEND="${DEPEND}"
+
+KMEXTRA="
+	grantleeeditor/contactthemeeditor
+	plugins/kaddressbook/
+	plugins/ktexteditor/
+"
+KMCOMPILEONLY="
+	grantleetheme/
+	kaddressbookgrantlee/
+"
+KMEXTRACTONLY="
+	akonadi_next/
+	calendarsupport/
+	grantleeeditor/grantleethemeeditor/
+	libkleo/
+	pimcommon/
+"
+
+KMLOADLIBS="kdepim-common-libs"
+
+pkg_postinst() {
+	kde4-meta_pkg_postinst
+
+	if ! has_version kde-base/kdepim-kresources:${SLOT}; then
+		echo
+		elog "For groupware functionality, please install kde-base/kdepim-kresources:${SLOT}"
+		echo
+	fi
+}

diff --git a/kde-base/kalarm/kalarm-4.14.5.ebuild b/kde-base/kalarm/kalarm-4.14.5.ebuild
new file mode 100644
index 0000000..ae20a3f
--- /dev/null
+++ b/kde-base/kalarm/kalarm-4.14.5.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="Personal alarm message, command and email scheduler for KDE"
+HOMEPAGE+=" http://userbase.kde.org/KAlarm"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+RDEPEND="
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs)
+	media-libs/phonon[qt4]
+	x11-libs/libX11
+"
+DEPEND="${RDEPEND}"
+
+KMEXTRACTONLY="
+	kmail/
+"

diff --git a/kde-base/kdepim-common-libs/kdepim-common-libs-4.14.5.ebuild b/kde-base/kdepim-common-libs/kdepim-common-libs-4.14.5.ebuild
new file mode 100644
index 0000000..0492008
--- /dev/null
+++ b/kde-base/kdepim-common-libs/kdepim-common-libs-4.14.5.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kdepim"
+KMNOMODULE="true"
+inherit kde4-meta
+
+DESCRIPTION="Common libraries for KDE PIM apps"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	app-crypt/gpgme
+	>=app-office/akonadi-server-1.12.90
+	dev-libs/grantlee:0
+	$(add_kdebase_dep baloo)
+	$(add_kdebase_dep kdepimlibs)
+"
+RDEPEND="${DEPEND}
+	!kde-base/akonadi:4
+	!kde-base/libkdepim:4
+	!kde-base/libkleo:4
+	!kde-base/libkpgp:4
+	!<kde-base/kaddressbook-4.11.50:4
+	!kde-base/kdepim-wizards:4
+	!<kde-base/kmail-4.4.80:4
+	!=kde-base/kmail-4.11*
+	!=kde-base/kmail-4.12.0
+	!=kde-base/kmail-4.12.1
+	!<kde-base/kmail-4.13.60
+	!<kde-base/korganizer-4.5.67:4
+	app-crypt/gnupg
+	$(add_kdebase_dep kdepim-runtime)
+"
+
+RESTRICT="test"
+# bug 393131
+
+KMEXTRA="
+	agents/sendlateragent/
+	akonadi_next/
+	calendarsupport/
+	calendarviews/
+	composereditor-ng/
+	grantleeeditor/grantleethemeeditor/
+	grantleetheme/
+	kaddressbookgrantlee/
+	incidenceeditor-ng/
+	libkdepim/
+	libkdepimdbusinterfaces/
+	libkleo/
+	libkpgp/
+	kdgantt2/
+	messagecomposer/
+	messagecore/
+	messagelist/
+	messageviewer/
+	noteshared/
+	pimcommon/
+	templateparser/
+"
+KMEXTRACTONLY="
+	kleopatra/
+	kmail/
+	knode/org.kde.knode.xml
+	korgac/org.kde.korganizer.KOrgac.xml
+	korganizer/org.kde.korganizer.Korganizer.xml
+	mailcommon/
+"
+KMSAVELIBS="true"
+
+PATCHES=( "${FILESDIR}/install-composereditorng.patch" )
+
+src_prepare() {
+	kde4-meta_src_prepare
+	sed -e '/folderarchiveagent.desktop/d' \
+		-i agents/CMakeLists.txt || die
+}

diff --git a/kde-base/kdepim-icons/kdepim-icons-4.14.5.ebuild b/kde-base/kdepim-icons/kdepim-icons-4.14.5.ebuild
new file mode 100644
index 0000000..5b638c0
--- /dev/null
+++ b/kde-base/kdepim-icons/kdepim-icons-4.14.5.ebuild
@@ -0,0 +1,16 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kdepim"
+KMMODULE="icons"
+inherit kde4-meta
+
+DESCRIPTION="KDE PIM icons"
+IUSE=""
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="$(add_kdebase_dep kdepimlibs)"
+RDEPEND=""

diff --git a/kde-base/kdepim-kresources/kdepim-kresources-4.14.5.ebuild b/kde-base/kdepim-kresources/kdepim-kresources-4.14.5.ebuild
new file mode 100644
index 0000000..6727c5f
--- /dev/null
+++ b/kde-base/kdepim-kresources/kdepim-kresources-4.14.5.ebuild
@@ -0,0 +1,27 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kdepim"
+KMMODULE="kresources"
+inherit kde4-meta
+
+DESCRIPTION="KDE PIM groupware plugin collection"
+IUSE="debug"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs)
+"
+RDEPEND="${DEPEND}"
+
+KMEXTRACTONLY="
+	kmail/
+	knotes/
+	korganizer/version.h
+"
+
+KMLOADLIBS="kdepim-common-libs"

diff --git a/kde-base/kdepim-meta/kdepim-meta-4.14.5.ebuild b/kde-base/kdepim-meta/kdepim-meta-4.14.5.ebuild
new file mode 100644
index 0000000..43b59ec
--- /dev/null
+++ b/kde-base/kdepim-meta/kdepim-meta-4.14.5.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+inherit kde4-meta-pkg
+
+DESCRIPTION="kdepim - merge this to pull in all kdepim-derived packages"
+HOMEPAGE+=" http://community.kde.org/KDE_PIM"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="nls"
+
+RDEPEND="
+	$(add_kdebase_dep akonadiconsole)
+	$(add_kdebase_dep akregator)
+	$(add_kdebase_dep blogilo)
+	$(add_kdebase_dep calendarjanitor)
+	$(add_kdebase_dep kabcclient)
+	$(add_kdebase_dep kaddressbook)
+	$(add_kdebase_dep kalarm)
+	$(add_kdebase_dep kdepim-icons)
+	$(add_kdebase_dep kdepim-kresources)
+	$(add_kdebase_dep kdepim-runtime)
+	$(add_kdebase_dep kjots)
+	$(add_kdebase_dep kleopatra)
+	$(add_kdebase_dep kmail)
+	$(add_kdebase_dep knode)
+	$(add_kdebase_dep knotes)
+	$(add_kdebase_dep konsolekalendar)
+	$(add_kdebase_dep kontact)
+	$(add_kdebase_dep korganizer)
+	$(add_kdebase_dep ktimetracker)
+	$(add_kdebase_dep ktnef)
+	nls? (
+		$(add_kdebase_dep kde-l10n)
+		$(add_kdebase_dep kdepim-l10n)
+	)
+"

diff --git a/kde-base/kdepim-runtime/kdepim-runtime-4.14.5.ebuild b/kde-base/kdepim-runtime/kdepim-runtime-4.14.5.ebuild
new file mode 100644
index 0000000..07e6285
--- /dev/null
+++ b/kde-base/kdepim-runtime/kdepim-runtime-4.14.5.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KMNAME="kdepim-runtime"
+inherit kde4-base
+
+DESCRIPTION="KDE PIM runtime plugin collection"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug facebook google kolab"
+
+RESTRICT="test"
+# Would need test programs _testrunner and akonaditest from kdepimlibs, see bug 313233
+
+DEPEND="
+	>=app-office/akonadi-server-1.12.90
+	dev-libs/boost:=
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	$(add_kdebase_dep kdepimlibs)
+	x11-misc/shared-mime-info
+	facebook? ( net-libs/libkfbapi )
+	google? ( >=net-libs/libkgapi-2.0 )
+	kolab? ( >=net-libs/libkolab-0.5 )
+"
+RDEPEND="${DEPEND}
+	$(add_kdebase_dep kdepim-icons)
+	!kde-misc/akonadi-google
+"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package facebook LibKFbAPI)
+		$(cmake-utils_use_find_package google LibKGAPI2)
+		$(cmake-utils_use_find_package kolab Libkolab)
+		$(cmake-utils_use_find_package kolab Libkolabxml)
+	)
+
+	kde4-base_src_configure
+}

diff --git a/kde-base/kjots/kjots-4.14.5.ebuild b/kde-base/kjots/kjots-4.14.5.ebuild
new file mode 100644
index 0000000..c998d7c
--- /dev/null
+++ b/kde-base/kjots/kjots-4.14.5.ebuild
@@ -0,0 +1,26 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="KDE note taking utility"
+HOMEPAGE="http://www.kde.org/applications/utilities/kjots/"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	dev-libs/grantlee:0
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs)
+"
+RDEPEND="${DEPEND}"
+
+KMEXTRACTONLY="
+	akonadi_next/
+	noteshared/
+"

diff --git a/kde-base/kleopatra/kleopatra-4.14.5.ebuild b/kde-base/kleopatra/kleopatra-4.14.5.ebuild
new file mode 100644
index 0000000..a833cc0
--- /dev/null
+++ b/kde-base/kleopatra/kleopatra-4.14.5.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="Kleopatra - KDE X.509 key manager"
+HOMEPAGE="http://www.kde.org/applications/utilities/kleopatra/"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	>=app-crypt/gpgme-1.3.2
+	dev-libs/boost:=
+	dev-libs/libassuan
+	dev-libs/libgpg-error
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs)
+"
+RDEPEND="${DEPEND}
+	app-crypt/gnupg
+"
+
+KMEXTRACTONLY="
+	libkleo/
+"
+
+src_unpack() {
+	if use handbook; then
+		KMEXTRA="
+			doc/kwatchgnupg
+		"
+	fi
+
+	kde4-meta_src_unpack
+}

diff --git a/kde-base/kmail/kmail-4.14.5.ebuild b/kde-base/kmail/kmail-4.14.5.ebuild
new file mode 100644
index 0000000..628a010
--- /dev/null
+++ b/kde-base/kmail/kmail-4.14.5.ebuild
@@ -0,0 +1,113 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+VIRTUALX_REQUIRED=test
+inherit flag-o-matic kde4-meta
+
+DESCRIPTION="KMail is the email component of Kontact, the integrated personal information manager of KDE"
+HOMEPAGE="http://www.kde.org/applications/internet/kmail/"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep korganizer)
+	$(add_kdebase_dep kdepim-common-libs "" 4.12.1-r2)
+"
+RDEPEND="
+	${DEPEND}
+	!=kde-base/kdepim-common-libs-4.12.1-r1
+"
+
+RESTRICT="test"
+# bug 393147
+
+KMEXTRACTONLY="
+	agents/folderarchiveagent.desktop
+	agents/sendlateragent/
+	akonadi_next/
+	calendarsupport/
+	calendarviews/
+	grantleeeditor/grantleethemeeditor/
+	korganizer/
+	kresources/
+	libkleo/
+	libkpgp/
+	libkdepimdbusinterfaces/
+	kdgantt2/
+"
+KMCOMPILEONLY="
+	grantleetheme/
+	kaddressbookgrantlee/
+	messagecomposer/
+	messagecore/
+	messagelist/
+	messageviewer/
+	pimcommon/
+	templateparser/
+	incidenceeditor-ng/
+	calendarsupport/
+	noteshared/
+"
+KMEXTRA="
+	agents/archivemailagent/
+	agents/followupreminderagent/
+	agents/mailfilteragent/
+	grantleeeditor/headerthemeeditor/
+	kmailcvt/
+	ksendemail/
+	importwizard/
+	libksieve/
+	mailcommon/
+	mailimporter/
+	mboximporter/
+	pimsettingexporter/
+	plugins/messageviewer/
+"
+
+KMLOADLIBS="kdepim-common-libs"
+
+src_configure() {
+	# Bug 308903
+	use ppc64 && append-flags -mminimal-toc
+
+	kde4-meta_src_configure
+}
+
+src_compile() {
+	kde4-meta_src_compile kmail_xml
+	kde4-meta_src_compile
+}
+
+pkg_postinst() {
+	kde4-meta_pkg_postinst
+
+	if ! has_version kde-base/kdepim-kresources:${SLOT}; then
+		echo
+		elog "For groupware functionality, please install kde-base/kdepim-kresources:${SLOT}"
+		echo
+	fi
+	if ! has_version kde-base/kleopatra:${SLOT}; then
+		echo
+		elog "For certificate management and the gnupg log viewer, please install kde-base/kleopatra:${SLOT}"
+		echo
+	fi
+
+	if has_version "app-office/akonadi-server[sqlite]"; then
+		ewarn
+		ewarn "We strongly recommend you set your Akonadi database backend to QMYSQL in your"
+		ewarn "user configuration. This is the backend recommended by KDE upstream."
+		ewarn "Reports indicate that kde-base/kmail-4.10 does not work properly with the sqlite"
+		ewarn "backend anymore."
+		if has_version "app-office/akonadi-server[-mysql]"; then
+			ewarn "FOR THAT, YOU WILL HAVE TO RE-BUILD app-office/akonadi-server WITH mysql USEFLAG ENABLED."
+		fi
+		ewarn "You can select the backend in your ~/.config/akonadi/akonadiserverrc."
+		ewarn
+	fi
+}

diff --git a/kde-base/knode/knode-4.14.5.ebuild b/kde-base/knode/knode-4.14.5.ebuild
new file mode 100644
index 0000000..743e5d1
--- /dev/null
+++ b/kde-base/knode/knode-4.14.5.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="A newsreader for KDE"
+HOMEPAGE="http://www.kde.org/applications/internet/knode/"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+# test fails, last checked for 4.2.96
+RESTRICT=test
+
+DEPEND="
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs "" 4.12.1-r1)
+"
+RDEPEND="${DEPEND}"
+
+KMEXTRACTONLY="
+	agents/
+	libkleo/
+	libkpgp/
+	messagecomposer/
+	messageviewer/
+	messagecore/
+"
+KMCOMPILEONLY="
+	grantleetheme/
+	kaddressbookgrantlee/
+"
+
+KMLOADLIBS="kdepim-common-libs"
+
+src_unpack() {
+	if use handbook; then
+		KMEXTRA="
+			doc/kioslave/news
+		"
+	fi
+
+	kde4-meta_src_unpack
+}

diff --git a/kde-base/knotes/knotes-4.14.5.ebuild b/kde-base/knotes/knotes-4.14.5.ebuild
new file mode 100644
index 0000000..dea0191
--- /dev/null
+++ b/kde-base/knotes/knotes-4.14.5.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="KDE Notes application"
+HOMEPAGE="http://www.kde.org/applications/utilities/knotes/"
+KEYWORDS=" ~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs)
+"
+RDEPEND="${DEPEND}"
+
+KMCOMPILEONLY="
+	noteshared/
+"
+
+KMEXTRACTONLY="
+	akonadi_next/
+	pimcommon/
+"
+
+KMLOADLIBS="kdepim-common-libs"

diff --git a/kde-base/konsolekalendar/konsolekalendar-4.14.5.ebuild b/kde-base/konsolekalendar/konsolekalendar-4.14.5.ebuild
new file mode 100644
index 0000000..16aeafb
--- /dev/null
+++ b/kde-base/konsolekalendar/konsolekalendar-4.14.5.ebuild
@@ -0,0 +1,31 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+KMMODULE="console/${PN}"
+inherit kde4-meta
+
+DESCRIPTION="A command line interface to KDE calendars"
+HOMEPAGE+=" http://userbase.kde.org/KonsoleKalendar"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs)
+"
+RDEPEND="${DEPEND}"
+
+KMCOMPILEONLY="
+	calendarsupport/
+"
+KMEXTRACTONLY="
+	calendarviews/
+	libkdepimdbusinterfaces/
+"
+
+KMLOADLIBS="kdepim-common-libs"

diff --git a/kde-base/kontact/kontact-4.14.5.ebuild b/kde-base/kontact/kontact-4.14.5.ebuild
new file mode 100644
index 0000000..adb3b7c
--- /dev/null
+++ b/kde-base/kontact/kontact-4.14.5.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="KDE personal information manager"
+HOMEPAGE="http://www.kde.org/applications/office/kontact/"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs)
+"
+RDEPEND="${DEPEND}"
+
+KMLOADLIBS="kdepim-common-libs"
+KMSAVELIBS="true"
+
+# We remove plugins that are related to external kdepim programs. This way
+# kontact doesn't have to depend on all programs it has plugins for.
+# kcontactmanager gone from kdesvn
+#
+KMEXTRACTONLY="
+	kontact/plugins/akregator/
+	kontact/plugins/kaddressbook/
+	kontact/plugins/kjots/
+	kontact/plugins/kmail/
+	kontact/plugins/knode/
+	kontact/plugins/knotes/
+	kontact/plugins/korganizer/
+	kontact/plugins/ktimetracker/
+	kontact/plugins/planner/
+	kontact/plugins/specialdates/
+	libkdepimdbusinterfaces/
+"
+
+src_unpack() {
+	if use handbook; then
+		KMEXTRA+="
+			doc/kontact-admin/
+		"
+	fi
+
+	kde4-meta_src_unpack
+}

diff --git a/kde-base/korganizer/korganizer-4.14.5.ebuild b/kde-base/korganizer/korganizer-4.14.5.ebuild
new file mode 100644
index 0000000..22f45dd
--- /dev/null
+++ b/kde-base/korganizer/korganizer-4.14.5.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="A Personal Organizer for KDE"
+HOMEPAGE="http://www.kde.org/applications/office/korganizer/"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+DEPEND="
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs)
+	sys-libs/zlib
+"
+RDEPEND="${DEPEND}
+	$(add_kdebase_dep ktimezoned)
+"
+
+RESTRICT="test"
+# bug 393135
+
+KMLOADLIBS="kdepim-common-libs"
+
+KMEXTRA="
+	korgac/
+"
+
+KMEXTRACTONLY="
+	akonadi_next/
+	calendarviews/
+	kdgantt2/
+	kmail/
+	pimcommon/
+	knode/org.kde.knode.xml
+	libkdepimdbusinterfaces/
+	korgac/org.kde.korganizer.KOrgac.xml
+"
+
+KMCOMPILEONLY="
+	incidenceeditor-ng/
+	calendarsupport/
+"
+
+src_unpack() {
+	if use kontact; then
+		KMEXTRA="${KMEXTRA}
+			kontact/plugins/planner/
+			kontact/plugins/specialdates/
+		"
+	fi
+
+	kde4-meta_src_unpack
+}
+
+src_install() {
+	kde4-meta_src_install
+	# colliding with kdepim-common-libs
+	rm -rf "${ED}"/usr/share/kde4/servicetypes/calendarplugin.desktop
+	rm -rf "${ED}"/usr/share/kde4/servicetypes/calendardecoration.desktop
+}
+
+pkg_postinst() {
+	kde4-meta_pkg_postinst
+
+	if ! has_version kde-base/kdepim-kresources:${SLOT}; then
+		echo
+		elog "For groupware functionality, please install kde-base/kdepim-kresources:${SLOT}"
+		echo
+	fi
+}

diff --git a/kde-base/ktimetracker/ktimetracker-4.14.5.ebuild b/kde-base/ktimetracker/ktimetracker-4.14.5.ebuild
new file mode 100644
index 0000000..ae84b55
--- /dev/null
+++ b/kde-base/ktimetracker/ktimetracker-4.14.5.ebuild
@@ -0,0 +1,38 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="KTimeTracker tracks time spent on various tasks"
+HOEMPAGE="http://www.kde.org/applications/utilities/ktimetracker/"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug"
+
+RDEPEND="
+	$(add_kdebase_dep kdepim-kresources)
+	$(add_kdebase_dep kdepimlibs)
+	$(add_kdebase_dep kdepim-common-libs)
+	x11-libs/libXScrnSaver
+"
+DEPEND="${RDEPEND}
+	x11-proto/scrnsaverproto
+"
+
+KMEXTRACTONLY="
+	kresources/
+"
+
+KMLOADLIBS="kdepim-common-libs"
+
+src_unpack() {
+	if use kontact; then
+		KMEXTRA="${KMEXTRA} kontact/plugins/ktimetracker"
+	fi
+
+	kde4-meta_src_unpack
+}

diff --git a/kde-base/ktnef/ktnef-4.14.5.ebuild b/kde-base/ktnef/ktnef-4.14.5.ebuild
new file mode 100644
index 0000000..4ba96f1
--- /dev/null
+++ b/kde-base/ktnef/ktnef-4.14.5.ebuild
@@ -0,0 +1,24 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=5
+
+KDE_HANDBOOK="optional"
+KMNAME="kdepim"
+inherit kde4-meta
+
+DESCRIPTION="A viewer for TNEF attachments"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+LICENSE="LGPL-2.1"
+IUSE="debug"
+
+DEPEND="
+	app-office/akonadi-server
+	$(add_kdebase_dep kdepimlibs)
+"
+RDEPEND="${DEPEND}"
+
+KMEXTRACTONLY="
+	akonadi/
+"