[gentoo-commits] repo/gentoo:master commit in: games-emulation/mgba/

[Ionen Wolkens]

commit:     cd108727e0320b3ddc7f43da73b388249391b371
Author:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
AuthorDate: Mon Jan 30 18:55:47 2023 +0000
Commit:     Ionen Wolkens <ionen <AT> gentoo <DOT> org>
CommitDate: Mon Jan 30 19:11:09 2023 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cd108727

games-emulation/mgba: drop 0.10.0

Signed-off-by: Ionen Wolkens <ionen <AT> gentoo.org>

 games-emulation/mgba/Manifest           |   1 -
 games-emulation/mgba/mgba-0.10.0.ebuild | 106 --------------------------------
 2 files changed, 107 deletions(-)

diff --git a/games-emulation/mgba/Manifest b/games-emulation/mgba/Manifest
index 9e7fd52ce992..4ad9fcc5fa35 100644
--- a/games-emulation/mgba/Manifest
+++ b/games-emulation/mgba/Manifest
@@ -1,2 +1 @@
-DIST mgba-0.10.0.tar.gz 14302653 BLAKE2B 0ebfa8a3de5db61452f070116fcf2d6312ce96f5d08b1b1e70ba8f7e50235fecff2a0f6a5a32860b7e95e55a6ab5bbf2227d483bad7eb25d6c7e471424bcf0dd SHA512 05939f94bc00906d999b955091e8e8059cc13a5b822048f6e002062c2e74069337d947d2cde2f8c1be96e3353a361743d752811c214fa9da31ed6a4893b4d7e8
 DIST mgba-0.10.1.tar.gz 14308454 BLAKE2B 5e28ac799cd9e5398508a65bec00dc1da9462e19dc18e0194368a8c57fff2b1af7578a595ab1a414741c1f68c795de3d55913302810d95298a4068b385613389 SHA512 bb79d2380a4708b70daf95c9b403427f77254391b1e11d68411384f265a670907e64b842c9978c9be558ffad337b738d9d83988d52890f08aed7e7fc124f19d4

diff --git a/games-emulation/mgba/mgba-0.10.0.ebuild b/games-emulation/mgba/mgba-0.10.0.ebuild
deleted file mode 100644
index 706b27959a3e..000000000000
--- a/games-emulation/mgba/mgba-0.10.0.ebuild
+++ /dev/null
@@ -1,106 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( lua5-{3..4} )
-inherit cmake lua-single xdg
-
-if [[ ${PV} == 9999 ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/mgba-emu/mgba.git"
-else
-	SRC_URI="https://github.com/mgba-emu/mgba/archive/${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="amd64 ~arm64 ~ppc64 x86"
-fi
-
-DESCRIPTION="Game Boy Advance Emulator"
-HOMEPAGE="https://mgba.io/"
-
-LICENSE="MPL-2.0 BSD LGPL-2.1+ public-domain discord? ( MIT )"
-SLOT="0/$(ver_cut 1-2)"
-IUSE="debug discord elf ffmpeg gles2 gles3 gui libretro lua +opengl +sdl +sqlite test"
-REQUIRED_USE="
-	gui? ( || ( gles2 gles3 opengl ) sqlite )
-	lua? ( ${LUA_REQUIRED_USE} )"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	media-libs/libpng:=
-	sys-libs/zlib:=[minizip]
-	debug? ( dev-libs/libedit )
-	elf? ( dev-libs/elfutils )
-	ffmpeg? ( media-video/ffmpeg:= )
-	gles2? ( media-libs/libglvnd )
-	gles3? ( media-libs/libglvnd )
-	lua? ( ${LUA_DEPS} )
-	opengl? ( media-libs/libglvnd )
-	gui? (
-		dev-qt/qtcore:5
-		dev-qt/qtgui:5
-		dev-qt/qtmultimedia:5
-		dev-qt/qtnetwork:5
-		dev-qt/qtwidgets:5
-	)
-	sdl? ( media-libs/libsdl2[sound,joystick,gles2?,opengl?,video] )
-	sqlite? ( dev-db/sqlite:3 )"
-DEPEND="
-	${RDEPEND}
-	test? ( dev-util/cmocka )"
-BDEPEND="lua? ( virtual/pkgconfig )"
-
-PATCHES=(
-	"${FILESDIR}"/${PN}-0.10.0-optional-updater.patch
-)
-
-pkg_setup() {
-	use lua && lua-single_pkg_setup
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DBUILD_CINEMA=$(usex test)
-		-DBUILD_GL=$(usex opengl)
-		-DBUILD_GLES2=$(usex gles2)
-		-DBUILD_GLES3=$(usex gles3)
-		-DBUILD_LIBRETRO=$(usex libretro)
-		-DBUILD_QT=$(usex gui)
-		-DBUILD_SDL=$(usex sdl) # also used for gamepads in QT build
-		-DBUILD_SUITE=$(usex test)
-		-DBUILD_UPDATER=OFF
-		-DENABLE_SCRIPTING=$(usex lua)
-		-DMARKDOWN=OFF #752048
-		-DUSE_DEBUGGERS=$(usex debug)
-		-DUSE_DISCORD_RPC=$(usex discord)
-		-DUSE_EDITLINE=$(usex debug)
-		-DUSE_ELF=$(usex elf)
-		-DUSE_EPOXY=OFF
-		-DUSE_FFMPEG=$(usex ffmpeg)
-		-DUSE_GDB_STUB=$(usex debug)
-		-DUSE_LIBZIP=OFF
-		-DUSE_LZMA=ON
-		-DUSE_MINIZIP=ON
-		-DUSE_PNG=ON
-		-DUSE_SQLITE3=$(usex sqlite)
-		-DUSE_ZLIB=ON
-		$(usev libretro -DLIBRETRO_LIBDIR="${EPREFIX}"/usr/$(get_libdir)/libretro)
-	)
-	use lua && mycmakeargs+=( -DUSE_LUA=$(ver_cut 1-2 $(lua_get_version)) )
-
-	cmake_src_configure
-}
-
-src_test() {
-	# CMakeLists.txt forces SKIP_RPATH=ON when PREFIX=/usr
-	local -x LD_LIBRARY_PATH=${BUILD_DIR}:${LD_LIBRARY_PATH}
-
-	cmake_src_test
-}
-
-src_install() {
-	cmake_src_install
-
-	use !test || rm "${ED}"/usr/bin/mgba-cinema || die
-
-	rm -r "${ED}"/usr/share/doc/${PF}/{LICENSE,licenses} || die
-}