[gentoo-commits] repo/gentoo:master commit in: dev-perl/Crypt-SMIME/

[Kent Fredric]

commit:     5b09ea03e77c4f12e23b930b97ae125097bbe1ba
Author:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
AuthorDate: Thu Jul  2 13:09:34 2020 +0000
Commit:     Kent Fredric <kentnl <AT> gentoo <DOT> org>
CommitDate: Thu Jul  2 13:09:56 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5b09ea03

dev-perl/Crypt-SMIME: -r bump for EAPI7 and CFLAGS love

- EAPI7
- Unconditionally patch bad tests
- Ensure CFLAGS passed through make/compiler

Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Kent Fredric <kentnl <AT> gentoo.org>

 dev-perl/Crypt-SMIME/Crypt-SMIME-0.250.0-r1.ebuild | 49 ++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/dev-perl/Crypt-SMIME/Crypt-SMIME-0.250.0-r1.ebuild b/dev-perl/Crypt-SMIME/Crypt-SMIME-0.250.0-r1.ebuild
new file mode 100644
index 00000000000..f7a56171e9d
--- /dev/null
+++ b/dev-perl/Crypt-SMIME/Crypt-SMIME-0.250.0-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DIST_AUTHOR=MIKAGE
+DIST_VERSION=0.25
+inherit perl-module
+
+DESCRIPTION="S/MIME message signing, verification, encryption and decryption"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="libressl test minimal"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!libressl? ( >=dev-libs/openssl-0.9.9:0 )
+	libressl? ( dev-libs/libressl )
+	virtual/perl-XSLoader
+"
+BDEPEND="${RDEPEND}
+	virtual/perl-ExtUtils-MakeMaker
+	dev-perl/ExtUtils-PkgConfig
+	dev-perl/ExtUtils-CChecker
+	>=virtual/perl-ExtUtils-Constant-0.230.0
+	test? (
+		dev-perl/Test-Exception
+		virtual/perl-Test-Simple
+		!minimal? (
+			>=dev-perl/Test-Taint-1.60.0
+			>=dev-perl/Taint-Util-0.80.0
+		)
+	)
+"
+PERL_RM_FILES=(
+	t/boilerplate.t
+	t/manifest.t
+	t/dependencies.t
+	t/pod-coverage.t
+	t/pod.t
+)
+
+src_compile() {
+	mymake=(
+		"OPTIMIZE=${CFLAGS}"
+	)
+	perl-module_src_compile
+}