[gentoo-commits] gentoo-x86 commit in dev-python/sphinx: ChangeLog sphinx-0.6.2.ebuild

[Patrick Lauer (patrick)]

patrick     09/06/21 09:13:47

  Modified:             ChangeLog
  Added:                sphinx-0.6.2.ebuild
  Log:
  Bump to 0.6.2
  (Portage version: 2.2_rc33/cvs/Linux x86_64)

Revision  Changes    Path
1.19                 dev-python/sphinx/ChangeLog

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/sphinx/ChangeLog?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/sphinx/ChangeLog?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/sphinx/ChangeLog?r1=1.18&r2=1.19

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- ChangeLog	9 Jun 2009 15:55:50 -0000	1.18
+++ ChangeLog	21 Jun 2009 09:13:47 -0000	1.19
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/sphinx
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v 1.18 2009/06/09 15:55:50 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/ChangeLog,v 1.19 2009/06/21 09:13:47 patrick Exp $
+
+*sphinx-0.6.2 (21 Jun 2009)
+
+  21 Jun 2009; Patrick Lauer <patrick@g.o> +sphinx-0.6.2.ebuild:
+  Bump to 0.6.2
 
   09 Jun 2009; Raúl Porcel <armin76@g.o> sphinx-0.5.2.ebuild,
   sphinx-0.6.1-r1.ebuild:



1.1                  dev-python/sphinx/sphinx-0.6.2.ebuild

file : http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/sphinx/sphinx-0.6.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewcvs.py/gentoo-x86/dev-python/sphinx/sphinx-0.6.2.ebuild?rev=1.1&content-type=text/plain

Index: sphinx-0.6.2.ebuild
===================================================================
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/sphinx/sphinx-0.6.2.ebuild,v 1.1 2009/06/21 09:13:47 patrick Exp $

inherit distutils multilib

MY_PN="Sphinx"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Tool to create documentation for Python projects"
HOMEPAGE="http://sphinx.pocoo.org/"
SRC_URI="http://pypi.python.org/packages/source/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~s390 ~sh ~sparc ~x86"
IUSE="doc test"

RDEPEND=">=dev-python/pygments-0.8
	>=dev-python/jinja2-2.1
	>=dev-python/docutils-0.4"

DEPEND="${RDEPEND}
	dev-python/setuptools
	test? ( dev-python/nose )"

S="${WORKDIR}/${MY_P}"

src_compile() {
	DOCS="CHANGES"
	distutils_src_compile

	if use doc ; then
		cd doc
		PYTHONPATH="../" emake \
			SPHINXBUILD="${python} ../sphinx-build.py" \
			html || die "making docs failed"
	fi
}

src_install() {
	distutils_src_install

	if use doc ; then
		dohtml -A txt -r doc/_build/html/* || die
	fi
}

src_test() {
	PYTHONPATH="./build/lib" "${python}" tests/run.py || die "Tests failed"
}

pkg_postinst() {
	distutils_pkg_postinst

	# Generating the Grammar pickle to avoid on the fly generation causing sandbox violations (bug #266015)
	"${python}" \
		-c "from sphinx.pycode.pgen2.driver import load_grammar ; load_grammar('${ROOT}/usr/$(get_libdir)/python${PYVER}/site-packages/sphinx/pycode/Grammar.txt')" \
		|| die "generating grammar pickle failed"
}

pkg_postrm() {
	rm "${ROOT}/usr/$(get_libdir)/python${PYVER}/site-packages/sphinx/pycode"/Grammar*.pickle
	distutils_pkg_postrm
}