[gentoo-commits] gentoo-x86 commit in net-wireless/gnome-bluetooth: gnome-bluetooth-3.8.1.ebuild ChangeLog

[Pacho Ramos (pacho)]

pacho       13/06/03 20:15:57

  Modified:             ChangeLog
  Added:                gnome-bluetooth-3.8.1.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.12.2/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.127                net-wireless/gnome-bluetooth/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog?rev=1.127&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog?rev=1.127&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog?r1=1.126&r2=1.127

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog,v
retrieving revision 1.126
retrieving revision 1.127
diff -u -r1.126 -r1.127
--- ChangeLog	30 Mar 2013 17:12:10 -0000	1.126
+++ ChangeLog	3 Jun 2013 20:15:57 -0000	1.127
@@ -1,6 +1,11 @@
 # ChangeLog for net-wireless/gnome-bluetooth
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog,v 1.126 2013/03/30 17:12:10 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog,v 1.127 2013/06/03 20:15:57 pacho Exp $
+
+*gnome-bluetooth-3.8.1 (03 Jun 2013)
+
+  03 Jun 2013; Pacho Ramos <pacho@g.o> +gnome-bluetooth-3.8.1.ebuild:
+  Version bump
 
   30 Mar 2013; Gilles Dartiguelongue <eva@g.o>
   -gnome-bluetooth-3.4.2-r1.ebuild:



1.1                  net-wireless/gnome-bluetooth/gnome-bluetooth-3.8.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnome-bluetooth/gnome-bluetooth-3.8.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnome-bluetooth/gnome-bluetooth-3.8.1.ebuild?rev=1.1&content-type=text/plain

Index: gnome-bluetooth-3.8.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnome-bluetooth/gnome-bluetooth-3.8.1.ebuild,v 1.1 2013/06/03 20:15:57 pacho Exp $

EAPI="5"
GCONF_DEBUG="yes"

inherit eutils gnome2 udev user

DESCRIPTION="Fork of bluez-gnome focused on integration with GNOME"
HOMEPAGE="http://live.gnome.org/GnomeBluetooth"

LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
SLOT="2/11" # subslot = libgnome-bluetooth soname version
IUSE="+introspection"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"

COMMON_DEPEND="
	>=dev-libs/glib-2.29.90:2
	>=x11-libs/gtk+-2.91.3:3[introspection?]
	>=x11-libs/libnotify-0.7:=
	virtual/udev
	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
"
RDEPEND="${COMMON_DEPEND}
	>=net-wireless/bluez-4.34
	app-mobilephone/obexd
	x11-themes/gnome-icon-theme-symbolic
"
DEPEND="${COMMON_DEPEND}
	!net-wireless/bluez-gnome
	app-text/docbook-xml-dtd:4.1.2
	dev-libs/libxml2:2
	dev-util/gdbus-codegen
	>=dev-util/gtk-doc-am-1.9
	>=dev-util/intltool-0.40.0
	>=sys-devel/gettext-0.17
	virtual/pkgconfig
	x11-libs/libX11
	x11-libs/libXi
	x11-proto/xproto
"
# eautoreconf needs:
#	gnome-base/gnome-common
#	dev-util/gtk-doc-am

pkg_setup() {
	enewgroup plugdev
}

src_prepare() {
	# Regenerate gdbus-codegen files to allow using any glib version; bug #436236
	rm -v lib/bluetooth-client-glue.{c,h} || die
	gnome2_src_prepare
}

src_configure() {
	gnome2_src_configure \
		$(use_enable introspection) \
		--enable-documentation \
		--disable-desktop-update \
		--disable-icon-update \
		--disable-static \
		ITSTOOL=$(type -P true)
}

src_install() {
	gnome2_src_install
	udev_dorules "${FILESDIR}"/61-${PN}.rules
}

pkg_postinst() {
	gnome2_pkg_postinst
	if ! has_version sys-auth/consolekit[acl] ; then
		elog "Don't forget to add yourself to the plugdev group "
		elog "if you want to be able to control bluetooth transmitter."
	fi
}