[gentoo-commits] gentoo-x86 commit in x11-misc/xfe: ChangeLog xfe-1.33.ebuild

[Jeroen Roovers (jer)]

jer         12/10/02 20:53:23

  Modified:             ChangeLog
  Added:                xfe-1.33.ebuild
  Log:
  Version bump. Add LINGUAS support.
  
  (Portage version: 2.2.0_alpha134/cvs/Linux x86_64)

Revision  Changes    Path
1.75                 x11-misc/xfe/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xfe/ChangeLog?rev=1.75&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xfe/ChangeLog?rev=1.75&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xfe/ChangeLog?r1=1.74&r2=1.75

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/xfe/ChangeLog,v
retrieving revision 1.74
retrieving revision 1.75
diff -u -r1.74 -r1.75
--- ChangeLog	12 May 2012 23:38:17 -0000	1.74
+++ ChangeLog	2 Oct 2012 20:53:23 -0000	1.75
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/xfe
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xfe/ChangeLog,v 1.74 2012/05/12 23:38:17 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xfe/ChangeLog,v 1.75 2012/10/02 20:53:23 jer Exp $
+
+*xfe-1.33 (02 Oct 2012)
+
+  02 Oct 2012; Jeroen Roovers <jer@g.o> +xfe-1.33.ebuild:
+  Version bump. Add LINGUAS support.
 
 *xfe-1.32.5 (12 May 2012)
 



1.1                  x11-misc/xfe/xfe-1.33.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xfe/xfe-1.33.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/xfe/xfe-1.33.ebuild?rev=1.1&content-type=text/plain

Index: xfe-1.33.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/xfe/xfe-1.33.ebuild,v 1.1 2012/10/02 20:53:23 jer Exp $

EAPI=4

inherit base

DESCRIPTION="MS-Explorer-like minimalist file manager for X"
HOMEPAGE="http://roland65.free.fr/xfe"
SRC_URI="mirror://sourceforge/${PN}/${PN}/${PV}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="debug nls startup-notification"

XFELINGUAS="
	bs ca cs da de el es_AR es fr hu it ja nl no pl pt_BR pt_PT ru sv tr zh_CN
	zh_TW
"
for lingua in ${XFELINGUAS}; do
	IUSE+=" linguas_${lingua}"
done

RDEPEND="
	media-libs/libpng:0
	startup-notification? ( x11-libs/startup-notification )
	x11-libs/fox:1.6[truetype,png]
	x11-libs/libX11
	x11-libs/libXft
"
DEPEND="
	${RDEPEND}
	nls? ( sys-devel/gettext )
"

DOCS=( AUTHORS BUGS ChangeLog NEWS README TODO )
PATCHES=( "${FILESDIR}"/${PN}-1.32.2-missing_Xlib_h.patch )

src_prepare() {
	base_src_prepare
	cat >po/POTFILES.skip <<-EOF
	src/icons.cpp
	xfe.desktop.in.in
	xfi.desktop.in.in
	xfp.desktop.in.in
	xfv.desktop.in.in
	xfw.desktop.in.in
	EOF

	local lingua
	for lingua in ${XFELINGUAS}; do
		if ! use linguas_${lingua}; then
			sed -i po/LINGUAS -e "s|${lingua}||g" || die
		fi
	done
}

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_enable startup-notification sn) \
		$(use_enable debug)
}