[gentoo-commits] repo/gentoo:master commit in: dev-db/sqlitebrowser/

[James Le Cuirot]

commit:     d1f6c36477476add0efe1389a7ce4eccac2c0213
Author:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
AuthorDate: Sun Dec  6 21:46:43 2015 +0000
Commit:     James Le Cuirot <chewi <AT> gentoo <DOT> org>
CommitDate: Sun Dec  6 21:49:49 2015 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d1f6c364

dev-db/sqlitebrowser: Use the new antlr-cpp package instead of antlr

The non-Java parts of antlr have now been split out. The Java part
isn't required in this case.

Package-Manager: portage-2.2.26

 dev-db/sqlitebrowser/sqlitebrowser-3.7.0-r1.ebuild | 60 ++++++++++++++++++++++
 1 file changed, 60 insertions(+)

diff --git a/dev-db/sqlitebrowser/sqlitebrowser-3.7.0-r1.ebuild b/dev-db/sqlitebrowser/sqlitebrowser-3.7.0-r1.ebuild
new file mode 100644
index 0000000..3ebd2cb
--- /dev/null
+++ b/dev-db/sqlitebrowser/sqlitebrowser-3.7.0-r1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+CMAKE_MAKEFILE_GENERATOR=ninja
+
+inherit eutils cmake-utils
+
+DESCRIPTION="SQLite Database Browser"
+HOMEPAGE="http://sqlitebrowser.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3 MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="qt4 qt5 test"
+
+REQUIRED_USE="^^ ( qt4 qt5 )"
+
+RDEPEND="
+	dev-cpp/antlr-cpp:2=
+	dev-db/sqlite:3
+	dev-libs/qcustomplot[qt5=]
+	x11-libs/qscintilla
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtgui:4
+	)
+	qt5? (
+		dev-qt/qtnetwork:5
+		dev-qt/qttest:5
+		dev-qt/qtwidgets:5
+	)"
+DEPEND="${RDEPEND}
+	qt5? ( dev-qt/linguist-tools:5 )
+"
+
+PATCHES=( "${FILESDIR}"/${P}-unbundle.patch )
+
+src_prepare() {
+	# https://github.com/qingfengxia/qhexedit still bundled
+	# x11-libs/qscintilla[qt4?,qt5?] still bundled
+	find libs/{antlr-2.7.7,qcustomplot-source} -delete || die
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_use qt5)
+		$(cmake-utils_use_enable test TESTING)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	doicon images/sqlitebrowser.svg
+}