[gentoo-commits] gentoo-x86 commit in media-libs/libsndfile: libsndfile-1.0.18-r1.ebuild ChangeLog

[Alexis Ballier (aballier)]

aballier    09/03/03 10:18:58

  Modified:             ChangeLog
  Added:                libsndfile-1.0.18-r1.ebuild
  Log:
  force disabling octave module which was automagic because it seems it installs files at bad locations (bug #260769), may fail to build (bug #260853) and to link (bug #260835).
  (Portage version: 2.2_rc23/cvs/Linux x86_64)

Revision  Changes    Path
1.87                 media-libs/libsndfile/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsndfile/ChangeLog?rev=1.87&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsndfile/ChangeLog?rev=1.87&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsndfile/ChangeLog?r1=1.86&r2=1.87

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/libsndfile/ChangeLog,v
retrieving revision 1.86
retrieving revision 1.87
diff -u -r1.86 -r1.87
--- ChangeLog	28 Feb 2009 12:45:00 -0000	1.86
+++ ChangeLog	3 Mar 2009 10:18:58 -0000	1.87
@@ -1,6 +1,14 @@
 # ChangeLog for media-libs/libsndfile
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/libsndfile/ChangeLog,v 1.86 2009/02/28 12:45:00 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libsndfile/ChangeLog,v 1.87 2009/03/03 10:18:58 aballier Exp $
+
+*libsndfile-1.0.18-r1 (03 Mar 2009)
+
+  03 Mar 2009; Alexis Ballier <aballier@g.o>
+  +libsndfile-1.0.18-r1.ebuild:
+  force disabling octave module which was automagic because it seems it
+  installs files at bad locations (bug #260769), may fail to build (bug
+  #260853) and to link (bug #260835).
 
   28 Feb 2009; Alexis Ballier <aballier@g.o>
   libsndfile-1.0.17-r1.ebuild:



1.1                  media-libs/libsndfile/libsndfile-1.0.18-r1.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsndfile/libsndfile-1.0.18-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/media-libs/libsndfile/libsndfile-1.0.18-r1.ebuild?rev=1.1&content-type=text/plain

Index: libsndfile-1.0.18-r1.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/libsndfile/libsndfile-1.0.18-r1.ebuild,v 1.1 2009/03/03 10:18:58 aballier Exp $

inherit eutils libtool autotools

MY_P=${P/_pre/pre}

DESCRIPTION="A C library for reading and writing files containing sampled sound"
HOMEPAGE="http://www.mega-nerd.com/libsndfile"
if [[ "${MY_P}" == "${P}" ]]; then
	SRC_URI="http://www.mega-nerd.com/libsndfile/${P}.tar.gz"
else
	SRC_URI="http://www.mega-nerd.com/tmp/${MY_P}b.tar.gz"
fi

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
IUSE="sqlite alsa minimal"

RDEPEND="!minimal? ( >=media-libs/flac-1.2.1
		>=media-libs/libogg-1.1.3
		>=media-libs/libvorbis-1.2.1_rc1 )
	alsa? ( media-libs/alsa-lib )
	sqlite? ( >=dev-db/sqlite-3.2 )"
DEPEND="${RDEPEND}
	dev-util/pkgconfig"

S=${WORKDIR}/${MY_P}

src_unpack() {
	unpack ${A}
	cd "${S}"

	sed -i -e "s/noinst_PROGRAMS/check_PROGRAMS/" "${S}/tests/Makefile.am" \
	"${S}/examples/Makefile.am" || die "failed to remove forced build of test and example programs"
	epatch "${FILESDIR}/${PN}-1.0.17-regtests-need-sqlite.patch"
	epatch "${FILESDIR}/${PN}-1.0.18-m4macro.patch"
	epatch "${FILESDIR}/${PN}-1.0.18-less_strict_tests.patch"

	AT_M4DIR=M4 eautoreconf
	epunt_cxx
}

src_compile() {
	econf $(use_enable sqlite) \
		$(use_enable alsa) \
		$(use_enable !minimal external-libs) \
		--disable-octave \
		--disable-gcc-werror \
		--disable-gcc-pipe \
		--disable-dependency-tracking
	emake || die "emake failed."
}

src_install() {
	emake DESTDIR="${D}" htmldocdir="/usr/share/doc/${PF}/html" install || die "emake install failed."
	dodoc AUTHORS ChangeLog NEWS README TODO
}