[gentoo-commits] gentoo-x86 commit in sys-freebsd/freebsd-sources: freebsd-sources-9.1-r9.ebuild ChangeLog freebsd-sources-9.1-r8.ebuild

[Naohiro Aota (naota)]

naota       14/06/05 02:33:45

  Modified:             ChangeLog
  Added:                freebsd-sources-9.1-r9.ebuild
  Removed:              freebsd-sources-9.1-r8.ebuild
  Log:
  Apply security patches #512376 #512374
  
  (Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key F8551514)

Revision  Changes    Path
1.106                sys-freebsd/freebsd-sources/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-freebsd/freebsd-sources/ChangeLog?rev=1.106&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-freebsd/freebsd-sources/ChangeLog?rev=1.106&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-freebsd/freebsd-sources/ChangeLog?r1=1.105&r2=1.106

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-freebsd/freebsd-sources/ChangeLog,v
retrieving revision 1.105
retrieving revision 1.106
diff -u -r1.105 -r1.106
--- ChangeLog	19 May 2014 02:22:37 -0000	1.105
+++ ChangeLog	5 Jun 2014 02:33:45 -0000	1.106
@@ -1,6 +1,14 @@
 # ChangeLog for sys-freebsd/freebsd-sources
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-freebsd/freebsd-sources/ChangeLog,v 1.105 2014/05/19 02:22:37 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-freebsd/freebsd-sources/ChangeLog,v 1.106 2014/06/05 02:33:45 naota Exp $
+
+*freebsd-sources-9.1-r9 (05 Jun 2014)
+
+  05 Jun 2014; Naohiro Aota <naota@g.o>
+  +files/freebsd-sources-9.1-exec.patch,
+  +files/freebsd-sources-9.1-ktrace.patch, +freebsd-sources-9.1-r9.ebuild,
+  -freebsd-sources-9.1-r8.ebuild:
+  Apply security patches #512376 #512374
 
 *freebsd-sources-9.1-r8 (19 May 2014)
 



1.1                  sys-freebsd/freebsd-sources/freebsd-sources-9.1-r9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-freebsd/freebsd-sources/freebsd-sources-9.1-r9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-freebsd/freebsd-sources/freebsd-sources-9.1-r9.ebuild?rev=1.1&content-type=text/plain

Index: freebsd-sources-9.1-r9.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-freebsd/freebsd-sources/freebsd-sources-9.1-r9.ebuild,v 1.1 2014/06/05 02:33:45 naota Exp $

inherit bsdmk freebsd flag-o-matic

DESCRIPTION="FreeBSD kernel sources"
SLOT="${RV}"
KEYWORDS="~amd64-fbsd ~sparc-fbsd ~x86-fbsd"

IUSE="symlink"

SRC_URI="mirror://gentoo/${SYS}.tar.bz2
	http://dev.gentoo.org/~naota/patch/${P}-en-13-03.patch"

RDEPEND="=sys-freebsd/freebsd-mk-defs-${RV}*"
DEPEND=""

RESTRICT="strip binchecks"

S="${WORKDIR}/sys"

PATCHES=( "${FILESDIR}/${PN}-9.0-disable-optimization.patch"
	"${FILESDIR}/${PN}-9.1-gentoo.patch"
	"${FILESDIR}/${PN}-6.0-flex-2.5.31.patch"
	"${FILESDIR}/${PN}-6.1-ntfs.patch"
	"${FILESDIR}/${PN}-7.1-types.h-fix.patch"
	"${FILESDIR}/${PN}-8.0-subnet-route-pr40133.patch"
	"${FILESDIR}/${PN}-7.1-includes.patch"
	"${FILESDIR}/${PN}-9.0-sysctluint.patch"
	"${FILESDIR}/${PN}-7.0-tmpfs_whiteout_stub.patch"
	"${FILESDIR}/${PN}-9.1-cve-2013-3266.patch"
	"${FILESDIR}/${PN}-9.1-mmap.patch"
	"${FILESDIR}/${PN}-9.1-nfsserver.patch"
	"${DISTDIR}/${PN}-9.1-en-13-03.patch"
	"${FILESDIR}/${PN}-9.1-cve-2013-3077.patch"
	"${FILESDIR}/${PN}-9.1-cve-2013-5209.patch"
	"${FILESDIR}/${PN}-9.1-cve-2013-5691.patch"
	"${FILESDIR}/${PN}-9.1-cve-2013-5710.patch"
	"${FILESDIR}/${PN}-9.1-cve-2014-1453.patch"
	"${FILESDIR}/${PN}-9.1-random.patch"
	"${FILESDIR}/${PN}-9.1-mmap-2014.patch"
	"${FILESDIR}/${PN}-9.1-tcp.patch"
	"${FILESDIR}/${PN}-9.1-ciss.patch"
	"${FILESDIR}/${PN}-9.1-exec.patch"
	"${FILESDIR}/${PN}-9.1-ktrace.patch" )

src_unpack() {
	freebsd_src_unpack

	# This replaces the gentoover patch, it doesn't need reapply every time.
	sed -i -e 's:^REVISION=.*:REVISION="'${PVR}'":' \
		-e 's:^BRANCH=.*:BRANCH="Gentoo":' \
		-e 's:^VERSION=.*:VERSION="${TYPE} ${BRANCH} ${REVISION}":' \
		"${S}/conf/newvers.sh"

	# __FreeBSD_cc_version comes from FreeBSD's gcc.
	# on 9.0-RELEASE it's 900001.
	sed -e "s:-D_KERNEL:-D_KERNEL -D__FreeBSD_cc_version=900001:g" \
		-i "${S}/conf/kern.pre.mk" \
		-i "${S}/conf/kmod.mk" || die "Couldn't set __FreeBSD_cc_version"

	# Remove -Werror
	sed -e "s:-Werror:-Wno-error:g" \
		-i "${S}/conf/kern.pre.mk" \
		-i "${S}/conf/kmod.mk" || die
}

src_compile() {
	einfo "Nothing to compile.."
}

src_install() {
	insinto "/usr/src/sys-${RV}"
	doins -r "${S}/"*
}

pkg_postinst() {
	if [[ ! -L "${ROOT}/usr/src/sys" ]]; then
		einfo "/usr/src/sys symlink doesn't exist; creating symlink to sys-${RV}..."
		ln -sf "sys-${RV}" "${ROOT}/usr/src/sys" || \
			eerror "Couldn't create ${ROOT}/usr/src/sys symlink."
	elif use symlink; then
		einfo "Updating /usr/src/sys symlink to sys-${RV}..."
		rm "${ROOT}/usr/src/sys" || \
			eerror "Couldn't remove previous symlinks, please fix manually."
		ln -sf "sys-${RV}" "${ROOT}/usr/src/sys" || \
			eerror "Couldn't create ${ROOT}/usr/src/sys symlink."
	fi

	if use sparc-fbsd ; then
		ewarn "WARNING: kldload currently causes kernel panics"
		ewarn "on sparc64. This is probably a gcc-4.1 issue, but"
		ewarn "we need gcc-4.1 to compile the kernel correctly :/"
		ewarn "Please compile all modules you need into the kernel"
	fi
}