[gentoo-commits] gentoo-x86 commit in games-emulation/snes9x: snes9x-1.53.ebuild ChangeLog

[Michael Sterrett (mr_bones_)]

mr_bones_    11/09/26 22:23:28

  Modified:             ChangeLog
  Added:                snes9x-1.53.ebuild
  Log:
  version bump (bug #380809); also builds against newer zlib (bug #384547)
  
  (Portage version: 2.1.10.11/cvs/Linux i686)

Revision  Changes    Path
1.52                 games-emulation/snes9x/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/snes9x/ChangeLog?rev=1.52&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/snes9x/ChangeLog?rev=1.52&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/snes9x/ChangeLog?r1=1.51&r2=1.52

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-emulation/snes9x/ChangeLog,v
retrieving revision 1.51
retrieving revision 1.52
diff -u -r1.51 -r1.52
--- ChangeLog	15 Nov 2010 09:49:52 -0000	1.51
+++ ChangeLog	26 Sep 2011 22:23:28 -0000	1.52
@@ -1,6 +1,12 @@
 # ChangeLog for games-emulation/snes9x
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-emulation/snes9x/ChangeLog,v 1.51 2010/11/15 09:49:52 tupone Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/games-emulation/snes9x/ChangeLog,v 1.52 2011/09/26 22:23:28 mr_bones_ Exp $
+
+*snes9x-1.53 (26 Sep 2011)
+
+  26 Sep 2011; Michael Sterrett <mr_bones_@g.o> +snes9x-1.53.ebuild,
+  +files/snes9x-1.53-build.patch:
+  version bump (bug #380809); also builds against newer zlib (bug #384547)
 
   15 Nov 2010; Alfredo Tupone <tupone@g.o> snes9x-1.52-r1.ebuild:
   Require app-emulation/emul-linux-x86-soundlibs when needed. Bug #345099 by



1.1                  games-emulation/snes9x/snes9x-1.53.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/snes9x/snes9x-1.53.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-emulation/snes9x/snes9x-1.53.ebuild?rev=1.1&content-type=text/plain

Index: snes9x-1.53.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-emulation/snes9x/snes9x-1.53.ebuild,v 1.1 2011/09/26 22:23:27 mr_bones_ Exp $

EAPI=2
inherit autotools eutils flag-o-matic multilib gnome2-utils games

DESCRIPTION="Super Nintendo Entertainment System (SNES) emulator"
HOMEPAGE="http://code.google.com/p/snes9x-gtk/"
SRC_URI="http://snes9x-gtk.googlecode.com/files/${P}-src.tar.bz2"

LICENSE="as-is GPL-2 LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
IUSE="alsa debug gtk joystick multilib netplay nls opengl oss png pulseaudio portaudio +xv +xrandr zlib"

RDEPEND="x11-libs/libX11
	x11-libs/libXext
	png? ( >=media-libs/libpng-1.2.43 )
	amd64? ( png? ( >=media-libs/libpng-1.4.2 ) )
	gtk? ( >=x11-libs/gtk+-2.10:2
		x11-misc/xdg-utils
		portaudio? ( >=media-libs/portaudio-19_pre )
		joystick? ( >=media-libs/libsdl-1.2.12[joystick] )
		opengl? ( virtual/opengl )
		xv? ( x11-libs/libXv )
		xrandr? ( x11-libs/libXrandr )
		alsa? ( media-libs/alsa-lib )
		pulseaudio? ( media-sound/pulseaudio ) )"
DEPEND="${RDEPEND}
	x11-proto/xproto
	gtk? ( dev-util/pkgconfig
		xv? ( x11-proto/videoproto ) )
	nls? ( dev-util/intltool )"

S=${WORKDIR}/${P}-src/unix

pkg_setup() {
	games_pkg_setup
}

src_prepare() {
	cd "${WORKDIR}"/${P}-src
	sed -i -e '/pedantic/d' {gtk,unix}/configure.ac || die
	sed -i -e '75i#define OF(x) x' unzip/{un,}zip.h || die
	sed -i -e '22i#define OF(x) x' unzip/ioapi.h || die
	epatch "${FILESDIR}"/${P}-build.patch
	cd unix
	eautoreconf
	if use gtk; then
		cd ../gtk
		eautoreconf
	fi
}

src_configure() {
	append-ldflags -Wl,-z,noexecstack

	egamesconf \
		$(use_enable joystick gamepad) \
		$(use_enable debug debugger) \
		$(use_enable netplay) \
		$(use_enable zlib gzip) \
		$(use_enable zlib zip) \
		$(use_enable png screenshot)

	if use gtk; then
		cd ../gtk
		egamesconf \
			--disable-dependency-tracking \
			--datadir=/usr/share \
			$(use_enable nls) \
			$(use_with opengl) \
			$(use_with joystick) \
			$(use_with xv) \
			$(use_with xrandr) \
			$(use_with netplay) \
			$(use_with zlib) \
			$(use_with alsa) \
			$(use_with oss) \
			$(use_with pulseaudio) \
			$(use_with portaudio) \
			$(use_with png screenshot)
	fi
}

src_compile() {
	games_src_compile
	if use gtk; then
		emake -C ../gtk || die
	fi
}

src_install() {
	dogamesbin ${PN} || die

	dohtml {.,..}/docs/*.html
	dodoc ../docs/{snes9x.conf.default,{changes,control-inputs,controls,snapshots}.txt}

	if use gtk; then
		emake -C ../gtk DESTDIR="${D}" install || die
		dodoc ../gtk/{AUTHORS,doc/README}
	fi

	prepgamesdirs
}

pkg_preinst() {
	games_pkg_preinst
	use gtk && gnome2_icon_savelist
}

pkg_postinst() {
	games_pkg_postinst
	use gtk && gnome2_icon_cache_update
}

pkg_postrm() {
	use gtk && gnome2_icon_cache_update
}