[gentoo-commits] gentoo-x86 commit in dev-libs/apr-util: apr-util-1.5.3-r2.ebuild ChangeLog apr-util-1.5.3-r1.ebuild

[Lars Wendler (polynomial-c)]

polynomial-c    14/08/01 04:47:40

  Modified:             ChangeLog
  Added:                apr-util-1.5.3-r2.ebuild
  Removed:              apr-util-1.5.3-r1.ebuild
  Log:
  Fixed compilation with nss/openssl USE flag (bug #518708). Committed straight to stable
  
  (Portage version: 2.2.10/cvs/Linux x86_64, RepoMan options: --force, signed Manifest commit with key 0x981CA6FC)

Revision  Changes    Path
1.210                dev-libs/apr-util/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/apr-util/ChangeLog?rev=1.210&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/apr-util/ChangeLog?rev=1.210&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/apr-util/ChangeLog?r1=1.209&r2=1.210

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-libs/apr-util/ChangeLog,v
retrieving revision 1.209
retrieving revision 1.210
diff -u -r1.209 -r1.210
--- ChangeLog	17 May 2014 13:55:59 -0000	1.209
+++ ChangeLog	1 Aug 2014 04:47:40 -0000	1.210
@@ -1,6 +1,13 @@
 # ChangeLog for dev-libs/apr-util
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/apr-util/ChangeLog,v 1.209 2014/05/17 13:55:59 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/apr-util/ChangeLog,v 1.210 2014/08/01 04:47:40 polynomial-c Exp $
+
+*apr-util-1.5.3-r2 (01 Aug 2014)
+
+  01 Aug 2014; Lars Wendler <polynomial-c@g.o>
+  -apr-util-1.5.3-r1.ebuild, +apr-util-1.5.3-r2.ebuild:
+  Fixed compilation with nss/openssl USE flag (bug #518708). Committed straight
+  to stable.
 
   17 May 2014; Agostino Sarubbo <ago@g.o> apr-util-1.5.3-r1.ebuild:
   Stable for alpha, wrt bug #504300



1.1                  dev-libs/apr-util/apr-util-1.5.3-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/apr-util/apr-util-1.5.3-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-libs/apr-util/apr-util-1.5.3-r2.ebuild?rev=1.1&content-type=text/plain

Index: apr-util-1.5.3-r2.ebuild
===================================================================
# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/apr-util/apr-util-1.5.3-r2.ebuild,v 1.1 2014/08/01 04:47:40 polynomial-c Exp $

EAPI="4"

# Usually apr-util has the same PV as apr, but in case of security fixes, this may change.
# APR_PV="${PV}"
APR_PV="1.4.6"

inherit autotools db-use eutils libtool multilib toolchain-funcs

DESCRIPTION="Apache Portable Runtime Utility Library"
HOMEPAGE="http://apr.apache.org/"
SRC_URI="mirror://apache/apr/${P}.tar.bz2"

LICENSE="Apache-2.0"
SLOT="1"
KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="berkdb doc freetds gdbm ldap mysql nss odbc openssl postgres sqlite static-libs"
RESTRICT="test"

RDEPEND="dev-libs/expat
	>=dev-libs/apr-${APR_PV}:1
	berkdb? ( >=sys-libs/db-4 )
	freetds? ( dev-db/freetds )
	gdbm? ( sys-libs/gdbm )
	ldap? ( =net-nds/openldap-2* )
	mysql? ( =virtual/mysql-5* )
	nss? ( dev-libs/nss )
	odbc? ( dev-db/unixODBC )
	openssl? ( dev-libs/openssl )
	postgres? ( dev-db/postgresql-base )
	sqlite? ( dev-db/sqlite:3 )"
DEPEND="${RDEPEND}
	>=sys-devel/libtool-2.4.2
	doc? ( app-doc/doxygen )"

DOCS=(CHANGES NOTICE README)

src_prepare() {
	epatch "${FILESDIR}"/${P}-berkdb6.patch #476374
	epatch "${FILESDIR}"/${PN}-1.5.3-sysroot.patch #385775
	eautoreconf
	elibtoolize
}

src_configure() {
	local myconf=()

	tc-is-static-only && myconf+=( --disable-util-dso )

	if use berkdb; then
		local db_version
		db_version="$(db_findver sys-libs/db)" || die "Unable to find Berkeley DB version"
		db_version="$(db_ver_to_slot "${db_version}")"
		db_version="${db_version/\./}"
		myconf+=(
			--with-dbm=db${db_version}
			# We use $T for the libdir because otherwise it'd simply be the normal
			# system libdir.  That's pointless as the compiler will search it for
			# us already.  This makes cross-compiling and such easier.
			--with-berkeley-db="${SYSROOT}$(db_includedir 2>/dev/null):${T}"
		)
	else
		myconf+=( --without-berkeley-db )
	fi

	if use nss || use openssl ; then
		myconf+=( --with-crypto ) # 518708
	fi

	econf \
		--datadir="${EPREFIX}"/usr/share/apr-util-1 \
		--with-apr="${SYSROOT}${EPREFIX}"/usr \
		--with-expat="${EPREFIX}"/usr \
		--without-sqlite2 \
		$(use_with freetds) \
		$(use_with gdbm) \
		$(use_with ldap) \
		$(use_with mysql) \
		$(use_with nss) \
		$(use_with odbc) \
		$(use_with openssl) \
		$(use_with postgres pgsql) \
		$(use_with sqlite sqlite3) \
		"${myconf[@]}"
	# Use the current env build settings rather than whatever apr was built with.
	sed -i -r \
		-e "/^(apr_builddir|apr_builders|top_builddir)=/s:=:=${SYSROOT}:" \
		-e "/^CC=/s:=.*:=$(tc-getCC):" \
		-e '/^(C|CPP|CXX|LD)FLAGS=/d' \
		-e '/^LTFLAGS/s:--silent::' \
		build/rules.mk || die
}

src_compile() {
	emake
	use doc && emake dox
}

src_install() {
	default

	find "${ED}" -name "*.la" -delete
	find "${ED}usr/$(get_libdir)/apr-util-${SLOT}" -name "*.a" -delete
	use static-libs || find "${ED}" -name "*.a" -delete

	use doc && dohtml -r docs/dox/html/*

	# This file is only used on AIX systems, which Gentoo is not,
	# and causes collisions between the SLOTs, so remove it.
	rm -f "${ED}usr/$(get_libdir)/aprutil.exp"
}