[gentoo-commits] gentoo-x86 commit in media-video/pgcedit: metadata.xml pgcedit-0.8.6.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      12/12/31 00:46:07

  Added:                metadata.xml pgcedit-0.8.6.ebuild ChangeLog
  Log:
  Initial ebuild partially based on one in Sunrise #213937 by Juan Aguado.
  
  (Portage version: 2.2.0_alpha144/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

Revision  Changes    Path
1.1                  media-video/pgcedit/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pgcedit/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pgcedit/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<maintainer>
		<email>maintainer-needed@g.o</email>
	</maintainer>
	<use>
		<flag name='video'>Add support for video preview</flag>
	</use>
</pkgmetadata>



1.1                  media-video/pgcedit/pgcedit-0.8.6.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pgcedit/pgcedit-0.8.6.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pgcedit/pgcedit-0.8.6.ebuild?rev=1.1&content-type=text/plain

Index: pgcedit-0.8.6.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/pgcedit/pgcedit-0.8.6.ebuild,v 1.1 2012/12/31 00:46:07 vapier Exp $

EAPI="4"

inherit eutils versionator

MY_PN="PgcEdit"
MY_P="${MY_PN}_source_$(get_after_major_version)"
MY_PDOC="${MY_PN}_Manual_html"

DESCRIPTION="DVD IFO and Menu editor"
HOMEPAGE="http://download.videohelp.com/r0lZ/pgcedit/"
SRC_URI="http://download.videohelp.com/r0lZ/${PN}/versions/${MY_P}.zip
	http://download.videohelp.com/r0lZ/${PN}/versions/${MY_PDOC}.zip"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="video"

RDEPEND="app-cdr/cdrtools
	>=dev-lang/tcl-8.4
	>=dev-lang/tk-8.4
	video? ( app-emulation/wine )"
DEPEND="app-arch/unzip"

S=${WORKDIR}

src_prepare() {
	epatch "${FILESDIR}"/${P}-config-paths.patch
	sed -i "s:@DOCDIR@:/usr/share/doc/${PF}/html:" lib/main.tcl || die
	# These are only used in Windows.
	rm bin/{mkisofs,pskill}.exe || die
	use video || rm bin/PgcEditPreview.exe
}

src_install() {
	newbin ${MY_PN}_main.tcl ${PN}

	keepdir /usr/share/${PN}/plugins
	insinto /usr/share/${PN}
	doins -r bin lib
	dohtml -r doc/*

	doicon "${FILESDIR}"/${PN}.png
	make_desktop_entry ${PN} ${MY_PN} ${PN} "AudioVideo;Video;"

	dodoc HISTORY.txt TODO.txt
}



1.1                  media-video/pgcedit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pgcedit/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/pgcedit/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for media-video/pgcedit
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/media-video/pgcedit/ChangeLog,v 1.1 2012/12/31 00:46:07 vapier Exp $

*pgcedit-0.8.6 (31 Dec 2012)

  31 Dec 2012; Mike Frysinger <vapier@g.o>
  +files/pgcedit-0.8.6-config-paths.patch, +files/pgcedit.png, +metadata.xml,
  +pgcedit-0.8.6.ebuild:
  Initial ebuild partially based on one in Sunrise #213937 by Juan Aguado.