[gentoo-commits] gentoo-x86 commit in app-portage/gentoolkit: ChangeLog gentoolkit-0.3.0_rc11-r3.ebuild gentoolkit-0.3.0_rc11-r2.ebuild

[Paul Varner (fuzzyray)]

fuzzyray    10/11/24 19:00:55

  Modified:             ChangeLog
  Added:                gentoolkit-0.3.0_rc11-r3.ebuild
  Removed:              gentoolkit-0.3.0_rc11-r2.ebuild
  Log:
  Update euse to look for portage config files in new as well as old paths - bug 346519. Make euse prefix aware.
  
  (Portage version: 2.1.9.24/cvs/Linux i686)

Revision  Changes    Path
1.201                app-portage/gentoolkit/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/gentoolkit/ChangeLog?rev=1.201&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/gentoolkit/ChangeLog?rev=1.201&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/gentoolkit/ChangeLog?r1=1.200&r2=1.201

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v
retrieving revision 1.200
retrieving revision 1.201
diff -u -r1.200 -r1.201
--- ChangeLog	22 Nov 2010 20:22:33 -0000	1.200
+++ ChangeLog	24 Nov 2010 19:00:55 -0000	1.201
@@ -1,6 +1,14 @@
 # ChangeLog for app-portage/gentoolkit
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v 1.200 2010/11/22 20:22:33 fuzzyray Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/ChangeLog,v 1.201 2010/11/24 19:00:55 fuzzyray Exp $
+
+*gentoolkit-0.3.0_rc11-r3 (24 Nov 2010)
+
+  24 Nov 2010; Paul Varner <fuzzyray@g.o> +files/0.3.0_rc11-euse.patch,
+  +files/0.3.0_rc11-euse_prefix.patch, -gentoolkit-0.3.0_rc11-r2.ebuild,
+  +gentoolkit-0.3.0_rc11-r3.ebuild:
+  Update euse to look for portage config files in new as well as old paths -
+  bug 346519. Make euse prefix aware
 
 *gentoolkit-0.3.0_rc11-r2 (22 Nov 2010)
 



1.1                  app-portage/gentoolkit/gentoolkit-0.3.0_rc11-r3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.3.0_rc11-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.3.0_rc11-r3.ebuild?rev=1.1&content-type=text/plain

Index: gentoolkit-0.3.0_rc11-r3.ebuild
===================================================================
# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-portage/gentoolkit/gentoolkit-0.3.0_rc11-r3.ebuild,v 1.1 2010/11/24 19:00:55 fuzzyray Exp $

EAPI="3"
SUPPORT_PYTHON_ABIS="1"
DISTUTILS_DISABLE_VERSIONING_OF_PYTHON_SCRIPTS="1"
RESTRICT_PYTHON_ABIS="2.[45]"
PYTHON_USE_WITH="xml"

inherit distutils python eutils

DESCRIPTION="Collection of administration scripts for Gentoo"
HOMEPAGE="http://www.gentoo.org/proj/en/portage/tools/index.xml"
SRC_URI="mirror://gentoo/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
IUSE=""

# Drop "~m68k ~s390 ~sh ~sparc-fbsd ~x86-fbsd" due to dev-python/argparse dependency
# Note: argparse is provided in python 2.7 and 3.2
# KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~ppc-aix ~x64-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"

DEPEND="sys-apps/portage"
RDEPEND="${DEPEND}
	!<=app-portage/gentoolkit-dev-0.2.7
	dev-python/argparse
	|| ( app-misc/realpath sys-freebsd/freebsd-bin )
	sys-apps/gawk
	sys-apps/grep"

distutils_src_compile_pre_hook() {
	echo VERSION="${PVR}" "$(PYTHON)" setup.py set_version
	VERSION="${PVR}" "$(PYTHON)" setup.py set_version \
		|| die "setup.py set_version failed"
}

src_prepare() {
	epatch "${FILESDIR}/${PV}-eshowkw_indir.patch"
	epatch "${FILESDIR}/${PV}-setup.py.patch"
	epatch "${FILESDIR}/${PV}-cpv.py.patch"
	epatch "${FILESDIR}/${PV}-euse.patch"
	epatch "${FILESDIR}/${PV}-euse_prefix.patch"
}

src_install() {
	python_convert_shebangs -r "" build-*/scripts-*
	distutils_src_install

	# Create cache directory for revdep-rebuild
	dodir /var/cache/revdep-rebuild
	keepdir /var/cache/revdep-rebuild
	use prefix || fowners root:root /var/cache/revdep-rebuild
	fperms 0700 /var/cache/revdep-rebuild

	# remove on Gentoo Prefix platforms where it's broken anyway
	if use prefix; then
		[[ ${CHOST} != *-aix* ]] && rm "${ED}"/usr/bin/revdep-rebuild
	fi

	# Can distutils handle this?
	dosym eclean /usr/bin/eclean-dist
	dosym eclean /usr/bin/eclean-pkg
}

pkg_postinst() {
	distutils_pkg_postinst

	# Make sure that our ownership and permissions stuck
	use prefix || chown root:root "${EROOT}/var/cache/revdep-rebuild"
	chmod 0700 "${EROOT}/var/cache/revdep-rebuild"

	einfo
	einfo "For further information on gentoolkit, please read the gentoolkit"
	einfo "guide: http://www.gentoo.org/doc/en/gentoolkit.xml"
	einfo
	einfo "Another alternative to equery is app-portage/portage-utils"
}