[gentoo-commits] gentoo-x86 commit in sys-apps/iproute2: ChangeLog iproute2-9999.ebuild iproute2-3.1.0.ebuild

[Mike Frysinger (vapier)]

vapier      11/12/02 22:24:35

  Modified:             ChangeLog iproute2-9999.ebuild
  Added:                iproute2-3.1.0.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha75/cvs/Linux x86_64)

Revision  Changes    Path
1.175                sys-apps/iproute2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/ChangeLog?rev=1.175&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/ChangeLog?rev=1.175&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/ChangeLog?r1=1.174&r2=1.175

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v
retrieving revision 1.174
retrieving revision 1.175
diff -u -r1.174 -r1.175
--- ChangeLog	18 Oct 2011 21:41:55 -0000	1.174
+++ ChangeLog	2 Dec 2011 22:24:35 -0000	1.175
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/iproute2
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v 1.174 2011/10/18 21:41:55 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/ChangeLog,v 1.175 2011/12/02 22:24:35 vapier Exp $
+
+*iproute2-3.1.0 (02 Dec 2011)
+
+  02 Dec 2011; Mike Frysinger <vapier@g.o> +iproute2-3.1.0.ebuild,
+  +files/iproute2-3.1.0-mtu.patch, iproute2-9999.ebuild:
+  Version bump.
 
   18 Oct 2011; Mike Frysinger <vapier@g.o> iproute2-2.6.38.ebuild,
   +files/iproute2-2.6.38-parallel-build.patch:



1.17                 sys-apps/iproute2/iproute2-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild?r1=1.16&r2=1.17

Index: iproute2-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- iproute2-9999.ebuild	31 Jul 2011 18:33:22 -0000	1.16
+++ iproute2-9999.ebuild	2 Dec 2011 22:24:35 -0000	1.17
@@ -1,11 +1,10 @@
 # Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild,v 1.16 2011/07/31 18:33:22 mattst88 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-9999.ebuild,v 1.17 2011/12/02 22:24:35 vapier Exp $
 
 EAPI=4
 
 EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/shemminger/iproute2.git"
-[[ ${PV} == "9999" ]] && SCM_ECLASS="git-2"
 
 if [[ ${PV} == *.*.*.* ]] ; then
 	MY_PV=${PV%.*}-${PV##*.}
@@ -14,12 +13,12 @@
 fi
 MY_P="${PN}-${MY_PV}"
 
-inherit eutils toolchain-funcs flag-o-matic base ${SCM_ECLASS}
-unset SCM_ECLASS
+inherit eutils toolchain-funcs flag-o-matic
+[[ ${PV} == "9999" ]] && inherit git-2
 
 DESCRIPTION="kernel routing and traffic control utilities"
 HOMEPAGE="http://www.linuxfoundation.org/collaborate/workgroups/networking/iproute2"
-[[ ${PV} == "9999" ]] || SRC_URI="http://developer.osdl.org/dev/iproute2/download/${MY_P}.tar.bz2"
+[[ ${PV} == "9999" ]] || SRC_URI="mirror://kernel/linux/utils/networking/${PN}/${P}.tar.bz2"
 
 LICENSE="GPL-2"
 SLOT="0"
@@ -37,12 +36,8 @@
 
 S=${WORKDIR}/${MY_P}
 
-PATCHES=(
-	"${FILESDIR}/${PN}-2.6.29.1-hfsc.patch" #291907
-)
-
 src_prepare() {
-	base_src_prepare
+	epatch "${FILESDIR}"/${PN}-3.1.0-mtu.patch #291907
 
 	sed -i \
 		-e "/^LIBDIR/s:=.*:=/$(get_libdir):" \
@@ -59,16 +54,21 @@
 }
 
 src_configure() {
-	echo "TC_CONFIG_ATM:=$(use atm && echo "y" || echo "n")" > Config
+	tc-export AR CC PKG_CONFIG
 
+	# This sure is ugly.  Should probably move into toolchain-funcs at some point.
+	local setns
+	pushd "${T}" >/dev/null
+	echo 'main(){return setns();};' > test.c
+	${CC} ${CFLAGS} ${LDFLAGS} test.c >&/dev/null && setns=y || setns=n
+	popd >/dev/null
+
+	cat <<-EOF > Config
+	TC_CONFIG_ATM := $(usex atm y n)
+	IP_CONFIG_SETNS := ${setns}
 	# Use correct iptables dir, #144265 #293709
-	append-cppflags -DIPT_LIB_DIR=\\\"`$(tc-getPKG_CONFIG) xtables --variable=xtlibdir`\\\"
-}
-
-src_compile() {
-	emake \
-		CC="$(tc-getCC)" \
-		AR="$(tc-getAR)"
+	IPT_LIB_DIR := $(${PKG_CONFIG} xtables --variable=xtlibdir)
+	EOF
 }
 
 src_install() {



1.1                  sys-apps/iproute2/iproute2-3.1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/iproute2-3.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/iproute2/iproute2-3.1.0.ebuild?rev=1.1&content-type=text/plain

Index: iproute2-3.1.0.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/iproute2/iproute2-3.1.0.ebuild,v 1.1 2011/12/02 22:24:35 vapier Exp $

EAPI=4

EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/shemminger/iproute2.git"

if [[ ${PV} == *.*.*.* ]] ; then
	MY_PV=${PV%.*}-${PV##*.}
else
	MY_PV=${PV}
fi
MY_P="${PN}-${MY_PV}"

inherit eutils toolchain-funcs flag-o-matic
[[ ${PV} == "9999" ]] && inherit git-2

DESCRIPTION="kernel routing and traffic control utilities"
HOMEPAGE="http://www.linuxfoundation.org/collaborate/workgroups/networking/iproute2"
[[ ${PV} == "9999" ]] || SRC_URI="mirror://kernel/linux/utils/networking/${PN}/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
[[ ${PV} == "9999" ]] || KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="atm berkdb minimal"

RDEPEND="!net-misc/arpd
	!minimal? ( berkdb? ( sys-libs/db ) )
	atm? ( net-dialup/linux-atm )"
DEPEND="${RDEPEND}
	sys-devel/bison
	sys-devel/flex
	>=sys-kernel/linux-headers-2.6.27
	elibc_glibc? ( >=sys-libs/glibc-2.7 )"

S=${WORKDIR}/${MY_P}

src_prepare() {
	epatch "${FILESDIR}"/${PN}-3.1.0-mtu.patch #291907

	sed -i \
		-e "/^LIBDIR/s:=.*:=/$(get_libdir):" \
		-e "s:-O2:${CFLAGS} ${CPPFLAGS}:" \
		Makefile || die

	# build against system headers
	rm -r include/netinet #include/linux include/ip{,6}tables{,_common}.h include/libiptc

	# don't build arpd if USE=-berkdb #81660
	use berkdb || sed -i '/^TARGETS=/s: arpd : :' misc/Makefile

	use minimal && sed -i -e '/^SUBDIRS=/s:=.*:=lib tc:' Makefile
}

src_configure() {
	tc-export AR CC PKG_CONFIG

	# This sure is ugly.  Should probably move into toolchain-funcs at some point.
	local setns
	pushd "${T}" >/dev/null
	echo 'main(){return setns();};' > test.c
	${CC} ${CFLAGS} ${LDFLAGS} test.c >&/dev/null && setns=y || setns=n
	popd >/dev/null

	cat <<-EOF > Config
	TC_CONFIG_ATM := $(usex atm y n)
	IP_CONFIG_SETNS := ${setns}
	# Use correct iptables dir, #144265 #293709
	IPT_LIB_DIR := $(${PKG_CONFIG} xtables --variable=xtlibdir)
	EOF
}

src_install() {
	if use minimal ; then
		into /
		dosbin tc/tc
		return 0
	fi

	emake \
		DESTDIR="${D}" \
		SBINDIR=/sbin \
		DOCDIR=/usr/share/doc/${PF} \
		MANDIR=/usr/share/man \
		install

	dolib.a lib/libnetlink.a
	insinto /usr/include
	doins include/libnetlink.h

	if use berkdb ; then
		dodir /var/lib/arpd
		# bug 47482, arpd doesn't need to be in /sbin
		dodir /usr/sbin
		mv "${ED}"/sbin/arpd "${ED}"/usr/sbin/
	fi
}