[gentoo-commits] gentoo-x86 commit in app-admin/syslog-ng: ChangeLog syslog-ng-3.1.3.ebuild

[Michael Sterrett (mr_bones_)]

mr_bones_    10/11/28 07:36:41

  Modified:             ChangeLog
  Added:                syslog-ng-3.1.3.ebuild
  Log:
  version bump (bug #346735)
  
  (Portage version: 2.1.9.24/cvs/Linux i686)

Revision  Changes    Path
1.260                app-admin/syslog-ng/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/ChangeLog?rev=1.260&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/ChangeLog?rev=1.260&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/ChangeLog?r1=1.259&r2=1.260

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v
retrieving revision 1.259
retrieving revision 1.260
diff -u -r1.259 -r1.260
--- ChangeLog	20 Oct 2010 15:33:12 -0000	1.259
+++ ChangeLog	28 Nov 2010 07:36:41 -0000	1.260
@@ -1,6 +1,12 @@
 # ChangeLog for app-admin/syslog-ng
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v 1.259 2010/10/20 15:33:12 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/ChangeLog,v 1.260 2010/11/28 07:36:41 mr_bones_ Exp $
+
+*syslog-ng-3.1.3 (28 Nov 2010)
+
+  28 Nov 2010; Michael Sterrett <mr_bones_@g.o>
+  +syslog-ng-3.1.3.ebuild:
+  version bump (bug #346735)
 
   20 Oct 2010; Michael Sterrett <mr_bones_@g.o>
   syslog-ng-3.0.8.ebuild, syslog-ng-3.1.2.ebuild:



1.1                  app-admin/syslog-ng/syslog-ng-3.1.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/syslog-ng-3.1.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-admin/syslog-ng/syslog-ng-3.1.3.ebuild?rev=1.1&content-type=text/plain

Index: syslog-ng-3.1.3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-admin/syslog-ng/syslog-ng-3.1.3.ebuild,v 1.1 2010/11/28 07:36:41 mr_bones_ Exp $

EAPI=2
inherit autotools fixheadtails eutils

MY_PV=${PV/_/}
DESCRIPTION="syslog replacement with advanced filtering features"
HOMEPAGE="http://www.balabit.com/products/syslog_ng/"
SRC_URI="http://www.balabit.com/downloads/files/syslog-ng/sources/${PV}/source/syslog-ng_${PV}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="caps hardened ipv6 +pcre selinux spoof-source sql ssl static tcpd"
RESTRICT="test"

LIBS_DEPEND="
	spoof-source? ( net-libs/libnet )
	ssl? ( dev-libs/openssl )
	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
	!static? ( >=dev-libs/eventlog-0.2 )
	>=dev-libs/glib-2.10.1:2
	caps? ( sys-libs/libcap )
	sql? ( >=dev-db/libdbi-0.8.3 )"
RDEPEND="
	!static? (
		pcre? ( dev-libs/libpcre )
		${LIBS_DEPEND}
	)"
DEPEND="${RDEPEND}
	${LIBS_DEPEND}
	static? ( >=dev-libs/eventlog-0.2[static-libs] )
	dev-util/pkgconfig
	sys-devel/flex"
PROVIDE="virtual/logger"

src_prepare() {
	sed -i \
		-e 's/mkdir /mkdir $(DESTDIR)/' \
		scripts/Makefile.am \
		|| die 'sed failed'
	ht_fix_file configure.in
	eautoreconf
}

src_configure() {
	local myconf

	if use static ; then
		myconf="${myconf} --enable-static-linking"
		if use pcre ; then
			ewarn "USE=pcre is incompatible with static linking"
			myconf="${myconf} --disable-pcre"
		fi
	else
			myconf="${myconf} --enable-dynamic-linking"
	fi
	econf \
		--disable-dependency-tracking \
		--sysconfdir=/etc/syslog-ng \
		--with-pidfile-dir=/var/run \
		$(use_enable caps linux-caps) \
		$(use_enable ipv6) \
		$(use_enable pcre) \
		$(use_enable spoof-source) \
		$(use_enable sql) \
		$(use_enable ssl) \
		$(use_enable tcpd tcp-wrapper) \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"

	dodoc AUTHORS ChangeLog NEWS README \
		doc/examples/{syslog-ng.conf.sample,syslog-ng.conf.solaris} \
		contrib/syslog-ng.conf* \
		contrib/syslog2ng "${FILESDIR}/syslog-ng.conf."*

	# Install default configuration
	insinto /etc/syslog-ng
	if use hardened || use selinux ; then
		newins "${FILESDIR}/syslog-ng.conf.gentoo.hardened.${PV%%.*}" syslog-ng.conf
	elif use userland_BSD ; then
		newins "${FILESDIR}/syslog-ng.conf.gentoo.fbsd.${PV%%.*}" syslog-ng.conf
	else
		newins "${FILESDIR}/syslog-ng.conf.gentoo.${PV%%.*}" syslog-ng.conf
	fi

	insinto /etc/logrotate.d
	# Install snippet for logrotate, which may or may not be installed
	if use hardened || use selinux ; then
		newins "${FILESDIR}/syslog-ng.logrotate.hardened" syslog-ng
	else
		newins "${FILESDIR}/syslog-ng.logrotate" syslog-ng
	fi

	newinitd "${FILESDIR}/syslog-ng.rc6.${PV%%.*}" syslog-ng
	newconfd "${FILESDIR}/syslog-ng.confd" syslog-ng
	keepdir /etc/syslog-ng/patterndb.d
}

pkg_postinst() {
	echo
	elog "It is highly recommended that app-admin/logrotate be emerged to"
	elog "manage the log files.  ${PN} installs a file in /etc/logrotate.d"
	elog "for logrotate to use."
	echo
}