[gentoo-commits] repo/gentoo:master commit in: gui-libs/gtksourceview/

[Matt Turner]

commit:     9df3d7249630dda74a112c1b1f3dba94206405d0
Author:     Pascal Jäger <pascal.jaeger <AT> leimstift <DOT> de>
AuthorDate: Tue Sep 20 20:39:34 2022 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Wed Sep 21 13:10:28 2022 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9df3d724

gui-libs/gtksourceview: bump to 5.6.0

Signed-off-by: Pascal Jäger <pascal.jaeger <AT> leimstift.de>
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 gui-libs/gtksourceview/Manifest                   |  1 +
 gui-libs/gtksourceview/gtksourceview-5.6.0.ebuild | 74 +++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/gui-libs/gtksourceview/Manifest b/gui-libs/gtksourceview/Manifest
index ff9a9d3dcb03..79635bb6132b 100644
--- a/gui-libs/gtksourceview/Manifest
+++ b/gui-libs/gtksourceview/Manifest
@@ -1 +1,2 @@
 DIST gtksourceview-5.4.2.tar.xz 1261496 BLAKE2B 3c7447de6d252c7fbccd5fb18222aeb25cd264b53847d3fb45a5b30a528d3a850d059f226a696e9d8462085910c67e318be10de89c0e7a554787fb25f27a6674 SHA512 eef5267bd473327f4e3e7b79d4a96c53067e221e9f171dde864a7866ccab8258ca9e13b5f59e40272fd7e3acd9e1e08bb4bea3674fa2864ec108b4a47220e9d3
+DIST gtksourceview-5.6.0.tar.xz 1266084 BLAKE2B b633de2abaa8476ae86cb4ec7b1bf4e1c48077f2674988b3ba807cb02c1b4ccc792325ddc3c2e1333d3f373371b378f8e2fa73089279d48b825267370af9d6a0 SHA512 f1dd7dc236b30ca540f033dd7ffdb2715375854d22ae69d7229dc525ea54f5319408624497d7c0c4b7b8e14a2c8a6b992721fe397171b62efab48b5a38509df9

diff --git a/gui-libs/gtksourceview/gtksourceview-5.6.0.ebuild b/gui-libs/gtksourceview/gtksourceview-5.6.0.ebuild
new file mode 100644
index 000000000000..ff010dbd6254
--- /dev/null
+++ b/gui-libs/gtksourceview/gtksourceview-5.6.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson vala virtualx xdg
+
+DESCRIPTION="A text widget implementing syntax highlighting and other features"
+HOMEPAGE="https://wiki.gnome.org/Projects/GtkSourceView"
+
+LICENSE="LGPL-2.1+"
+SLOT="5"
+
+IUSE="gtk-doc +introspection sysprof +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.72:2
+	>=gui-libs/gtk-4.6:4[introspection?]
+	>=dev-libs/libxml2-2.6:2
+	introspection? ( >=dev-libs/gobject-introspection-1.70.0:= )
+	>=dev-libs/fribidi-0.19.7
+	media-libs/fontconfig
+	x11-libs/pango[introspection?]
+	>=dev-libs/libpcre2-10.21:=[-recursion-limit(-)]
+	sysprof? ( dev-util/sysprof-capture:4 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? ( dev-util/gi-docgen )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dinstall_tests=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use sysprof)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	# Tests fail in test-regex with libpcre2[recursion-limit] - https://gitlab.gnome.org/GNOME/gtksourceview/-/issues/255
+	# Ensured OK via USE dep, as it would mean issues in real usage for syntax highlighting as well
+	virtx meson_src_test --timeout-multiplier=2
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /usr/share/${PN}-5/language-specs
+	newins "${FILESDIR}"/5-gentoo.lang gentoo.lang
+
+	if use gtk-doc ; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}