[gentoo-commits] repo/gentoo:master commit in: net-libs/libtorrent-rasterbar/

[Mikle Kolyada]

commit:     5e7ec5e56097136228c358bd9a573be91da7e47f
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Sat Oct 26 20:47:11 2019 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Sat Oct 26 20:47:11 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5e7ec5e5

net-libs/libtorrent-rasterbar: Drop old

Package-Manager: Portage-2.3.76, Repoman-2.3.16
Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>

 .../libtorrent-rasterbar-1.2.2.ebuild              | 111 ---------------------
 1 file changed, 111 deletions(-)

diff --git a/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.2.2.ebuild b/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.2.2.ebuild
deleted file mode 100644
index 9f40198c2dd..00000000000
--- a/net-libs/libtorrent-rasterbar/libtorrent-rasterbar-1.2.2.ebuild
+++ /dev/null
@@ -1,111 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python2_7 python3_{5,6} )
-PYTHON_REQ_USE="threads"
-DISTUTILS_OPTIONAL=true
-DISTUTILS_IN_SOURCE_BUILD=true
-
-inherit autotools distutils-r1 flag-o-matic
-
-MY_PV=$(ver_rs 1-2 '_')
-MY_P=${PN/-rasterbar}-${MY_PV}
-
-DESCRIPTION="C++ BitTorrent implementation focusing on efficiency and scalability"
-HOMEPAGE="https://libtorrent.org https://github.com/arvidn/libtorrent"
-SRC_URI="https://github.com/arvidn/libtorrent/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0/9"
-KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
-IUSE="debug +dht doc examples libressl python +ssl static-libs test"
-
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-
-RDEPEND="
-	dev-libs/boost:=[threads]
-	virtual/libiconv
-	examples? ( !net-p2p/mldonkey )
-	python? (
-		${PYTHON_DEPS}
-		dev-libs/boost:=[python,${PYTHON_USEDEP}]
-	)
-	ssl? (
-		!libressl? ( dev-libs/openssl:0= )
-		libressl? ( dev-libs/libressl:= )
-	)
-"
-DEPEND="${RDEPEND}
-	sys-devel/libtool
-"
-
-S="${WORKDIR}/${PN/-rasterbar}-${MY_P}"
-
-src_prepare() {
-	mkdir "${S}"/build-aux/ || die
-	touch "${S}"/build-aux/config.rpath || die
-	eautoreconf
-
-	default
-
-	# bug 578026
-	# prepend -L${S}/... to ensure bindings link against the lib we just built
-	sed -i -e "s|^|-L${S}/src/.libs |" bindings/python/link_flags.in || die
-
-	# prepend -I${S}/... to ensure bindings use the right headers
-	sed -i -e "s|^|-I${S}/src/include |" bindings/python/compile_flags.in || die
-
-	use python && distutils-r1_src_prepare
-}
-
-src_configure() {
-	append-cxxflags -std=c++11 # bug 634506
-
-	local myeconfargs=(
-		$(use_enable debug)
-		$(use_enable debug export-all)
-		$(use_enable debug logging)
-		$(use_enable dht)
-		$(use_enable examples)
-		$(use_enable ssl encryption)
-		$(use_enable static-libs static)
-		$(use_enable test tests)
-		--with-libiconv
-	)
-	econf "${myeconfargs[@]}"
-
-	if use python; then
-		python_configure() {
-			econf "${myeconfargs[@]}" \
-				--enable-python-binding \
-				--with-boost-python="${EPYTHON#python}"
-		}
-		distutils-r1_src_configure
-	fi
-}
-
-src_compile() {
-	default
-
-	python_compile() {
-		cd "${BUILD_DIR}/../bindings/python" || die
-		distutils-r1_python_compile
-	}
-	use python && distutils-r1_src_compile
-}
-
-src_install() {
-	use doc && HTML_DOCS+=( "${S}"/docs )
-
-	default
-
-	python_install() {
-		cd "${BUILD_DIR}/../bindings/python" || die
-		distutils-r1_python_install
-	}
-	use python && distutils-r1_src_install
-
-	find "${D}" -name '*.la' -delete || die
-}