[gentoo-commits] gentoo-x86 commit in net-fs/nfs-utils: ChangeLog nfs-utils-1.1.2.ebuild

[Mike Frysinger (vapier)]

vapier      08/04/20 10:41:59

  Modified:             ChangeLog
  Added:                nfs-utils-1.1.2.ebuild
  Log:
  Version bump.
  (Portage version: 2.2_pre5)

Revision  Changes    Path
1.123                net-fs/nfs-utils/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/nfs-utils/ChangeLog?rev=1.123&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/nfs-utils/ChangeLog?rev=1.123&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/nfs-utils/ChangeLog?r1=1.122&r2=1.123

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/ChangeLog,v
retrieving revision 1.122
retrieving revision 1.123
diff -u -r1.122 -r1.123
--- ChangeLog	20 Apr 2008 01:02:00 -0000	1.122
+++ ChangeLog	20 Apr 2008 10:41:58 -0000	1.123
@@ -1,6 +1,11 @@
 # ChangeLog for net-fs/nfs-utils
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/ChangeLog,v 1.122 2008/04/20 01:02:00 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/ChangeLog,v 1.123 2008/04/20 10:41:58 vapier Exp $
+
+*nfs-utils-1.1.2 (20 Apr 2008)
+
+  20 Apr 2008; Mike Frysinger <vapier@g.o> +nfs-utils-1.1.2.ebuild:
+  Version bump.
 
 *nfs-utils-1.1.1-r1 (20 Apr 2008)
 



1.1                  net-fs/nfs-utils/nfs-utils-1.1.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/nfs-utils/nfs-utils-1.1.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/net-fs/nfs-utils/nfs-utils-1.1.2.ebuild?rev=1.1&content-type=text/plain

Index: nfs-utils-1.1.2.ebuild
===================================================================
# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-fs/nfs-utils/nfs-utils-1.1.2.ebuild,v 1.1 2008/04/20 10:41:58 vapier Exp $

inherit eutils flag-o-matic multilib

DESCRIPTION="NFS client and server daemons"
HOMEPAGE="http://nfs.sourceforge.net/"
SRC_URI="mirror://sourceforge/nfs/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
IUSE="nonfsv4 tcpd kerberos"

# kth-krb doesn't provide the right include
# files, and nfs-utils doesn't build against heimdal either,
# so don't depend on virtual/krb.
# (04 Feb 2005 agriffis)
RDEPEND="tcpd? ( sys-apps/tcp-wrappers )
	>=net-nds/portmap-5b-r6
	!nonfsv4? (
		>=dev-libs/libevent-1.0b
		>=net-libs/libnfsidmap-0.16
		kerberos? (
			net-libs/librpcsecgss
			net-libs/libgssglue
			app-crypt/mit-krb5
		)
	)"
# util-linux dep is to prevent man-page collision
DEPEND="${RDEPEND}
	>=sys-apps/util-linux-2.12r-r7"

src_compile() {
	econf \
		--mandir=/usr/share/man \
		--with-statedir=/var/lib/nfs \
		--disable-rquotad \
		--enable-nfsv3 \
		--enable-secure-statd \
		$(use_with tcpd tcp-wrappers) \
		$(use_enable !nonfsv4 nfsv4) \
		$(use !nonfsv4 && use_enable kerberos gss) \
		|| die "Configure failed"
	emake || die "Failed to compile"
}

src_install() {
	emake DESTDIR="${D}" install || die

	# Don't overwrite existing xtab/etab, install the original
	# versions somewhere safe...  more info in pkg_postinst
	dodir /usr/lib/nfs
	keepdir /var/lib/nfs/{sm,sm.bak}
	mv "${D}"/var/lib/nfs/* "${D}"/usr/lib/nfs
	keepdir /var/lib/nfs

	# Install some client-side binaries in /sbin
	dodir /sbin
	mv "${D}"/usr/sbin/rpc.statd "${D}"/sbin/ || die

	dodoc ChangeLog README
	docinto linux-nfs ; dodoc linux-nfs/*

	insinto /etc
	doins "${FILESDIR}"/exports

	local f list=""
	if use !nonfsv4 ; then
		list="${list} rpc.idmapd"
		use kerberos && list="${list} rpc.gssd rpc.svcgssd"
	fi
	for f in nfs nfsmount rpc.statd ${list} ; do
		newinitd "${FILESDIR}"/${f}.initd ${f} || die "doinitd ${f}"
	done
	newconfd "${FILESDIR}"/nfs.confd nfs
	use !nonfsv4 && doins utils/idmapd/idmapd.conf

	# uClibc doesn't provide rpcgen like glibc, so lets steal it from nfs-utils
	if ! use elibc_glibc ; then
		dobin tools/rpcgen/rpcgen || die "rpcgen"
		newdoc tools/rpcgen/README README.rpcgen
	fi
}

pkg_preinst() {
	[[ -s ${ROOT}/etc/exports ]] && rm -f "${D}"/etc/exports
}

pkg_postinst() {
	# Install default xtab and friends if there's none existing.
	# In src_install we put them in /usr/lib/nfs for safe-keeping, but
	# the daemons actually use the files in /var/lib/nfs.  This fixes
	# bug 30486
	local f
	for f in "${ROOT}"/usr/$(get_libdir)/nfs/*; do
		[[ -e ${ROOT}/var/lib/nfs/${f##*/} ]] && continue
		einfo "Copying default ${f##*/} from /usr/$(get_libdir)/nfs to /var/lib/nfs"
		cp -pPR "${f}" "${ROOT}"/var/lib/nfs/
	done
}



-- 
gentoo-commits@l.g.o mailing list